+rl
@rl:='prim':'type'
[ksi0:rl][eta0:rl]
is:=is"e"(rl,ksi0,eta0):'prop'
nis:=not(is(ksi0,eta0)):'prop'
@[p:[x:rl]'prop']
all:=all"l"(rl,p):'prop'
some:=some"l"(rl,p):'prop'
one:=one"e"(rl,p):'prop'
ksi0@[s:set(rl)]
in:=esti(rl,ksi0,s):'prop'
@0:='prim':rl
[ksi:cut]
pofrp:='prim':rl
nofrp:='prim':rl
[eta:cut][i:is"rp"(ksi,eta)]
isrpep:=isf(cut,rl,[x:cut]pofrp(x),ksi,eta,i):is(pofrp(ksi),pofrp(eta))
isrpen:=isf(cut,rl,[x:cut]nofrp(x),ksi,eta,i):is(nofrp(ksi),nofrp(eta))
eta@[i:is(pofrp(ksi),pofrp(eta))]
isrpip:='prim':is"rp"(ksi,eta)
eta@[i:is(nofrp(ksi),nofrp(eta))]
isrpin:='prim':is"rp"(ksi,eta)
@[ksi0:rl]
pos:=image(cut,rl,[x:cut]pofrp(x),ksi0):'prop'
neg:=image(cut,rl,[x:cut]nofrp(x),ksi0):'prop'
axrl:='prim':orec3(is(ksi0,0),pos(ksi0),neg(ksi0))
axrlo:=orec3e1(is(ksi0,0),pos(ksi0),neg(ksi0),axrl):or3(is(ksi0,0),pos(ksi0),neg(ksi0))
axrle:=orec3e2(is(ksi0,0),pos(ksi0),neg(ksi0),axrl):ec3(is(ksi0,0),pos(ksi0),neg(ksi0))
ksi@posi:=imagei(cut,rl,[x:cut]pofrp(x),ksi):pos(pofrp(ksi))
negi:=imagei(cut,rl,[x:cut]nofrp(x),ksi):neg(nofrp(ksi))
ksi0@[p:pos(ksi0)][p1:'prop'][p2:[x:cut][t:is(ksi0,pofrp(x))]p1]
posapp:=someapp(cut,[x:cut]is(ksi0,pofrp(x)),p,p1,p2):p1
ksi0@[n:neg(ksi0)][p1:'prop'][p2:[x:cut][t:is(ksi0,nofrp(x))]p1]
negapp:=someapp(cut,[x:cut]is(ksi0,nofrp(x)),n,p1,p2):p1
+iv1
@t1:=[x:cut][y:cut][t:is(pofrp(x),pofrp(y))]isrpip(x,y,t):injective(cut,rl,[x:cut]pofrp(x))
-iv1
p@rpofp:=soft(cut,rl,[x:cut]pofrp(x),t1".iv1",ksi0,p):cut
[eta0:rl][q:pos(eta0)][i:is(ksi0,eta0)]
isperp:=isinv(cut,rl,[x:cut]pofrp(x),t1".iv1",ksi0,p,eta0,q,i):is"rp"(rpofp(ksi0,p),rpofp(eta0,q))
q@[i:is"rp"(rpofp(ksi0,p),rpofp(eta0,q))]
ispirp:=isinve(cut,rl,[x:cut]pofrp(x),t1".iv1",ksi0,p,eta0,q,i):is(ksi0,eta0)
ksi@isrpp1:=isst1(cut,rl,[x:cut]pofrp(x),t1".iv1",ksi):is"rp"(ksi,rpofp(pofrp(ksi),posi(ksi)))
isrpp2:=isst2(cut,rl,[x:cut]pofrp(x),t1".iv1",ksi):is"rp"(rpofp(pofrp(ksi),posi(ksi)),ksi)
p@isprp1:=ists1"e"(cut,rl,[x:cut]pofrp(x),t1".iv1",ksi0,p):is(ksi0,pofrp(rpofp(ksi0,p)))
isprp2:=ists2"e"(cut,rl,[x:cut]pofrp(x),t1".iv1",ksi0,p):is(pofrp(rpofp(ksi0,p)),ksi0)
+*iv1
@t2:=[x:cut][y:cut][t:is(nofrp(x),nofrp(y))]isrpin(x,y,t):injective(cut,rl,[x:cut]nofrp(x))
-iv1
n@rpofn:=soft(cut,rl,[x:cut]nofrp(x),t2".iv1",ksi0,n):cut
[eta0:rl][m:neg(eta0)][i:is(ksi0,eta0)]
isnerp:=isinv(cut,rl,[x:cut]nofrp(x),t2".iv1",ksi0,n,eta0,m,i):is"rp"(rpofn(ksi0,n),rpofn(eta0,m))
m@[i:is"rp"(rpofn(ksi0,n),rpofn(eta0,m))]
isnirp:=isinve(cut,rl,[x:cut]nofrp(x),t2".iv1",ksi0,n,eta0,m,i):is(ksi0,eta0)
ksi@isrpn1:=isst1(cut,rl,[x:cut]nofrp(x),t2".iv1",ksi):is"rp"(ksi,rpofn(nofrp(ksi),negi(ksi)))
isrpn2:=isst2(cut,rl,[x:cut]nofrp(x),t2".iv1",ksi):is"rp"(rpofn(nofrp(ksi),negi(ksi)),ksi)
n@isnrp1:=ists1"e"(cut,rl,[x:cut]nofrp(x),t2".iv1",ksi0,n):is(ksi0,nofrp(rpofn(ksi0,n)))
isnrp2:=ists2"e"(cut,rl,[x:cut]nofrp(x),t2".iv1",ksi0,n):is(nofrp(rpofn(ksi0,n)),ksi0)
ksi0@[p1:'prop'][pp:[t:pos(ksi0)]p1][0p:[t:is(ksi0,0)]p1][np:[t:neg(ksi0)]p1]
rlapp:=or3app(is(ksi0,0),pos(ksi0),neg(ksi0),p1,axrlo(ksi0),0p,pp,np):p1
ksi0@[p:pos(ksi0)]
pnotn:=ec3e23(is(ksi0,0),pos(ksi0),neg(ksi0),axrle(ksi0),p):not(neg(ksi0))
pnot0:=ec3e21(is(ksi0,0),pos(ksi0),neg(ksi0),axrle(ksi0),p):nis(ksi0,0)
ksi0@[i:is(ksi0,0)]
0notp:=ec3e12(is(ksi0,0),pos(ksi0),neg(ksi0),axrle(ksi0),i):not(pos(ksi0))
0notn:=ec3e13(is(ksi0,0),pos(ksi0),neg(ksi0),axrle(ksi0),i):not(neg(ksi0))
ksi0@[n:neg(ksi0)]
nnotp:=ec3e32(is(ksi0,0),pos(ksi0),neg(ksi0),axrle(ksi0),n):not(pos(ksi0))
nnot0:=ec3e31(is(ksi0,0),pos(ksi0),neg(ksi0),axrle(ksi0),n):nis(ksi0,0)
ksi0@[p:pos(ksi0)]
mn0a:=nofrp(rpofp(ksi0,p)):rl
negip:=negi(rpofp(ksi0,p)):neg(mn0a(ksi0,p))
[eta0:rl][q:pos(eta0)][i:is(ksi0,eta0)]
ispen:=isrpen(rpofp(ksi0,p),rpofp(eta0,q),isperp(ksi0,p,eta0,q,i)):is(mn0a(ksi0,p),mn0a(eta0,q))
q@[i:is(mn0a(ksi0,p),mn0a(eta0,q))]
ispin:=ispirp(ksi0,p,eta0,q,isrpin(rpofp(ksi0,p),rpofp(eta0,q),i)):is(ksi0,eta0)
@[ksi:cut]
ismn0rp1:=isrpen(rpofp(pofrp(ksi),posi(ksi)),ksi,isrpp2(ksi)):is(mn0a(pofrp(ksi),posi(ksi)),nofrp(ksi))
ismn0rp2:=symis(rl,mn0a(pofrp(ksi),posi(ksi)),nofrp(ksi),ismn0rp1):is(nofrp(ksi),mn0a(pofrp(ksi),posi(ksi)))
ksi0@[n:neg(ksi0)]
pofn:=pofrp(rpofn(ksi0,n)):rl
posin:=posi(rpofn(ksi0,n)):pos(pofn(ksi0,n))
[eta0:rl][o:neg(eta0)][i:is(ksi0,eta0)]
isnep:=isrpep(rpofn(ksi0,n),rpofn(eta0,o),isnerp(ksi0,n,eta0,o,i)):is(pofn(ksi0,n),pofn(eta0,o))
o@[i:is(pofn(ksi0,n),pofn(eta0,o))]
isnip:=isnirp(ksi0,n,eta0,o,isrpip(rpofn(ksi0,n),rpofn(eta0,o),i)):is(ksi0,eta0)
@[ksi:cut]
ispofnrp1:=isrpep(rpofn(nofrp(ksi),negi(ksi)),ksi,isrpn2(ksi)):is(pofn(nofrp(ksi),negi(ksi)),pofrp(ksi))
ispofnrp2:=symis(rl,pofn(nofrp(ksi),negi(ksi)),pofrp(ksi),ispofnrp1):is(pofrp(ksi),pofn(nofrp(ksi),negi(ksi)))
n@isnp1:=tris(rl,ksi0,nofrp(rpofn(ksi0,n)),mn0a(pofn(ksi0,n),posin(ksi0,n)),isnrp1(ksi0,n),ismn0rp2(rpofn(ksi0,n))):is(ksi0,mn0a(pofn(ksi0,n),posin(ksi0,n)))
isnp2:=symis(rl,ksi0,mn0a(pofn(ksi0,n),posin(ksi0,n)),isnp1):is(mn0a(pofn(ksi0,n),posin(ksi0,n)),ksi0)
ksi0@[p:pos(ksi0)]
ispn1:=tris(rl,ksi0,pofrp(rpofp(ksi0,p)),pofn(mn0a(ksi0,p),negip(ksi0,p)),isprp1(ksi0,p),ispofnrp2(rpofp(ksi0,p))):is(ksi0,pofn(mn0a(ksi0,p),negip(ksi0,p)))
ispn2:=symis(rl,ksi0,pofn(mn0a(ksi0,p),negip(ksi0,p)),ispn1):is(pofn(mn0a(ksi0,p),negip(ksi0,p)),ksi0)
ksi0@satz163:=refis(rl,ksi0):is(ksi0,ksi0)
[eta0:rl][i:is(ksi0,eta0)]
satz164:=symis(rl,ksi0,eta0,i):is(eta0,ksi0)
eta0@[zeta0:rl][i:is(ksi0,eta0)][j:is(eta0,zeta0)]
satz165:=tris(rl,ksi0,eta0,zeta0,i,j):is(ksi0,zeta0)
ksi0@abs:=ite"l.r"(neg(ksi0),rl,[t:neg(ksi0)]pofn(ksi0,t),[t:not(neg(ksi0))]ksi0,[t:neg(ksi0)][u:neg(ksi0)]isnep(ksi0,t,ksi0,u,refis(rl,ksi0)),[t:not(neg(ksi0))][u:not(neg(ksi0))]refis(rl,ksi0)):rl
[n:not(neg(ksi0))]
+iv2
t1:=itef"l.r"(neg(ksi0),rl,[t:neg(ksi0)]pofn(ksi0,t),[t:not(neg(ksi0))]ksi0,[t:neg(ksi0)][u:neg(ksi0)]isnep(ksi0,t,ksi0,u,refis(rl,ksi0)),[t:not(neg(ksi0))][u:not(neg(ksi0))]refis(rl,ksi0),n):is(abs(ksi0),ksi0)
-iv2
ksi0@[p:pos(ksi0)]
absp:=t1".iv2"(pnotn(ksi0,p)):is(abs(ksi0),ksi0)
ksi0@[i:is(ksi0,0)]
abs0:=tris(rl,abs(ksi0),ksi0,0,t1".iv2"(0notn(ksi0,i)),i):is(abs(ksi0),0)
ksi0@[n:neg(ksi0)]
absn:=itet"l.r"(neg(ksi0),rl,[t:neg(ksi0)]pofn(ksi0,t),[t:not(neg(ksi0))]ksi0,[t:neg(ksi0)][u:neg(ksi0)]isnep(ksi0,t,ksi0,u,refis(rl,ksi0)),[t:not(neg(ksi0))][u:not(neg(ksi0))]refis(rl,ksi0),n):is(abs(ksi0),pofn(ksi0,n))
eta0@[i:is(ksi0,eta0)]
isabs:=isf(rl,rl,[x:rl]abs(x),ksi0,eta0,i):is(abs(ksi0),abs(eta0))
ksi0@[p:pos(ksi0)]
satz166a:=isp1(rl,[x:rl]pos(x),ksi0,abs(ksi0),p,absp(ksi0,p)):pos(abs(ksi0))
ksi0@[n:neg(ksi0)]
satz166b:=isp1(rl,[x:rl]pos(x),pofn(ksi0,n),abs(ksi0),posin(ksi0,n),absn(ksi0,n)):pos(abs(ksi0))
eta0@[p:pos(ksi0)][q:pos(eta0)][i:is(abs(ksi0),abs(eta0))]
satz166c:=tr3is(rl,ksi0,abs(ksi0),abs(eta0),eta0,symis(rl,abs(ksi0),ksi0,absp(ksi0,p)),i,absp(eta0,q)):is(ksi0,eta0)
eta0@[n:neg(ksi0)][o:neg(eta0)][i:is(abs(ksi0),abs(eta0))]
satz166d:=isnip(ksi0,n,eta0,o,tr3is(rl,pofn(ksi0,n),abs(ksi0),abs(eta0),pofn(eta0,o),symis(rl,abs(ksi0),pofn(ksi0,n),absn(ksi0,n)),i,absn(eta0,o))):is(ksi0,eta0)
ksi0@[n:nis(ksi0,0)]
satz166e:=rlapp(ksi0,pos(abs(ksi0)),[t:pos(ksi0)]satz166a(ksi0,t),th2"l.imp"(is(ksi0,0),pos(abs(ksi0)),n),[t:neg(ksi0)]satz166b(ksi0,t)):pos(abs(ksi0))
ksi0@[eta0:rl][p:pos(ksi0)]
more1a:=imp"l.r"(pos(eta0),[t:pos(eta0)]more(rpofp(ksi0,p),rpofp(eta0,t))):'prop'
eta0@more1:=and(pos(ksi0),[t:pos(ksi0)]more1a(t)):'prop'
more2:=and(is(ksi0,0),neg(eta0)):'prop'
more3a:=more1(abs(eta0),abs(ksi0)):'prop'
more3:=and3(neg(ksi0),neg(eta0),more3a):'prop'
more:=or3(more1,more2,more3):'prop'
[m:more(ksi0,eta0)][p:pos(ksi0)]
+*iv2
p@t2:=th1"l.and"(is(ksi0,0),neg(eta0),pnot0(ksi0,p)):not(more2)
t3:=th3"l.imp"(more3,neg(ksi0),pnotn(ksi0,p),[t:more3]and3e1(neg(ksi0),neg(eta0),more3a,t)):not(more3)
t4:=or3e1(more1,more2,more3,m,t2,t3):more1
-iv2
p@[q:pos(eta0)]
moreep2:=<q><p>ande2(pos(ksi0),[t:pos(ksi0)]more1a(t),t4".iv2"):more"rp"(rpofp(ksi0,p),rpofp(eta0,q))
m@[p:pos(eta0)]
+*iv2
p@t5:=th2"l.and"(is(ksi0,0),neg(eta0),pnotn(eta0,p)):not(more2)
t6:=th3"l.imp"(more3,neg(eta0),pnotn(eta0,p),[t:more3]and3e2(neg(ksi0),neg(eta0),more3a,t)):not(more3)
t7:=or3e1(more1,more2,more3,m,t5,t6):more1
-iv2
p@moreep1a:=ande1(pos(ksi0),[t:pos(ksi0)]more1a(t),t7".iv2"):pos(ksi0)
moreep1:=moreep2(moreep1a,p):more"rp"(rpofp(ksi0,moreep1a),rpofp(eta0,p))
m@[i:is(ksi0,0)]
+*iv2
i@t8:=th1"l.and"(pos(ksi0),[t:pos(ksi0)]more1a(t),0notp(ksi0,i)):not(more1)
t9:=th3"l.imp"(more3,neg(ksi0),0notn(ksi0,i),[t:more3]and3e1(neg(ksi0),neg(eta0),more3a,t)):not(more3)
t10:=or3e2(more1,more2,more3,m,t9,t8):more2
-iv2
i@moree01:=ande2(is(ksi0,0),neg(eta0),t10".iv2"):neg(eta0)
m@[i:is(eta0,0)]
+*iv2
i@t11:=th2"l.and"(is(ksi0,0),neg(eta0),0notn(eta0,i)):not(more2)
t12:=th3"l.imp"(more3,neg(eta0),0notn(eta0,i),[t:more3]and3e2(neg(ksi0),neg(eta0),more3a,t)):not(more3)
t13:=or3e1(more1,more2,more3,m,t11,t12):more1
-iv2
i@moree02:=ande1(pos(ksi0),[t:pos(ksi0)]more1a(t),t13".iv2"):pos(ksi0)
m@[n:neg(ksi0)]
+*iv2
n@t14:=th1"l.and"(pos(ksi0),[t:pos(ksi0)]more1a(t),nnotp(ksi0,n)):not(more1)
t15:=th1"l.and"(is(ksi0,0),neg(eta0),nnot0(ksi0,n)):not(more2)
t16:=or3e3(more1,more2,more3,m,t14,t15):more3
-iv2
n@moreen1a:=and3e2(neg(ksi0),neg(eta0),more3a,t16".iv2"):neg(eta0)
+*iv2
n@t17:=and3e3(neg(ksi0),neg(eta0),more3a,t16):more3a
-iv2
n@moreen1:=or3i1(more1(abs(eta0),abs(ksi0)),more2(abs(eta0),abs(ksi0)),more3(abs(eta0),abs(ksi0)),t17".iv2"):more(abs(eta0),abs(ksi0))
eta0@[p:pos(ksi0)][q:pos(eta0)][m:more"rp"(rpofp(ksi0,p),rpofp(eta0,q))][t:pos(ksi0)][u:pos(eta0)]
+*iv2
u@t18:=ismore12(rpofp(ksi0,p),rpofp(ksi0,t),rpofp(eta0,q),rpofp(eta0,u),isperp(ksi0,p,ksi0,t,refis(rl,ksi0)),isperp(eta0,q,eta0,u,refis(rl,eta0)),m):more"rp"(rpofp(ksi0,t),rpofp(eta0,u))
m@t19:=andi(pos(ksi0),[t:pos(ksi0)]more1a(ksi0,eta0,t),p,[t:pos(ksi0)][u:pos(eta0)]t18(t,u)):more1(ksi0,eta0)
-iv2
m@moreipp:=or3i1(more1(ksi0,eta0),more2(ksi0,eta0),more3(ksi0,eta0),t19".iv2"):more(ksi0,eta0)
p@[i:is(eta0,0)][q:pos(ksi0)]
+*iv2
q@t20:=th2"l.r.imp"(pos(eta0),[t:pos(eta0)]more"rp"(rpofp(ksi0,q),rpofp(eta0,t)),0notp(eta0,i)):more1a(ksi0,eta0,q)
i@t21:=andi(pos(ksi0),[t:pos(ksi0)]more1a(ksi0,eta0,t),p,[t:pos(ksi0)]t20(t)):more1(ksi0,eta0)
-iv2
i@moreip0:=or3i1(more1(ksi0,eta0),more2(ksi0,eta0),more3(ksi0,eta0),t21".iv2"):more(ksi0,eta0)
p@[n:neg(eta0)][q:pos(ksi0)]
+*iv2
q@t22:=th2"l.r.imp"(pos(eta0),[t:pos(eta0)]more"rp"(rpofp(ksi0,q),rpofp(eta0,t)),nnotp(eta0,n)):more1a(ksi0,eta0,q)
n@t23:=andi(pos(ksi0),[t:pos(ksi0)]more1a(ksi0,eta0,t),p,[t:pos(ksi0)]t22(t)):more1(ksi0,eta0)
-iv2
n@moreipn:=or3i1(more1(ksi0,eta0),more2(ksi0,eta0),more3(ksi0,eta0),t23".iv2"):more(ksi0,eta0)
eta0@[i:is(ksi0,0)][n:neg(eta0)]
+*iv2
n@t24:=andi(is(ksi0,0),neg(eta0),i,n):more2(ksi0,eta0)
-iv2
n@morei0n:=or3i2(more1(ksi0,eta0),more2(ksi0,eta0),more3(ksi0,eta0),t24".iv2"):more(ksi0,eta0)
eta0@[n:neg(ksi0)][o:neg(eta0)][m:more(abs(eta0),abs(ksi0))]
+*iv2
m@t25:=t4(abs(eta0),abs(ksi0),m,satz166b(eta0,o)):more3a(ksi0,eta0)
t26:=and3i(neg(ksi0),neg(eta0),more3a(ksi0,eta0),n,o,t25):more3(ksi0,eta0)
-iv2
m@moreinn:=or3i3(more1(ksi0,eta0),more2(ksi0,eta0),more3(ksi0,eta0),t26".iv2"):more(ksi0,eta0)
eta0@less:=more(eta0,ksi0):'prop'
[l:less(ksi0,eta0)][p:pos(ksi0)][q:pos(eta0)]
lessep2:=satz121(rpofp(eta0,q),rpofp(ksi0,p),moreep2(eta0,ksi0,l,q,p)):less"rp"(rpofp(ksi0,p),rpofp(eta0,q))
p@lessep1a:=moreep1a(eta0,ksi0,l,p):pos(eta0)
lessep1:=lessep2(ksi0,eta0,l,p,lessep1a):less"rp"(rpofp(ksi0,p),rpofp(eta0,lessep1a))
l@[i:is(ksi0,0)]
lesse01:=moree02(eta0,ksi0,l,i):pos(eta0)
l@[i:is(eta0,0)]
lesse02:=moree01(eta0,ksi0,l,i):neg(ksi0)
l@[n:neg(eta0)]
lessen1a:=moreen1a(eta0,ksi0,l,n):neg(ksi0)
lessen1:=moreen1(eta0,ksi0,l,n):more(abs(ksi0),abs(eta0))
eta0@[p:pos(ksi0)][q:pos(eta0)][l:less"rp"(rpofp(ksi0,p),rpofp(eta0,q))]
lessipp:=moreipp(eta0,ksi0,q,p,satz122(rpofp(ksi0,p),rpofp(eta0,q),l)):less(ksi0,eta0)
eta0@[i:is(ksi0,0)][p:pos(eta0)]
lessi0p:=moreip0(eta0,ksi0,p,i):less(ksi0,eta0)
eta0@[n:neg(ksi0)][p:pos(eta0)]
lessinp:=moreipn(eta0,ksi0,p,n):less(ksi0,eta0)
n@[i:is(eta0,0)]
lessin0:=morei0n(eta0,ksi0,i,n):less(ksi0,eta0)
n@[o:neg(eta0)][m:more(abs(ksi0),abs(eta0))]
lessinn:=moreinn(eta0,ksi0,o,n,m):less(ksi0,eta0)
+2167
eta0@ixy0:=is(ksi0,eta0):'prop'
mxy0:=more(ksi0,eta0):'prop'
lxy0:=less(ksi0,eta0):'prop'
o30:=or3(ixy0,mxy0,lxy0):'prop'
e30:=ec3(ixy0,mxy0,lxy0):'prop'
oe30:=orec3(ixy0,mxy0,lxy0):'prop'
[p:pos(ksi0)]
ksi:=rpofp(ksi0,p):cut
[q:pos(eta0)]
eta:=rpofp(eta0,q):cut
ixy:=is"rp"(ksi,eta):'prop'
mxy:=more"rp"(ksi,eta):'prop'
lxy:=less"rp"(ksi,eta):'prop'
o3:=or3(ixy,mxy,lxy):'prop'
e3:=ec3(ixy,mxy,lxy):'prop'
oe3:=orec3(ixy,mxy,lxy):'prop'
t1:=satz123a(ksi,eta):o3
[i:ixy]
t2:=ispirp(ksi0,p,eta0,q,i):ixy0
t3:=or3i1(ixy0,mxy0,lxy0,t2):o30
q@[m:mxy]
t4:=moreipp(ksi0,eta0,p,q,m):mxy0
t5:=or3i2(ixy0,mxy0,lxy0,t4):o30
q@[l:lxy]
t6:=lessipp(ksi0,eta0,p,q,l):lxy0
t7:=or3i3(ixy0,mxy0,lxy0,t6):o30
q@t8:=or3app(ixy,mxy,lxy,o30,t1,[t:ixy]t3(t),[t:mxy]t5(t),[t:lxy]t7(t)):o30
t9:=satz123b(ksi,eta):e3
[i:ixy0]
t10:=isperp(ksi0,p,eta0,q,i):ixy
t11:=ec3e12(ixy,mxy,lxy,t9,t10):not(mxy)
t12:=th3"l.imp"(mxy0,mxy,t11,[t:mxy0]moreep2(ksi0,eta0,t,p,q)):not(mxy0)
q@[m:mxy0]
t13:=moreep2(ksi0,eta0,m,p,q):mxy
t14:=ec3e23(ixy,mxy,lxy,t9,t13):not(lxy)
t15:=th3"l.imp"(lxy0,lxy,t14,[t:lxy0]lessep2(ksi0,eta0,t,p,q)):not(lxy0)
q@[l:lxy0]
t16:=lessep2(ksi0,eta0,l,p,q):lxy
t17:=ec3e31(ixy,mxy,lxy,t9,t16):not(ixy)
t18:=th3"l.imp"(ixy0,ixy,t17,[t:ixy0]isperp(ksi0,p,eta0,q,t)):not(ixy0)
q@t19:=th6"l.ec3"(ixy0,mxy0,lxy0,[t:ixy0]t12(t),[t:mxy0]t15(t),[t:lxy0]t18(t)):e30
t20:=orec3i(ixy0,mxy0,lxy0,t8,t19):oe30
p@[i:is(eta0,0)]
t21:=moreip0(ksi0,eta0,p,i):mxy0
t22:=or3i2(ixy0,mxy0,lxy0,t21):o30
t23:=th4"e.notis"(rl,ksi0,0,eta0,pnot0(ksi0,p),i):not(ixy0)
t24:=th3"l.imp"(lxy0,pos(eta0),0notp(eta0,i),[t:lxy0]lessep1a(ksi0,eta0,t,p)):not(lxy0)
t25:=ec3i3(ixy0,mxy0,lxy0,t24,t23):e30
t26:=orec3i(ixy0,mxy0,lxy0,t22,t25):oe30
p@[n:neg(eta0)]
t27:=moreipn(ksi0,eta0,p,n):mxy0
t28:=or3i2(ixy0,mxy0,lxy0,t27):o30
t29:=th3"l.imp"(ixy0,pos(eta0),nnotp(eta0,n),[t:ixy0]isp(rl,[u:rl]pos(u),ksi0,eta0,p,t)):not(ixy0)
t30:=th3"l.imp"(lxy0,pos(eta0),nnotp(eta0,n),[t:lxy0]lessep1a(ksi0,eta0,t,p)):not(lxy0)
t31:=ec3i3(ixy0,mxy0,lxy0,t30,t29):e30
t32:=orec3i(ixy0,mxy0,lxy0,t28,t31):oe30
p@t33:=rlapp(eta0,oe30,[t:pos(eta0)]t20(t),[t:is(eta0,0)]t26(t),[t:neg(eta0)]t32(t)):oe30
eta0@[i:is(ksi0,0)][p:pos(eta0)]
t34:=lessi0p(ksi0,eta0,i,p):lxy0
t35:=or3i3(ixy0,mxy0,lxy0,t34):o30
t36:=th3"l.imp"(ixy0,is(eta0,0),pnot0(eta0,p),[t:ixy0]tris1(rl,eta0,0,ksi0,t,i)):not(ixy0)
t36a:=th3"l.imp"(mxy0,pos(ksi0),0notp(ksi0,i),[t:mxy0]moreep1a(ksi0,eta0,t,p)):not(mxy0)
t37:=ec3i1(ixy0,mxy0,lxy0,t36,t36a):e30
t38:=orec3i(ixy0,mxy0,lxy0,t35,t37):oe30
i@[j:is(eta0,0)]
t39:=tris2(rl,ksi0,eta0,0,i,j):ixy0
t40:=or3i1(ixy0,mxy0,lxy0,t39):o30
t41:=th3"l.imp"(mxy0,neg(eta0),0notn(eta0,j),[t:mxy0]moree01(ksi0,eta0,t,i)):not(mxy0)
t42:=th3"l.imp"(lxy0,pos(eta0),0notp(eta0,j),[t:lxy0]lesse01(ksi0,eta0,t,i)):not(lxy0)
t43:=ec3i2(ixy0,mxy0,lxy0,t41,t42):e30
t44:=orec3i(ixy0,mxy0,lxy0,t40,t43):oe30
i@[n:neg(eta0)]
t45:=morei0n(ksi0,eta0,i,n):mxy0
t46:=or3i2(ixy0,mxy0,lxy0,t45):o30
t47:=th3"l.imp"(ixy0,is(eta0,0),nnot0(eta0,n),[t:ixy0]tris1(rl,eta0,0,ksi0,t,i)):not(ixy0)
t48:=th3"l.imp"(lxy0,neg(ksi0),0notn(ksi0,i),[t:lxy0]lessen1a(ksi0,eta0,t,n)):not(lxy0)
t49:=ec3i3(ixy0,mxy0,lxy0,t48,t47):e30
t50:=orec3i(ixy0,mxy0,lxy0,t46,t49):oe30
i@t51:=rlapp(eta0,oe30,[t:pos(eta0)]t38(t),[t:is(eta0,0)]t44(t),[t:neg(eta0)]t50(t)):oe30
eta0@[n:neg(ksi0)][p:pos(eta0)]
t52:=lessinp(ksi0,eta0,n,p):less(ksi0,eta0)
t53:=or3i3(ixy0,mxy0,lxy0,t52):o30
t54:=th3"l.imp"(ixy0,neg(eta0),pnotn(eta0,p),[t:ixy0]isp(rl,[u:rl]neg(u),ksi0,eta0,n,t)):not(ixy0)
t55:=th3"l.imp"(mxy0,neg(eta0),pnotn(eta0,p),[t:mxy0]moreen1a(ksi0,eta0,t,n)):not(mxy0)
t56:=ec3i1(ixy0,mxy0,lxy0,t54,t55):e30
t57:=orec3i(ixy0,mxy0,lxy0,t53,t56):oe30
n@[i:is(eta0,0)]
t58:=lessin0(ksi0,eta0,n,i):less(ksi0,eta0)
t59:=or3i3(ixy0,mxy0,lxy0,t58):o30
t60:=th4"e.notis"(rl,ksi0,0,eta0,nnot0(ksi0,n),i):not(ixy0)
t61:=th3"l.imp"(mxy0,neg(eta0),0notn(eta0,i),[t:mxy0]moreen1a(ksi0,eta0,t,n)):not(mxy0)
t62:=ec3i1(ixy0,mxy0,lxy0,t60,t61):e30
t63:=orec3i(ixy0,mxy0,lxy0,t59,t62):oe30
n@[o:neg(eta0)]
t64:=satz166b(ksi0,n):pos(abs(ksi0))
t65:=satz166b(eta0,o):pos(abs(eta0))
ixya:=is(abs(ksi0),abs(eta0)):'prop'
mxya:=more(abs(ksi0),abs(eta0)):'prop'
lxya:=less(abs(ksi0),abs(eta0)):'prop'
t66:=t8(abs(ksi0),abs(eta0),t64,t65):or3(ixya,mxya,lxya)
t67:=t19(abs(ksi0),abs(eta0),t64,t65):ec3(ixya,mxya,lxya)
[l:lxya]
t68:=moreinn(ksi0,eta0,n,o,l):mxy0
t69:=or3i2(ixy0,mxy0,lxy0,t68):o30
t70:=th3"l.imp"(ixy0,ixya,ec3e31(ixya,mxya,lxya,t67,l),[t:ixy0]isabs(ksi0,eta0,t)):not(ixy0)
t71:=th3"l.imp"(lxy0,mxya,ec3e32(ixya,mxya,lxya,t67,l),[t:lxy0]lessen1(ksi0,eta0,t,o)):not(lxy0)
t72:=ec3i3(ixy0,mxy0,lxy0,t71,t70):e30
t73:=orec3i(ixy0,mxy0,lxy0,t69,t72):oe30
o@[i:ixya]
t74:=satz166d(ksi0,eta0,n,o,i):ixy0
t75:=or3i1(ixy0,mxy0,lxy0,t74):o30
t76:=th3"l.imp"(mxy0,lxya,ec3e13(ixya,mxya,lxya,t67,i),[t:mxy0]moreen1(ksi0,eta0,t,n)):not(mxy0)
t77:=th3"l.imp"(lxy0,mxya,ec3e12(ixya,mxya,lxya,t67,i),[t:lxy0]lessen1(ksi0,eta0,t,o)):not(lxy0)
t78:=ec3i2(ixy0,mxy0,lxy0,t76,t77):e30
t79:=orec3i(ixy0,mxy0,lxy0,t75,t78):oe30
o@[m:mxya]
t80:=lessinn(ksi0,eta0,n,o,m):lxy0
t81:=or3i3(ixy0,mxy0,lxy0,t80):o30
t82:=th3"l.imp"(ixy0,ixya,ec3e21(ixya,mxya,lxya,t67,m),[t:ixy0]isabs(ksi0,eta0,t)):not(ixy0)
t83:=th3"l.imp"(mxy0,lxya,ec3e23(ixya,mxya,lxya,t67,m),[t:mxy0]moreen1(ksi0,eta0,t,n)):not(mxy0)
t84:=ec3i1(ixy0,mxy0,lxy0,t82,t83):e30
t85:=orec3i(ixy0,mxy0,lxy0,t81,t84):oe30
o@t86:=or3app(ixya,mxya,lxya,oe30,t66,[t:ixya]t79(t),[t:mxya]t85(t),[t:lxya]t73(t)):oe30
n@t87:=rlapp(eta0,oe30,[t:pos(eta0)]t57(t),[t:is(eta0,0)]t63(t),[t:neg(eta0)]t86(t)):oe30
-2167
eta0@satz167:=rlapp(ksi0,oe30".2167",[t:pos(ksi0)]t33".2167"(t),[t:is(ksi0,0)]t51".2167"(t),[t:neg(ksi0)]t87".2167"(t)):orec3(is(ksi0,eta0),more(ksi0,eta0),less(ksi0,eta0))
satz167a:=orec3e1(ixy0".2167",mxy0".2167",lxy0".2167",satz167):or3(is(ksi0,eta0),more(ksi0,eta0),less(ksi0,eta0))
satz167b:=orec3e2(ixy0".2167",mxy0".2167",lxy0".2167",satz167):ec3(is(ksi0,eta0),more(ksi0,eta0),less(ksi0,eta0))
moreis:=or(more(ksi0,eta0),is(ksi0,eta0)):'prop'
lessis:=or(less(ksi0,eta0),is(ksi0,eta0)):'prop'
[m:moreis(ksi0,eta0)]
satz168a:=th8"l.or"(more(ksi0,eta0),is(ksi0,eta0),is(eta0,ksi0),m,[t:is(ksi0,eta0)]symis(rl,ksi0,eta0,t)):lessis(eta0,ksi0)
eta0@[l:lessis(ksi0,eta0)]
satz168b:=th8"l.or"(less(ksi0,eta0),is(ksi0,eta0),is(eta0,ksi0),l,[t:is(ksi0,eta0)]symis(rl,ksi0,eta0,t)):moreis(eta0,ksi0)
eta0@[zeta0:rl][i:is(ksi0,eta0)][m:more(ksi0,zeta0)]
ismore1:=isp(rl,[x:rl]more(x,zeta0),ksi0,eta0,m,i):more(eta0,zeta0)
i@[m:more(zeta0,ksi0)]
ismore2:=isp(rl,[x:rl]more(zeta0,x),ksi0,eta0,m,i):more(zeta0,eta0)
i@[l:less(ksi0,zeta0)]
isless1:=ismore2(l):less(eta0,zeta0)
i@[l:less(zeta0,ksi0)]
isless2:=ismore1(l):less(zeta0,eta0)
i@[m:moreis(ksi0,zeta0)]
ismoreis1:=isp(rl,[x:rl]moreis(x,zeta0),ksi0,eta0,m,i):moreis(eta0,zeta0)
i@[m:moreis(zeta0,ksi0)]
ismoreis2:=isp(rl,[x:rl]moreis(zeta0,x),ksi0,eta0,m,i):moreis(zeta0,eta0)
i@[l:lessis(ksi0,zeta0)]
islessis1:=satz168a(zeta0,eta0,ismoreis2(satz168b(ksi0,zeta0,l))):lessis(eta0,zeta0)
i@[l:lessis(zeta0,ksi0)]
islessis2:=satz168a(eta0,zeta0,ismoreis1(satz168b(zeta0,ksi0,l))):lessis(zeta0,eta0)
eta0@[i:is(ksi0,eta0)]
moreisi2:=ori2(more(ksi0,eta0),is(ksi0,eta0),i):moreis(ksi0,eta0)
lessisi2:=ori2(less(ksi0,eta0),is(ksi0,eta0),i):lessis(ksi0,eta0)
eta0@[m:more(ksi0,eta0)]
moreisi1:=ori1(more(ksi0,eta0),is(ksi0,eta0),m):moreis(ksi0,eta0)
eta0@[l:less(ksi0,eta0)]
lessisi1:=ori1(less(ksi0,eta0),is(ksi0,eta0),l):lessis(ksi0,eta0)
zeta0@[upsilon0:rl][i:is(ksi0,eta0)][j:is(zeta0,upsilon0)][m:more(ksi0,zeta0)]
ismore12:=ismore2(zeta0,upsilon0,eta0,j,ismore1(ksi0,eta0,zeta0,i,m)):more(eta0,upsilon0)
j@[l:less(ksi0,zeta0)]
isless12:=ismore12(zeta0,upsilon0,ksi0,eta0,j,i,l):less(eta0,upsilon0)
j@[m:moreis(ksi0,zeta0)]
ismoreis12:=ismoreis2(zeta0,upsilon0,eta0,j,ismoreis1(ksi0,eta0,zeta0,i,m)):moreis(eta0,upsilon0)
j@[l:lessis(ksi0,zeta0)]
islessis12:=satz168a(upsilon0,eta0,ismoreis12(zeta0,upsilon0,ksi0,eta0,j,i,satz168b(ksi0,zeta0,l))):lessis(eta0,upsilon0)
eta0@[m:moreis(ksi0,eta0)]
satz167c:=th7"l.ec3"(is(ksi0,eta0),more(ksi0,eta0),less(ksi0,eta0),satz167b,comor(more(ksi0,eta0),is(ksi0,eta0),m)):not(less(ksi0,eta0))
eta0@[l:lessis(ksi0,eta0)]
satz167d:=th9"l.ec3"(is(ksi0,eta0),more(ksi0,eta0),less(ksi0,eta0),satz167b,l):not(more(ksi0,eta0))
eta0@[n:not(more(ksi0,eta0))]
satz167e:=th2"l.or3"(is(ksi0,eta0),more(ksi0,eta0),less(ksi0,eta0),satz167a,n):lessis(ksi0,eta0)
eta0@[n:not(less(ksi0,eta0))]
satz167f:=comor(is(ksi0,eta0),more(ksi0,eta0),th3"l.or3"(is(ksi0,eta0),more(ksi0,eta0),less(ksi0,eta0),satz167a,n)):moreis(ksi0,eta0)
eta0@[m:more(ksi0,eta0)]
satz167g:=th3"l.imp"(lessis(ksi0,eta0),not(more(ksi0,eta0)),weli(more(ksi0,eta0),m),[t:lessis(ksi0,eta0)]satz167d(t)):not(lessis(ksi0,eta0))
eta0@[l:less(ksi0,eta0)]
satz167h:=th3"l.imp"(moreis(ksi0,eta0),not(less(ksi0,eta0)),weli(less(ksi0,eta0),l),[t:moreis(ksi0,eta0)]satz167c(t)):not(moreis(ksi0,eta0))
eta0@[n:not(moreis(ksi0,eta0))]
satz167j:=or3e3(is(ksi0,eta0),more(ksi0,eta0),less(ksi0,eta0),satz167a,th5"l.or"(more(ksi0,eta0),is(ksi0,eta0),n),th4"l.or"(more(ksi0,eta0),is(ksi0,eta0),n)):less(ksi0,eta0)
eta0@[n:not(lessis(ksi0,eta0))]
satz167k:=or3e2(is(ksi0,eta0),more(ksi0,eta0),less(ksi0,eta0),satz167a,th4"l.or"(less(ksi0,eta0),is(ksi0,eta0),n),th5"l.or"(less(ksi0,eta0),is(ksi0,eta0),n)):more(ksi0,eta0)
ksi0@[p:pos(ksi0)]
satz169a:=moreip0(ksi0,0,p,refis(rl,0)):more(ksi0,0)
ksi0@[m:more(ksi0,0)]
satz169b:=moree02(ksi0,0,m,refis(rl,0)):pos(ksi0)
ksi0@[n:neg(ksi0)]
satz169c:=lessin0(ksi0,0,n,refis(rl,0)):less(ksi0,0)
ksi0@[l:less(ksi0,0)]
satz169d:=lesse02(ksi0,0,l,refis(rl,0)):neg(ksi0)
+2170
ksi0@[p:pos(ksi0)]
t1:=moreisi1(abs(ksi0),0,satz169a(abs(ksi0),satz166a(ksi0,p))):moreis(abs(ksi0),0)
ksi0@[i:is(ksi0,0)]
t2:=moreisi2(abs(ksi0),0,abs0(ksi0,i)):moreis(abs(ksi0),0)
ksi0@[n:neg(ksi0)]
t3:=moreisi1(abs(ksi0),0,satz169a(abs(ksi0),satz166b(ksi0,n))):moreis(abs(ksi0),0)
-2170
ksi0@satz170:=rlapp(ksi0,moreis(abs(ksi0),0),[t:pos(ksi0)]t1".2170"(t),[t:is(ksi0,0)]t2".2170"(t),[t:neg(ksi0)]t3".2170"(t)):moreis(abs(ksi0),0)
zeta0@[l:less(ksi0,eta0)][k:less(eta0,zeta0)]
+2171
[p:pos(zeta0)][q:pos(ksi0)]
t1:=lessep1a(ksi0,eta0,l,q):pos(eta0)
t2:=lessep2(ksi0,eta0,l,q,t1):less"rp"(rpofp(ksi0,q),rpofp(eta0,t1))
t3:=lessep2(eta0,zeta0,k,t1,p):less"rp"(rpofp(eta0,t1),rpofp(zeta0,p))
t4:=trless(rpofp(ksi0,q),rpofp(eta0,t1),rpofp(zeta0,p),t2,t3):less"rp"(rpofp(ksi0,q),rpofp(zeta0,p))
t5:=lessipp(ksi0,zeta0,q,p,t4):less(ksi0,zeta0)
p@[i:is(ksi0,0)]
t6:=lessi0p(ksi0,zeta0,i,p):less(ksi0,zeta0)
p@[n:neg(ksi0)]
t7:=lessinp(ksi0,zeta0,n,p):less(ksi0,zeta0)
p@t8:=rlapp(ksi0,less(ksi0,zeta0),[t:pos(ksi0)]t5(t),[t:is(ksi0,0)]t6(t),[t:neg(ksi0)]t7(t)):less(ksi0,zeta0)
k@[i:is(zeta0,0)]
t9:=lesse02(eta0,zeta0,k,i):neg(eta0)
t10:=lessen1a(ksi0,eta0,l,t9):neg(ksi0)
t11:=lessin0(ksi0,zeta0,t10,i):less(ksi0,zeta0)
k@[n:neg(zeta0)]
t11a:=lessen1a(eta0,zeta0,k,n):neg(eta0)
t12:=lessen1a(ksi0,eta0,l,t11a):neg(ksi0)
t13:=lessen1(ksi0,eta0,l,t11a):more(abs(ksi0),abs(eta0))
t14:=lessen1(eta0,zeta0,k,n):more(abs(eta0),abs(zeta0))
t15:=t5(abs(zeta0),abs(eta0),abs(ksi0),t14,t13,satz166b(ksi0,t12),satz166b(zeta0,n)):more(abs(ksi0),abs(zeta0))
t16:=lessinn(ksi0,zeta0,t12,n,t15):less(ksi0,zeta0)
-2171
satz171:=rlapp(zeta0,less(ksi0,zeta0),[t:pos(zeta0)]t8".2171"(t),[t:is(zeta0,0)]t11".2171"(t),[t:neg(zeta0)]t16".2171"(t)):less(ksi0,zeta0)
trless:=satz171:less(ksi0,zeta0)
zeta0@[m:more(ksi0,eta0)][n:more(eta0,zeta0)]
trmore:=trless(zeta0,eta0,ksi0,n,m):more(ksi0,zeta0)
zeta0@[l:lessis(ksi0,eta0)][k:less(eta0,zeta0)]
satz172a:=orapp(less(ksi0,eta0),is(ksi0,eta0),less(ksi0,zeta0),l,[t:less(ksi0,eta0)]trless(ksi0,eta0,zeta0,t,k),[t:is(ksi0,eta0)]isless1(eta0,ksi0,zeta0,symis(rl,ksi0,eta0,t),k)):less(ksi0,zeta0)
zeta0@[l:less(ksi0,eta0)][k:lessis(eta0,zeta0)]
satz172b:=orapp(less(eta0,zeta0),is(eta0,zeta0),less(ksi0,zeta0),k,[t:less(eta0,zeta0)]trless(ksi0,eta0,zeta0,l,t),[t:is(eta0,zeta0)]isless2(eta0,zeta0,ksi0,t,l)):less(ksi0,zeta0)
zeta0@[m:moreis(ksi0,eta0)][n:more(eta0,zeta0)]
satz172c:=satz172b(zeta0,eta0,ksi0,n,satz168a(ksi0,eta0,m)):more(ksi0,zeta0)
zeta0@[m:more(ksi0,eta0)][n:moreis(eta0,zeta0)]
satz172d:=satz172a(zeta0,eta0,ksi0,satz168a(eta0,zeta0,n),m):more(ksi0,zeta0)
zeta0@[l:lessis(ksi0,eta0)][k:lessis(eta0,zeta0)]
+2173
[i:is(ksi0,eta0)][j:is(eta0,zeta0)]
t1:=lessisi2(ksi0,zeta0,tris(rl,ksi0,eta0,zeta0,i,j)):lessis(ksi0,zeta0)
i@[m:less(eta0,zeta0)]
t2:=lessisi1(ksi0,zeta0,satz172a(ksi0,eta0,zeta0,l,m)):lessis(ksi0,zeta0)
i@t3:=orapp(less(eta0,zeta0),is(eta0,zeta0),lessis(ksi0,zeta0),k,[t:less(eta0,zeta0)]t2(t),[t:is(eta0,zeta0)]t1(t)):lessis(ksi0,zeta0)
k@[m:less(ksi0,eta0)]
t4:=lessisi1(ksi0,zeta0,satz172b(ksi0,eta0,zeta0,m,k)):lessis(ksi0,zeta0)
-2173
satz173:=orapp(less(ksi0,eta0),is(ksi0,eta0),lessis(ksi0,zeta0),l,[t:less(ksi0,eta0)]t4".2173"(t),[t:is(ksi0,eta0)]t3".2173"(t)):lessis(ksi0,zeta0)
trlessis:=satz173:lessis(ksi0,zeta0)
zeta0@[m:moreis(ksi0,eta0)][n:moreis(eta0,zeta0)]
trmoreis:=satz168b(zeta0,ksi0,trlessis(zeta0,eta0,ksi0,satz168a(eta0,zeta0,n),satz168a(ksi0,eta0,m))):moreis(ksi0,zeta0)
ksi0@ratrl1:=and(pos(ksi0),[t:pos(ksi0)]ratrp(rpofp(ksi0,t))):'prop'
ratrl2:=is(ksi0,0):'prop'
ratrl3:=and(neg(ksi0),ratrl1(abs(ksi0))):'prop'
ratrl:=or3(ratrl1,ratrl2,ratrl3):'prop'
[r:ratrl(ksi0)][p:pos(ksi0)]
+*iv2
p@t27:=th1"l.and"(neg(ksi0),ratrl1(abs(ksi0)),pnotn(ksi0,p)):not(ratrl3)
t28:=or3e1(ratrl1,ratrl2,ratrl3,r,pnot0(ksi0,p),t27):ratrl1
-iv2
p@ratrlep:=<p>ande2(pos(ksi0),[t:pos(ksi0)]ratrp(rpofp(ksi0,t)),t28".iv2"):ratrp(rpofp(ksi0,p))
r@[n:neg(ksi0)]
+*iv2
n@t29:=th1"l.and"(pos(ksi0),[t:pos(ksi0)]ratrp(rpofp(ksi0,t)),nnotp(ksi0,n)):not(ratrl1)
t30:=or3e3(ratrl1,ratrl2,ratrl3,r,t29,nnot0(ksi0,n)):ratrl3
t31:=ande2(neg(ksi0),ratrl1(abs(ksi0)),t30):ratrl1(abs(ksi0))
-iv2
n@ratrlen:=or3i1(ratrl1(abs(ksi0)),ratrl2(abs(ksi0)),ratrl3(abs(ksi0)),t31".iv2"):ratrl(abs(ksi0))
ksi0@[p:pos(ksi0)][r:ratrp(rpofp(ksi0,p))][q:pos(ksi0)]
+*iv2
q@t32:=isp(cut,[x:cut]ratrp(x),rpofp(ksi0,p),rpofp(ksi0,q),r,isperp(ksi0,p,ksi0,q,refis(rl,ksi0))):ratrp(rpofp(ksi0,q))
r@t33:=andi(pos(ksi0),[t:pos(ksi0)]ratrp(rpofp(ksi0,t)),p,[t:pos(ksi0)]t32(t)):ratrl1(ksi0)
-iv2
r@ratrlip:=or3i1(ratrl1,ratrl2,ratrl3,t33".iv2"):ratrl(ksi0)
ksi0@[i:is(ksi0,0)]
ratrli0:=or3i2(ratrl1,ratrl2,ratrl3,i):ratrl(ksi0)
ksi0@[n:neg(ksi0)][r:ratrl(abs(ksi0))]
+*iv2
r@t34:=t28(abs(ksi0),r,satz166b(ksi0,n)):ratrl1(abs(ksi0))
t35:=andi(neg(ksi0),ratrl1(abs(ksi0)),n,t34):ratrl3(ksi0)
-iv2
r@ratrlin:=or3i3(ratrl1,ratrl2,ratrl3,t35".iv2"):ratrl(ksi0)
ksi0@irratrl:=not(ratrl(ksi0)):'prop'
@[x0:rat]
pofrt:=pofrp(rpofrt(x0)):rl
posrt:=posi(rpofrt(x0)):pos(pofrt(x0))
[y0:rat][l:less"rt"(x0,y0)]
lessrtep:=lessipp(pofrt(x0),pofrt(y0),posrt(x0),posrt(y0),isless12"rp"(rpofrt(x0),rpofp(pofrt(x0),posrt(x0)),rpofrt(y0),rpofp(pofrt(y0),posrt(y0)),isrpp1(rpofrt(x0)),isrpp1(rpofrt(y0)),satz154c(x0,y0,l))):less(pofrt(x0),pofrt(y0))
y0@[l:less(pofrt(x0),pofrt(y0))]
lessrtip:=satz154f(x0,y0,isless12"rp"(rpofp(pofrt(x0),posrt(x0)),rpofrt(x0),rpofp(pofrt(y0),posrt(y0)),rpofrt(y0),isrpp2(rpofrt(x0)),isrpp2(rpofrt(y0)),lessep2(pofrt(x0),pofrt(y0),l,posrt(x0),posrt(y0)))):less"rt"(x0,y0)
-rl
+*rl
@[ksi:cut][r:ratrp(ksi)]
remark2:=ratrlip(pofrp(ksi),posi(ksi),isp(cut,[x:cut]ratrp(x),ksi,rpofp(pofrp(ksi),posi(ksi)),r,isrpp1(ksi))):ratrl(pofrp(ksi))
remark3:=ratrlin(nofrp(ksi),negi(ksi),isp(rl,[x:rl]ratrl(x),pofrp(ksi),abs(nofrp(ksi)),remark2,tris2(rl,pofrp(ksi),abs(nofrp(ksi)),pofn(nofrp(ksi),negi(ksi)),ispofnrp2(ksi),absn(nofrp(ksi),negi(ksi))))):ratrl(nofrp(ksi))
ksi@[i:irratrp(ksi)]
remark4:=th3"l.imp"(ratrl(pofrp(ksi)),ratrp(ksi),i,[t:ratrl(pofrp(ksi))]isp(cut,[x:cut]ratrp(x),rpofp(pofrp(ksi),posi(ksi)),ksi,ratrlep(pofrp(ksi),t,posi(ksi)),isrpp2(ksi))):irratrl(pofrp(ksi))
remark5:=th3"l.imp"(ratrl(nofrp(ksi)),ratrl(abs(nofrp(ksi))),isp(rl,[x:rl]irratrl(x),pofrp(ksi),abs(nofrp(ksi)),remark4,tris2(rl,pofrp(ksi),abs(nofrp(ksi)),pofn(nofrp(ksi),negi(ksi)),ispofnrp2(ksi),absn(nofrp(ksi),negi(ksi)))),[t:ratrl(nofrp(ksi))]ratrlen(nofrp(ksi),t,negi(ksi))):irratrl(nofrp(ksi))
ksi0@intrl1:=and(pos(ksi0),[t:pos(ksi0)]natrp(rpofp(ksi0,t))):'prop'
intrl2:=is(ksi0,0):'prop'
intrl3:=and(neg(ksi0),intrl1(abs(ksi0))):'prop'
intrl:=or3(intrl1,intrl2,intrl3):'prop'
[i:intrl(ksi0)][p:pos(ksi0)]
+*iv2
p@t45:=th1"l.and"(neg(ksi0),intrl1(abs(ksi0)),pnotn(ksi0,p)):not(intrl3)
t46:=or3e1(intrl1,intrl2,intrl3,i,pnot0(ksi0,p),t45):intrl1
-iv2
p@intrlep:=<p>ande2(pos(ksi0),[t:pos(ksi0)]natrp(rpofp(ksi0,t)),t46".iv2"):natrp(rpofp(ksi0,p))
i@[n:neg(ksi0)]
+*iv2
n@t47:=th1"l.and"(pos(ksi0),[t:pos(ksi0)]natrp(rpofp(ksi0,t)),nnotp(ksi0,n)):not(intrl1)
t48:=or3e3(intrl1,intrl2,intrl3,i,t47,nnot0(ksi0,n)):intrl3
t49:=ande2(neg(ksi0),intrl1(abs(ksi0)),t48):intrl1(abs(ksi0))
-iv2
n@intrlen:=or3i1(intrl1(abs(ksi0)),intrl2(abs(ksi0)),intrl3(abs(ksi0)),t49".iv2"):intrl(abs(ksi0))
ksi0@[p:pos(ksi0)][n:natrp(rpofp(ksi0,p))][q:pos(ksi0)]
+*iv2
q@t50:=isp(cut,[x:cut]natrp(x),rpofp(ksi0,p),rpofp(ksi0,q),n,isperp(ksi0,p,ksi0,q,refis(rl,ksi0))):natrp(rpofp(ksi0,q))
n@t51:=andi(pos(ksi0),[t:pos(ksi0)]natrp(rpofp(ksi0,t)),p,[t:pos(ksi0)]t50(t)):intrl1(ksi0)
-iv2
n@intrlip:=or3i1(intrl1,intrl2,intrl3,t51".iv2"):intrl(ksi0)
ksi0@[i:is(ksi0,0)]
intrli0:=or3i2(intrl1,intrl2,intrl3,i):intrl(ksi0)
ksi0@[n:neg(ksi0)][i:intrl(abs(ksi0))]
+*iv2
i@t52:=t46(abs(ksi0),i,satz166b(ksi0,n)):intrl1(abs(ksi0))
t53:=andi(neg(ksi0),intrl1(abs(ksi0)),n,t52):intrl3(ksi0)
-iv2
i@intrlin:=or3i3(intrl1,intrl2,intrl3,t53".iv2"):intrl(ksi0)
ksi0@[i:intrl(ksi0)]
+2174
[p:pos(ksi0)]
t1:=lemmaiii5(rpofp(ksi0,p),intrlep(ksi0,i,p)):ratrp(rpofp(ksi0,p))
t2:=ratrlip(ksi0,p,t1):ratrl(ksi0)
i@[j:is(ksi0,0)]
t3:=ratrli0(ksi0,j):ratrl(ksi0)
i@[n:neg(ksi0)]
t4:=t2(abs(ksi0),intrlen(ksi0,i,n),satz166b(ksi0,n)):ratrl(abs(ksi0))
t5:=ratrlin(ksi0,n,t4):ratrl(ksi0)
-2174
satz174:=rlapp(ksi0,ratrl(ksi0),[t:pos(ksi0)]t2".2174"(t),[t:is(ksi0,0)]t3".2174"(t),[t:neg(ksi0)]t5".2174"(t)):ratrl(ksi0)
ksi0@[p:pos(ksi0)]
+iv3
ksi:=rpofp(ksi0,p):cut
-iv3
eta0@[p:pos(eta0)]
+*iv3
p@eta:=rpofp(eta0,p):cut
-iv3
zeta0@[p:pos(zeta0)]
+*iv3
p@zeta:=rpofp(zeta0,p):cut
-iv3
upsilon0@[p:pos(upsilon0)]
+*iv3
p@upsilon:=rpofp(upsilon0,p):cut
-iv3
eta0@[p:pos(ksi0)][q:pos(eta0)][m:more(ksi0,eta0)]
+*iv3
m@t1:=moreep2(ksi0,eta0,m,p,q):more"rp"(ksi(p),eta(q))
-iv3
m@mna:=pofrp(mn(ksi".iv3"(p),eta".iv3"(q),t1".iv3")):rl
+*iv3
m@t2:=posi(mn(ksi(p),eta(q),t1)):pos(mna(ksi0,eta0,p,q,m))
-iv3
upsilon0@[i:is(ksi0,eta0)][j:is(zeta0,upsilon0)][p:pos(ksi0)][r:pos(zeta0)][m:more(ksi0,zeta0)][q:pos(eta0)][s:pos(upsilon0)][n:more(eta0,upsilon0)]
+*iv3
n@t2a:=isrpep(mn(ksi(p),zeta(r),t1(ksi0,zeta0,p,r,m)),mn(eta(q),upsilon(s),t1(eta0,upsilon0,q,s,n)),ismn12(ksi(p),eta(q),zeta(r),upsilon(s),t1(ksi0,zeta0,p,r,m),t1(eta0,upsilon0,q,s,n),isperp(ksi0,p,eta0,q,i),isperp(zeta0,r,upsilon0,s,j))):is(mna(ksi0,zeta0,p,r,m),mna(eta0,upsilon0,q,s,n))
-iv3
n@ismna12:=t2a".iv3":is(mna(ksi0,zeta0,p,r,m),mna(eta0,upsilon0,q,s,n))
eta0@[p:pos(ksi0)][q:pos(eta0)][m:more(ksi0,eta0)][r:pos(ksi0)]
+*iv3
r@t3a:=ismna12(ksi0,ksi0,eta0,eta0,refis(rl,ksi0),refis(rl,eta0),p,q,m,r,q,m):is(mna(ksi0,eta0,p,q,m),mna(ksi0,eta0,r,q,m))
-iv3
m@[r:pos(eta0)]
+*iv3
r@t3b:=ismna12(ksi0,ksi0,eta0,eta0,refis(rl,ksi0),refis(rl,eta0),p,q,m,p,r,m):is(mna(ksi0,eta0,p,q,m),mna(ksi0,eta0,p,r,m))
-iv3
m@[n:more(ksi0,eta0)]
+*iv3
n@t3c:=ismna12(ksi0,ksi0,eta0,eta0,refis(rl,ksi0),refis(rl,eta0),p,q,m,p,q,n):is(mna(ksi0,eta0,p,q,m),mna(ksi0,eta0,p,q,n))
-iv3
q@pl1a:=pofrp(pl(ksi".iv3"(p),eta".iv3"(q))):rl
+*iv3
q@t3d:=posi(pl(ksi(p),eta(q))):pos(pl1a)
-iv3
q@[r:pos(eta0)]
+*iv3
r@t4:=isrpep(pl(ksi(p),eta(q)),pl(ksi(p),eta(r)),ispl2(eta(q),eta(r),ksi(p),isperp(eta0,q,eta0,r,refis(rl,eta0)))):is(pl1a(q),pl1a(r))
eta0@py:=pos(eta0):'prop'
-iv3
p@pl1b:=ite"l.r"(py".iv3",rl,[t:py".iv3"]pl1a(t),[t:not(py".iv3")]ksi0,[t:py".iv3"][u:py".iv3"]t4".iv3"(t,u),[t:not(py".iv3")][u:not(py".iv3")]refis(rl,ksi0)):rl
+*iv3
q@t5:=itet"l.r"(py,rl,[t:py]pl1a(t),[t:not(py)]ksi0,[t:py][u:py]t4(t,u),[t:not(py)][u:not(py)]refis(rl,ksi0),q):is(pl1b,pl1a(q))
-iv3
p@[n:not(pos(eta0))]
+*iv3
n@t6:=itef"l.r"(py,rl,[t:py]pl1a(t),[t:not(py)]ksi0,[t:py][u:py]t4(t,u),[t:not(py)][u:not(py)]refis(rl,ksi0),n):is(pl1b,ksi0)
-iv3
p@[n:neg(eta0)][m:more(ksi0,abs(eta0))]
pl1c:=mna(ksi0,abs(eta0),p,satz166b(eta0,n),m):rl
[o:more(ksi0,abs(eta0))]
+*iv3
o@t7:=t3c(ksi0,abs(eta0),p,satz166b(eta0,n),m,o):is(pl1c(m),pl1c(o))
eta0@mxa:=more(ksi0,abs(eta0)):'prop'
-iv3
n@pl1d:=ite"l.r"(mxa".iv3",rl,[t:mxa".iv3"]pl1c(t),[t:not(mxa".iv3")]0,[t:mxa".iv3"][u:mxa".iv3"]t7".iv3"(t,u),[t:not(mxa".iv3")][y:not(mxa".iv3")]refis(rl,0)):rl
+*iv3
m@t8:=itet"l.r"(mxa,rl,[t:mxa]pl1c(t),[t:not(mxa)]0,[t:mxa][u:mxa]t7(t,u),[t:not(mxa)][u:not(mxa)]refis(rl,0),m):is(pl1d,pl1c(m))
-iv3
n@[o:not(more(ksi0,abs(eta0)))]
+*iv3
o@t9:=itef"l.r"(mxa,rl,[t:mxa]pl1c(t),[t:not(mxa)]0,[t:mxa][u:mxa]t7(t,u),[t:not(mxa)][u:not(mxa)]refis(rl,0),o):is(pl1d,0)
-iv3
n@[l:less(ksi0,abs(eta0))]
pl1e:=mn0a(mna(abs(eta0),ksi0,satz166b(eta0,n),p,l),t2".iv3"(abs(eta0),ksi0,satz166b(eta0,n),p,l)):rl
[k:less(ksi0,abs(eta0))]
+*iv3
k@t10:=ispen(mna(abs(eta0),ksi0,satz166b(eta0,n),p,l),t2(abs(eta0),ksi0,satz166b(eta0,n),p,l),mna(abs(eta0),ksi0,satz166b(eta0,n),p,k),t2(abs(eta0),ksi0,satz166b(eta0,n),p,k),t3c(abs(eta0),ksi0,satz166b(eta0,n),p,l,k)):is(pl1e(l),pl1e(k))
eta0@lxa:=less(ksi0,abs(eta0)):'prop'
-iv3
n@pl1f:=ite"l.r"(lxa".iv3",rl,[t:lxa".iv3"]pl1e(t),[t:not(lxa".iv3")]pl1d,[t:lxa".iv3"][u:lxa".iv3"]t10".iv3"(t,u),[t:not(lxa".iv3")][u:not(lxa".iv3")]refis(rl,pl1d)):rl
+*iv3
l@t11:=itet"l.r"(lxa,rl,[t:lxa]pl1e(t),[t:not(lxa)]pl1d,[t:lxa][u:lxa]t10(t,u),[t:not(lxa)][u:not(lxa)]refis(rl,pl1d),l):is(pl1f,pl1e(l))
-iv3
n@[o:not(less(ksi0,abs(eta0)))]
+*iv3
o@t12:=itef"l.r"(lxa,rl,[t:lxa]pl1e(t),[t:not(lxa)]pl1d,[t:lxa][u:lxa]t10(t,u),[t:not(lxa)][u:not(lxa)]refis(rl,pl1d),o):is(pl1f,pl1d)
-iv3
n@[o:neg(eta0)][m:more(ksi0,abs(eta0))]
+*iv3
m@t13:=ec3e23(is(ksi0,abs(eta0)),mxa,lxa,satz167b(ksi0,abs(eta0)),m):not(lxa)
t14:=tris(rl,pl1f,pl1d,pl1c(m),t12(t13),t8(m)):is(pl1f,pl1c(m))
t15:=tr3is(rl,pl1f,pl1c(m),pl1c(o,m),pl1f(o),t14,t3b(ksi0,abs(eta0),p,satz166b(eta0,n),m,satz166b(eta0,o)),symis(rl,pl1f(o),pl1c(o,m),t14(o,n,m))):is(pl1f(n),pl1f(o))
-iv3
o@[i:is(ksi0,abs(eta0))]
+*iv3
i@t16:=ec3e12(is(ksi0,abs(eta0)),mxa,lxa,satz167b(ksi0,abs(eta0)),i):not(mxa)
t17:=ec3e13(is(ksi0,abs(eta0)),mxa,lxa,satz167b(ksi0,abs(eta0)),i):not(lxa)
t18:=tris(rl,pl1f,pl1d,0,t12(t17),t9(t16)):is(pl1f,0)
t19:=tris2(rl,pl1f,pl1f(o),0,t18,t18(o,n,i)):is(pl1f(n),pl1f(o))
-iv3
o@[l:less(ksi0,abs(eta0))]
+*iv3
l@t20:=ec3e32(is(ksi0,abs(eta0)),mxa,lxa,satz167b(ksi0,abs(eta0)),l):not(mxa)
t21:=tr3is(rl,pl1f,pl1e(l),pl1e(o,l),pl1f(o),t11(l),ispen(mna(abs(eta0),ksi0,satz166b(eta0,n),p,l),t2(abs(eta0),ksi0,satz166b(eta0,n),p,l),mna(abs(eta0),ksi0,satz166b(eta0,o),p,l),t2(abs(eta0),ksi0,satz166b(eta0,o),p,l),t3a(abs(eta0),ksi0,satz166b(eta0,n),p,l,satz166b(eta0,o))),symis(rl,pl1f(o),pl1e(o,l),t11(o,l))):is(pl1f(n),pl1f(o))
o@t22:=or3app(is(ksi0,abs(eta0)),mxa,lxa,is(pl1f(n),pl1f(o)),satz167a(ksi0,abs(eta0)),[t:is(ksi0,abs(eta0))]t19(t),[t:mxa]t15(t),[t:lxa]t21(t)):is(pl1f(n),pl1f(o))
eta0@ny:=neg(eta0):'prop'
-iv3
p@pl1:=ite"l.r"(ny".iv3",rl,[t:ny".iv3"]pl1f(t),[t:not(ny".iv3")]pl1b,[t:ny".iv3"][u:ny".iv3"]t22".iv3"(t,u),[t:not(ny".iv3")][u:not(ny".iv3")]refis(rl,pl1b)):rl
+*iv3
n@t23:=itet"l.r"(ny,rl,[t:ny]pl1f(t),[t:not(ny)]pl1b,[t:ny][u:ny]t22(t,u),[t:not(ny)][u:not(ny)]refis(rl,pl1b),n):is(pl1,pl1f(n))
-iv3
p@[n:not(neg(eta0))]
+*iv3
n@t24:=itef"l.r"(ny,rl,[t:ny]pl1f(t),[t:not(ny)]pl1b,[t:ny][u:ny]t22(t,u),[t:not(ny)][u:not(ny)]refis(rl,pl1b),n):is(pl1,pl1b)
-iv3
p@[q:pos(ksi0)][r:pos(eta0)]
+*iv3
r@t25:=tris(rl,pl1,pl1b,pl1a(r),t24(pnotn(eta0,r)),t5(r)):is(pl1,pl1a(r))
t26:=isrpep(pl(ksi(p),eta(r)),pl(ksi(q),eta(r)),ispl1(ksi(p),ksi(q),eta(r),isperp(ksi0,p,ksi0,q,refis(rl,ksi0)))):is(pl1a(p,r),pl1a(q,r))
t27:=tr3is(rl,pl1(p),pl1a(p,r),pl1a(q,r),pl1(q),t25,t26,symis(rl,pl1(q),pl1a(q,r),t25(q,p,r))):is(pl1(p),pl1(q))
-iv3
q@[i:is(eta0,0)]
+*iv3
i@t28:=tris(rl,pl1,pl1b,ksi0,t24(0notn(eta0,i)),t6(0notp(eta0,i))):is(pl1,ksi0)
t29:=tris2(rl,pl1(p),pl1(q),ksi0,t28,t28(q,p,i)):is(pl1(p),pl1(q))
-iv3
q@[n:neg(eta0)][m:more(ksi0,abs(eta0))]
+*iv3
m@t30:=tr3is(rl,pl1f(p,n),pl1c(p,n,m),pl1c(q,n,m),pl1f(q,n),t14(p,n,n,m),t3a(ksi0,abs(eta0),p,satz166b(eta0,n),m,q),symis(rl,pl1f(q,n),pl1c(q,n,m),t14(q,n,n,m))):is(pl1f(p,n),pl1f(q,n))
-iv3
n@[i:is(ksi0,abs(eta0))]
+*iv3
i@t31:=tris2(rl,pl1f(p,n),pl1f(q,n),0,t18(p,n,n,i),t18(q,n,n,i)):is(pl1f(p,n),pl1f(q,n))
-iv3
n@[l:less(ksi0,abs(eta0))]
+*iv3
l@t32:=ispen(mna(abs(eta0),ksi0,satz166b(eta0,n),p,l),t2(abs(eta0),ksi0,satz166b(eta0,n),p,l),mna(abs(eta0),ksi0,satz166b(eta0,n),q,l),t2(abs(eta0),ksi0,satz166b(eta0,n),q,l),t3b(abs(eta0),ksi0,satz166b(eta0,n),p,l,q)):is(pl1e(p,n,l),pl1e(q,n,l))
t33:=tr3is(rl,pl1f(p,n),pl1e(p,n,l),pl1e(q,n,l),pl1f(q,n),t11(n,l),t32,symis(rl,pl1f(q,n),pl1e(q,n,l),t11(q,n,l))):is(pl1f(p,n),pl1f(q,n))
n@t34:=or3app(is(ksi0,abs(eta0)),mxa,lxa,is(pl1f(p,n),pl1f(q,n)),satz167a(ksi0,abs(eta0)),[t:is(ksi0,abs(eta0))]t31(t),[t:mxa]t30(t),[t:lxa]t33(t)):is(pl1f(p,n),pl1f(q,n))
t35:=tr3is(rl,pl1(p),pl1f(p,n),pl1f(q,n),pl1(q),t23(n),t34,symis(rl,pl1(q),pl1f(q,n),t23(q,n))):is(pl1(p),pl1(q))
q@t36:=rlapp(eta0,is(pl1(p),pl1(q)),[t:pos(eta0)]t27(t),[t:is(eta0,0)]t29(t),[t:neg(eta0)]t35(t)):is(pl1(p),pl1(q))
ksi0@px:=pos(ksi0):'prop'
-iv3
eta0@pl2:=ite"l.r"(px".iv3",rl,[t:px".iv3"]pl1(t),[t:not(px".iv3")]eta0,[t:px".iv3"][u:px".iv3"]t36".iv3"(t,u),[t:not(px".iv3")][u:not(px".iv3")]refis(rl,eta0)):rl
+*iv3
p@t37:=itet"l.r"(px,rl,[t:px]pl1(t),[t:not(px)]eta0,[t:px][u:px]t36(t,u),[t:not(px)][u:not(px)]refis(rl,eta0),p):is(pl2,pl1(p))
-iv3
eta0@[n:not(pos(ksi0))]
+*iv3
n@t38:=itef"l.r"(px,rl,[t:px]pl1(t),[t:not(px)]eta0,[t:px][u:px]t36(t,u),[t:not(px)][u:not(px)]refis(rl,eta0),n):is(pl2,eta0)
-iv3
eta0@[n:neg(ksi0)]
pl3a:=ite"l.r"(py".iv3",rl,[t:py".iv3"]pl1f(eta0,ksi0,t,n),[t:not(py".iv3")]ksi0,[t:py".iv3"][u:py".iv3"]t34".iv3"(eta0,ksi0,t,u,n),[t:not(py".iv3")][u:not(py".iv3")]refis(rl,ksi0)):rl
[p:pos(eta0)]
+*iv3
p@t39:=itet"l.r"(py,rl,[t:py]pl1f(eta0,ksi0,t,n),[t:not(py)]ksi0,[t:py][u:py]t34(eta0,ksi0,t,u,n),[t:not(py)][u:not(py)]refis(rl,ksi0),p):is(pl3a,pl1f(eta0,ksi0,p,n))
-iv3
n@[o:not(pos(eta0))]
+*iv3
o@t40:=itef"l.r"(py,rl,[t:py]pl1f(eta0,ksi0,t,n),[t:not(py)]ksi0,[t:py][u:py]t34(eta0,ksi0,t,u,n),[t:not(py)][u:not(py)]refis(rl,ksi0),o):is(pl3a,ksi0)
ksi0@xa:=abs(ksi0):rl
n@pxa:=satz166b(ksi0,n):pos(xa)
-iv3
n@[o:neg(eta0)]
+*iv3
eta0@ya:=abs(eta0):rl
o@pya:=satz166b(eta0,o):pos(ya)
-iv3
o@pl3b:=mn0a(pl1a(xa".iv3",ya".iv3",pxa".iv3",pya".iv3"),t3d".iv3"(xa".iv3",ya".iv3",pxa".iv3",pya".iv3")):rl
[p:neg(eta0)]
+*iv3
p@qya:=satz166b(eta0,p):pos(ya)
t41:=ispen(pl1a(xa,ya,pxa,pya),t3d(xa,ya,pxa,pya),pl1a(xa,ya,pxa,qya),t3d(xa,ya,pxa,qya),t4(xa,ya,pxa,pya,qya)):is(pl3b(o),pl3b(p))
-iv3
n@pl3:=ite"l.r"(ny".iv3",rl,[t:ny".iv3"]pl3b(t),[t:not(ny".iv3")]pl3a,[t:ny".iv3"][u:ny".iv3"]t41".iv3"(t,u),[t:not(ny".iv3")][u:not(ny".iv3")]refis(rl,pl3a)):rl
+*iv3
o@t42:=itet"l.r"(ny,rl,[t:ny]pl3b(t),[t:not(ny)]pl3a,[t:ny][u:ny]t41(t,u),[t:not(ny)][u:not(ny)]refis(rl,pl3a),o):is(pl3,pl3b(o))
-iv3
n@[o:not(neg(eta0))]
+*iv3
o@t43:=itef"l.r"(ny,rl,[t:ny]pl3b(t),[t:not(ny)]pl3a,[t:ny][u:ny]t41(t,u),[t:not(ny)][u:not(ny)]refis(rl,pl3a),o):is(pl3,pl3a)
-iv3
n@[o:neg(ksi0)]
+*iv3
o@qxa:=satz166b(ksi0,o):pos(xa)
-iv3
o@[p:pos(eta0)]
+*iv3
p@t44:=tris(rl,pl3,pl3a,pl1f(eta0,ksi0,p,n),t43(pnotn(eta0,p)),t39(p)):is(pl3,pl1f(eta0,ksi0,p,n))
t45:=tr3is(rl,pl3(n),pl1f(eta0,ksi0,p,n),pl1f(eta0,ksi0,p,o),pl3(o),t44,t22(eta0,ksi0,p,n,o),symis(rl,pl3(o),pl1f(eta0,ksi0,p,o),t44(o,n,p))):is(pl3(n),pl3(o))
-iv3
o@[i:is(eta0,0)]
+*iv3
i@t46:=tris(rl,pl3,pl3a,ksi0,t43(0notn(eta0,i)),t40(0notp(eta0,i))):is(pl3,ksi0)
t47:=tris2(rl,pl3(n),pl3(o),ksi0,t46,t46(o,n,i)):is(pl3(n),pl3(o))
-iv3
o@[p:neg(eta0)]
+*iv3
p@rya:=satz166b(eta0,p):pos(ya)
t48:=tr3is(rl,pl3(n),pl3b(n,p),pl3b(o,p),pl3(o),t42(p),ispen(pl1a(xa,ya,pxa,rya),t3d(xa,ya,pxa,rya),pl1a(xa,ya,qxa,rya),t3d(xa,ya,qxa,rya),t26(xa,ya,pxa,qxa,rya)),symis(rl,pl3(o),pl3b(o,p),t42(o,p))):is(pl3(n),pl3(o))
o@t49:=rlapp(eta0,is(pl3(n),pl3(o)),[t:pos(eta0)]t45(t),[t:is(eta0,0)]t47(t),[t:neg(eta0)]t48(t)):is(pl3(n),pl3(o))
ksi0@nx:=neg(ksi0):'prop'
-iv3
eta0@pl:=ite"l.r"(nx".iv3",rl,[t:nx".iv3"]pl3(t),[t:not(nx".iv3")]pl2,[t:nx".iv3"][u:nx".iv3"]t49".iv3"(t,u),[t:not(nx".iv3")][u:not(nx".iv3")]refis(rl,pl2)):rl
+*iv3
n@t50:=itet"l.r"(nx,rl,[t:nx]pl3(t),[t:not(nx)]pl2,[t:nx][u:nx]t49(t,u),[t:not(nx)][u:not(nx)]refis(rl,pl2),n):is(pl,pl3(n))
-iv3
eta0@[n:not(neg(ksi0))]
+*iv3
n@t51:=itef"l.r"(nx,rl,[t:nx]pl3(t),[t:not(nx)]pl2,[t:nx][u:nx]t49(t,u),[t:not(nx)][u:not(nx)]refis(rl,pl2),n):is(pl,pl2)
-iv3
eta0@[p:pos(ksi0)][q:pos(eta0)]
plpp:=tr3is(rl,pl,pl2,pl1(p),pl1a(p,q),t51".iv3"(pnotn(ksi0,p)),t37".iv3"(p),t25".iv3"(p,p,q)):is(pl(ksi0,eta0),pofrp(pl"rp"(rpofp(ksi0,p),rpofp(eta0,q))))
pospl:=isp1(rl,[x:rl]pos(x),pl1a(p,q),pl(ksi0,eta0),t3d".iv3"(p,q),plpp):pos(pl(ksi0,eta0))
p@[n:neg(eta0)]
plpn0:=tr3is(rl,pl,pl2,pl1(p),pl1f(p,n),t51".iv3"(pnotn(ksi0,p)),t37".iv3"(p),t23".iv3"(p,n)):is(pl(ksi0,eta0),pl1f(ksi0,eta0,p,n))
[m:more(ksi0,abs(eta0))]
plpn1:=tris(rl,pl,pl1f(p,n),pl1c(p,n,m),plpn0,t14".iv3"(p,n,n,m)):is(pl(ksi0,eta0),mna(ksi0,abs(eta0),p,satz166b(eta0,n),m))
n@[i:is(ksi0,abs(eta0))]
plpn2:=tris(rl,pl,pl1f(p,n),0,plpn0,t18".iv3"(p,n,n,i)):is(pl(ksi0,eta0),0)
n@[l:less(ksi0,abs(eta0))]
plpn3:=tris(rl,pl,pl1f(p,n),pl1e(p,n,l),plpn0,t11".iv3"(p,n,l)):is(pl(ksi0,eta0),mn0a(mna(abs(eta0),ksi0,satz166b(eta0,n),p,l),t2".iv3"(abs(eta0),ksi0,satz166b(eta0,n),p,l)))
eta0@[n:neg(ksi0)][p:pos(eta0)]
plnp0:=tris(rl,pl,pl3(n),pl1f(eta0,ksi0,p,n),t50".iv3"(n),t44".iv3"(n,n,p)):is(pl(ksi0,eta0),pl1f(eta0,ksi0,p,n))
n@[o:neg(eta0)]
+*iv3
o@t52:=tris(rl,pl,pl3(n),pl3b(n,o),t50(n),t42(n,o)):is(pl,pl3b(n,o))
t53:=ispen(pl(xa,ya),pospl(xa,ya,satz166b(ksi0,n),satz166b(eta0,o)),pl1a(xa,ya,satz166b(ksi0,n),satz166b(eta0,o)),t3d(xa,ya,satz166b(ksi0,n),satz166b(eta0,o)),plpp(xa,ya,satz166b(ksi0,n),satz166b(eta0,o))):is(mn0a(pl(xa,ya),pospl(xa,ya,satz166b(ksi0,n),satz166b(eta0,o))),pl3b(n,o))
-iv3
o@plnn:=tris2(rl,pl,mn0a(pl(abs(ksi0),abs(eta0)),pospl(abs(ksi0),abs(eta0),satz166b(ksi0,n),satz166b(eta0,o))),pl3b(n,o),t52".iv3",t53".iv3"):is(pl(ksi0,eta0),mn0a(pl(abs(ksi0),abs(eta0)),pospl(abs(ksi0),abs(eta0),satz166b(ksi0,n),satz166b(eta0,o))))
eta0@[i:is(ksi0,0)]
pl01:=tris(rl,pl,pl2,eta0,t51".iv3"(0notn(ksi0,i)),t38".iv3"(0notp(ksi0,i))):is(pl(ksi0,eta0),eta0)
eta0@[i:is(eta0,0)][p:pos(ksi0)]
+*iv3
p@t54:=tr4is(rl,pl,pl2,pl1(p),pl1b(p),ksi0,t51(pnotn(ksi0,p)),t37(p),t24(p,0notn(eta0,i)),t6(p,0notp(eta0,i))):is(pl(ksi0,eta0),ksi0)
-iv3
i@[j:is(ksi0,0)]
+*iv3
j@t55:=tr3is(rl,pl,eta0,0,ksi0,pl01(j),i,symis(rl,ksi0,0,j)):is(pl(ksi0,eta0),ksi0)
-iv3
i@[n:neg(ksi0)]
+*iv3
n@t56:=tr3is(rl,pl,pl3(n),pl3a(n),ksi0,t50(n),t43(n,0notn(eta0,i)),t40(n,0notp(eta0,i))):is(pl(ksi0,eta0),ksi0)
-iv3
i@pl02:=rlapp(ksi0,is(pl(ksi0,eta0),ksi0),[t:pos(ksi0)]t54".iv3"(t),[t:is(ksi0,0)]t55".iv3"(t),[t:neg(ksi0)]t56".iv3"(t)):is(pl(ksi0,eta0),ksi0)
zeta0@[i:is(ksi0,eta0)]
ispl1:=isf(rl,rl,[x:rl]pl(x,zeta0),ksi0,eta0,i):is(pl(ksi0,zeta0),pl(eta0,zeta0))
ispl2:=isf(rl,rl,[x:rl]pl(zeta0,x),ksi0,eta0,i):is(pl(zeta0,ksi0),pl(zeta0,eta0))
upsilon0@[i:is(ksi0,eta0)][j:is(zeta0,upsilon0)]
ispl12:=tris(rl,pl(ksi0,zeta0),pl(eta0,zeta0),pl(eta0,upsilon0),ispl1(ksi0,eta0,zeta0,i),ispl2(zeta0,upsilon0,eta0,j)):is(pl(ksi0,zeta0),pl(eta0,upsilon0))
+3175
eta0@[p:pos(ksi0)][q:pos(eta0)]
ksi:=rpofp(ksi0,p):cut
eta:=rpofp(eta0,q):cut
t1:=satz130(ksi,eta):is"rp"(pl"rp"(ksi,eta),pl"rp"(eta,ksi))
t2:=isrpep(pl"rp"(ksi,eta),pl"rp"(eta,ksi),t1):is(pl1a(ksi0,eta0,p,q),pl1a(eta0,ksi0,q,p))
t3:=tr3is(rl,pl(ksi0,eta0),pl1a(ksi0,eta0,p,q),pl1a(eta0,ksi0,q,p),pl(eta0,ksi0),plpp(ksi0,eta0,p,q),t2,symis(rl,pl(eta0,ksi0),pl1a(eta0,ksi0,q,p),plpp(eta0,ksi0,q,p))):is(pl(ksi0,eta0),pl(eta0,ksi0))
eta0@[i:is(eta0,0)]
t4:=tris2(rl,pl(ksi0,eta0),pl(eta0,ksi0),ksi0,pl02(ksi0,eta0,i),pl01(eta0,ksi0,i)):is(pl(ksi0,eta0),pl(eta0,ksi0))
p@[n:neg(eta0)]
t5:=tris2(rl,pl(ksi0,eta0),pl(eta0,ksi0),pl1f(ksi0,eta0,p,n),plpn0(ksi0,eta0,p,n),plnp0(eta0,ksi0,n,p)):is(pl(ksi0,eta0),pl(eta0,ksi0))
p@t6:=rlapp(eta0,is(pl(ksi0,eta0),pl(eta0,ksi0)),[t:pos(eta0)]t3(t),[t:is(eta0,0)]t4(t),[t:neg(eta0)]t5(t)):is(pl(ksi0,eta0),pl(eta0,ksi0))
eta0@[i:is(ksi0,0)]
t7:=tris2(rl,pl(ksi0,eta0),pl(eta0,ksi0),eta0,pl01(ksi0,eta0,i),pl02(eta0,ksi0,i)):is(pl(ksi0,eta0),pl(eta0,ksi0))
eta0@[n:neg(ksi0)][p:pos(eta0)]
t8:=symis(rl,pl(eta0,ksi0),pl(ksi0,eta0),t5(eta0,ksi0,p,n)):is(pl(ksi0,eta0),pl(eta0,ksi0))
n@[o:neg(eta0)]
xa:=abs(ksi0):rl
ya:=abs(eta0):rl
pxa:=satz166b(ksi0,n):pos(xa)
pya:=satz166b(eta0,o):pos(ya)
t9:=ispen(pl1a(xa,ya,pxa,pya),t3d"rl.iv3"(xa,ya,pxa,pya),pl1a(ya,xa,pya,pxa),t3d"rl.iv3"(ya,xa,pya,pxa),t2(xa,ya,pxa,pya)):is(pl3b(ksi0,eta0,n,o),pl3b(eta0,ksi0,o,n))
t10:=tr3is(rl,pl(ksi0,eta0),pl3b(ksi0,eta0,n,o),pl3b(eta0,ksi0,o,n),pl(eta0,ksi0),t52"rl.iv3"(ksi0,eta0,n,o),t9,symis(rl,pl(eta0,ksi0),pl3b(eta0,ksi0,o,n),t52"rl.iv3"(eta0,ksi0,o,n))):is(pl(ksi0,eta0),pl(eta0,ksi0))
n@t12:=rlapp(eta0,is(pl(ksi0,eta0),pl(eta0,ksi0)),[t:pos(eta0)]t8(t),[t:is(eta0,0)]t4(t),[t:neg(eta0)]t10(t)):is(pl(ksi0,eta0),pl(eta0,ksi0))
-3175
eta0@satz175:=rlapp(ksi0,is(pl(ksi0,eta0),pl(eta0,ksi0)),[t:pos(ksi0)]t6".3175"(t),[t:is(ksi0,0)]t7".3175"(t),[t:neg(ksi0)]t12".3175"(t)):is(pl(ksi0,eta0),pl(eta0,ksi0))
compl:=satz175:is(pl(ksi0,eta0),pl(eta0,ksi0))
ksi0@mn0b:=ite"l.r"(px".iv3",rl,[t:px".iv3"]mn0a(ksi0,t),[t:not(px".iv3")]0,[t:px".iv3"][u:px".iv3"]ispen(ksi0,t,ksi0,u,refis(rl,ksi0)),[t:not(px".iv3")][u:not(px".iv3")]refis(rl,0)):rl
[p:pos(ksi0)]
+*iv3
p@t57:=itet"l.r"(px,rl,[t:px]mn0a(ksi0,t),[t:not(px)]0,[t:px][u:px]ispen(ksi0,t,ksi0,u,refis(rl,ksi0)),[t:not(px)][u:not(px)]refis(rl,0),p):is(mn0b,mn0a(ksi0,p))
-iv3
ksi0@[n:not(pos(ksi0))]
+*iv3
n@t58:=itef"l.r"(px,rl,[t:px]mn0a(ksi0,t),[t:not(px)]0,[t:px][u:px]ispen(ksi0,t,ksi0,u,refis(rl,ksi0)),[t:not(px)][u:not(px)]refis(rl,0),n):is(mn0b,0)
-iv3
ksi0@mn0:=ite(nx".iv3",rl,abs(ksi0),mn0b):rl
[n:neg(ksi0)]
+*iv3
n@t59:=itet(nx,rl,abs(ksi0),mn0b,n):is(mn0,abs(ksi0))
-iv3
ksi0@[n:not(neg(ksi0))]
+*iv3
n@t60:=itef(nx,rl,abs(ksi0),mn0b,n):is(mn0,mn0b)
-iv3
ksi0@[p:pos(ksi0)]
mn0p:=tris(rl,mn0,mn0b,mn0a(ksi0,p),t60".iv3"(pnotn(ksi0,p)),t57".iv3"(p)):is(mn0(ksi0),mn0a(ksi0,p))
ksi0@[i:is(ksi0,0)]
mn00:=tris(rl,mn0,mn0b,0,t60".iv3"(0notn(ksi0,i)),t58".iv3"(0notp(ksi0,i))):is(mn0(ksi0),0)
ksi0@[n:neg(ksi0)]
mn0n:=t59".iv3"(n):is(mn0(ksi0),abs(ksi0))
eta0@[i:is(ksi0,eta0)]
ismn0:=isf(rl,rl,[x:rl]mn0(x),ksi0,eta0,i):is(mn0(ksi0),mn0(eta0))
eta0@[p:pos(ksi0)][n:neg(eta0)][l:less(ksi0,abs(eta0))]
plpn4:=tris2(rl,pl(ksi0,eta0),mn0(mna(abs(eta0),ksi0,satz166b(eta0,n),p,l)),pl1e(p,n,l),plpn3(p,n,l),mn0p(mna(abs(eta0),ksi0,satz166b(eta0,n),p,l),t2".iv3"(abs(eta0),ksi0,satz166b(eta0,n),p,l))):is(pl(ksi0,eta0),mn0(mna(abs(eta0),ksi0,satz166b(eta0,n),p,l)))
eta0@[n:neg(ksi0)][o:neg(eta0)]
plnn1:=tris2(rl,pl(ksi0,eta0),mn0(pl(abs(ksi0),abs(eta0))),mn0a(pl(abs(ksi0),abs(eta0)),pospl(abs(ksi0),abs(eta0),satz166b(ksi0,n),satz166b(eta0,o))),plnn(n,o),mn0p(pl(abs(ksi0),abs(eta0)),pospl(abs(ksi0),abs(eta0),satz166b(ksi0,n),satz166b(eta0,o)))):is(pl(ksi0,eta0),mn0(pl(abs(ksi0),abs(eta0))))
ksi0@[n:neg(ksi0)]
absn1:=symis(rl,mn0(ksi0),abs(ksi0),mn0n(ksi0,n)):is(abs(ksi0),mn0(ksi0))
ksi0@[p:pos(ksi0)]
satz176a:=isp1(rl,[x:rl]neg(x),mn0a(ksi0,p),mn0(ksi0),negip(ksi0,p),mn0p(ksi0,p)):neg(mn0(ksi0))
ksi0@[i:is(ksi0,0)]
satz176b:=mn00(ksi0,i):is(mn0(ksi0),0)
ksi0@[n:neg(ksi0)]
satz176c:=isp1(rl,[x:rl]pos(x),abs(ksi0),mn0(ksi0),satz166b(ksi0,n),mn0n(ksi0,n)):pos(mn0(ksi0))
+3176
ksi0@t1:=th5"l.ec3"(neg(mn0(ksi0)),pos(mn0(ksi0)),is(mn0(ksi0),0),th5a"l.ec3"(is(mn0(ksi0),0),pos(mn0(ksi0)),neg(mn0(ksi0)),axrle(mn0(ksi0)))):ec3(is(mn0(ksi0),0),neg(mn0(ksi0)),pos(mn0(ksi0)))
-3176
ksi0@[n:neg(mn0(ksi0))]
satz176d:=th11"l.ec3"(is(ksi0,0),pos(ksi0),neg(ksi0),is(mn0(ksi0),0),neg(mn0(ksi0)),pos(mn0(ksi0)),axrlo(ksi0),t1".3176",[t:is(ksi0,0)]satz176b(t),[t:pos(ksi0)]satz176a(t),[t:neg(ksi0)]satz176c(t),n):pos(ksi0)
ksi0@[i:is(mn0(ksi0),0)]
satz176e:=th10"l.ec3"(is(ksi0,0),pos(ksi0),neg(ksi0),is(mn0(ksi0),0),neg(mn0(ksi0)),pos(mn0(ksi0)),axrlo(ksi0),t1".3176",[t:is(ksi0,0)]satz176b(t),[t:pos(ksi0)]satz176a(t),[t:neg(ksi0)]satz176c(t),i):is(ksi0,0)
ksi0@[p:pos(mn0(ksi0))]
satz176f:=th12"l.ec3"(is(ksi0,0),pos(ksi0),neg(ksi0),is(mn0(ksi0),0),neg(mn0(ksi0)),pos(mn0(ksi0)),axrlo(ksi0),t1".3176",[t:is(ksi0,0)]satz176b(t),[t:pos(ksi0)]satz176a(t),[t:neg(ksi0)]satz176c(t),p):neg(ksi0)
ksi0@[p:pos(ksi0)]
lemma177:=tr3is(rl,abs(mn0(ksi0)),abs(mn0a(ksi0,p)),pofn(mn0a(ksi0,p),negip(ksi0,p)),ksi0,isabs(mn0(ksi0),mn0a(ksi0,p),mn0p(ksi0,p)),absn(mn0a(ksi0,p),negip(ksi0,p)),ispn2(ksi0,p)):is(abs(mn0(ksi0)),ksi0)
+3177
t2:=tris(rl,mn0(mn0(ksi0)),abs(mn0(ksi0)),ksi0,mn0n(mn0(ksi0),satz176a(ksi0,p)),lemma177):is(mn0(mn0(ksi0)),ksi0)
ksi0@[i:is(ksi0,0)]
t3:=tris2(rl,mn0(mn0(ksi0)),ksi0,0,mn00(mn0(ksi0),mn00(ksi0,i)),i):is(mn0(mn0(ksi0)),ksi0)
ksi0@[n:neg(ksi0)]
t5:=tris(rl,mn0(ksi0),abs(ksi0),pofn(ksi0,n),mn0n(ksi0,n),absn(ksi0,n)):is(mn0(ksi0),pofn(ksi0,n))
t6:=tr3is(rl,mn0(mn0(ksi0)),mn0(pofn(ksi0,n)),mn0a(pofn(ksi0,n),posin(ksi0,n)),ksi0,ismn0(mn0(ksi0),pofn(ksi0,n),t5),mn0p(pofn(ksi0,n),posin(ksi0,n)),isnp2(ksi0,n)):is(mn0(mn0(ksi0)),ksi0)
-3177
ksi0@satz177:=rlapp(ksi0,is(mn0(mn0(ksi0)),ksi0),[t:pos(ksi0)]t2".3177"(t),[t:is(ksi0,0)]t3".3177"(t),[t:neg(ksi0)]t6".3177"(t)):is(mn0(mn0(ksi0)),ksi0)
satz177a:=symis(rl,mn0(mn0(ksi0)),ksi0,satz177):is(ksi0,mn0(mn0(ksi0)))
+3178
[p:pos(ksi0)]
t1:=tris2(rl,abs(mn0(ksi0)),abs(ksi0),ksi0,lemma177(p),absp(ksi0,p)):is(abs(mn0(ksi0)),abs(ksi0))
ksi0@[i:is(ksi0,0)]
t2:=tris2(rl,abs(mn0(ksi0)),abs(ksi0),0,abs0(mn0(ksi0),mn00(ksi0,i)),abs0(ksi0,i)):is(abs(mn0(ksi0)),abs(ksi0))
ksi0@[n:neg(ksi0)]
t3:=tris(rl,abs(mn0(ksi0)),abs(abs(ksi0)),abs(ksi0),isabs(mn0(ksi0),abs(ksi0),mn0n(ksi0,n)),absp(abs(ksi0),satz166b(ksi0,n))):is(abs(mn0(ksi0)),abs(ksi0))
-3178
satz178:=rlapp(ksi0,is(abs(mn0(ksi0)),abs(ksi0)),[t:pos(ksi0)]t1".3178"(t),[t:is(ksi0,0)]t2".3178"(t),[t:neg(ksi0)]t3".3178"(t)):is(abs(mn0(ksi0)),abs(ksi0))
satz178a:=symis(rl,abs(mn0(ksi0)),abs(ksi0),satz178):is(abs(ksi0),abs(mn0(ksi0)))
+3179
[p:pos(ksi0)]
t1:=plpn2(ksi0,mn0(ksi0),p,satz176a(ksi0,p),symis(rl,abs(mn0(ksi0)),ksi0,lemma177(p))):is(pl(ksi0,mn0(ksi0)),0)
ksi0@[i:is(ksi0,0)]
t2:=tris(rl,pl(ksi0,mn0(ksi0)),mn0(ksi0),0,pl01(ksi0,mn0(ksi0),i),mn00(ksi0,i)):is(pl(ksi0,mn0(ksi0)),0)
ksi0@[n:neg(ksi0)]
t3:=tris(rl,pl(ksi0,mn0(ksi0)),pl(mn0(ksi0),ksi0),0,compl(ksi0,mn0(ksi0)),plpn2(mn0(ksi0),ksi0,satz176c(ksi0,n),n,mn0n(ksi0,n))):is(pl(ksi0,mn0(ksi0)),0)
-3179
satz179:=rlapp(ksi0,is(pl(ksi0,mn0(ksi0)),0),[t:pos(ksi0)]t1".3179"(t),[t:is(ksi0,0)]t2".3179"(t),[t:neg(ksi0)]t3".3179"(t)):is(pl(ksi0,mn0(ksi0)),0)
satz179a:=tris(rl,pl(mn0(ksi0),ksi0),pl(ksi0,mn0(ksi0)),0,compl(mn0(ksi0),ksi0),satz179(ksi0)):is(pl(mn0(ksi0),ksi0),0)
+3180
eta0@[m:moreis(ksi0,eta0)][p:pos(ksi0)][q:pos(eta0)]
t1:=ispl12(abs(mn0(ksi0)),ksi0,abs(mn0(eta0)),eta0,lemma177(ksi0,p),lemma177(eta0,q)):is(pl(abs(mn0(ksi0)),abs(mn0(eta0))),pl(ksi0,eta0))
t2:=tris(rl,pl(mn0(ksi0),mn0(eta0)),mn0(pl(abs(mn0(ksi0)),abs(mn0(eta0)))),mn0(pl(ksi0,eta0)),plnn1(mn0(ksi0),mn0(eta0),satz176a(ksi0,p),satz176a(eta0,q)),ismn0(pl(abs(mn0(ksi0)),abs(mn0(eta0))),pl(ksi0,eta0),t1)):is(pl(mn0(ksi0),mn0(eta0)),mn0(pl(ksi0,eta0)))
p@[i:is(eta0,0)]
t3:=tris2(rl,pl(mn0(ksi0),mn0(eta0)),mn0(pl(ksi0,eta0)),mn0(ksi0),pl02(mn0(ksi0),mn0(eta0),mn00(eta0,i)),ismn0(pl(ksi0,eta0),ksi0,pl02(ksi0,eta0,i))):is(pl(mn0(ksi0),mn0(eta0)),mn0(pl(ksi0,eta0)))
p@[n:neg(eta0)]
t4:=tris(rl,pl(mn0(ksi0),mn0(eta0)),pl(mn0(ksi0),abs(eta0)),pl(abs(eta0),mn0(ksi0)),ispl2(mn0(eta0),abs(eta0),mn0(ksi0),mn0n(eta0,n)),compl(mn0(ksi0),abs(eta0))):is(pl(mn0(ksi0),mn0(eta0)),pl(abs(eta0),mn0(ksi0)))
[o:more(ksi0,abs(eta0))]
t5:=ismore1(ksi0,abs(mn0(ksi0)),abs(eta0),symis(rl,abs(mn0(ksi0)),ksi0,lemma177(ksi0,p)),o):less(abs(eta0),abs(mn0(ksi0)))
t6:=ismna12(abs(mn0(ksi0)),ksi0,abs(eta0),abs(eta0),lemma177(ksi0,p),refis(rl,abs(eta0)),satz166b(mn0(ksi0),satz176a(ksi0,p)),satz166b(eta0,n),t5,p,satz166b(eta0,n),o):is(mna(abs(mn0(ksi0)),abs(eta0),satz166b(mn0(ksi0),satz176a(ksi0,p)),satz166b(eta0,n),t5),mna(ksi0,abs(eta0),p,satz166b(eta0,n),o))
t7:=tr3is(rl,pl(mn0(ksi0),mn0(eta0)),pl(abs(eta0),mn0(ksi0)),mn0(mna(abs(mn0(ksi0)),abs(eta0),satz166b(mn0(ksi0),satz176a(ksi0,p)),satz166b(eta0,n),t5)),mn0(mna(ksi0,abs(eta0),p,satz166b(eta0,n),o)),t4,plpn4(abs(eta0),mn0(ksi0),satz166b(eta0,n),satz176a(ksi0,p),t5),ismn0(mna(abs(mn0(ksi0)),abs(eta0),satz166b(mn0(ksi0),satz176a(ksi0,p)),satz166b(eta0,n),t5),mna(ksi0,abs(eta0),p,satz166b(eta0,n),o),t6)):is(pl(mn0(ksi0),mn0(eta0)),mn0(mna(ksi0,abs(eta0),p,satz166b(eta0,n),o)))
t8:=tris2(rl,pl(mn0(ksi0),mn0(eta0)),mn0(pl(ksi0,eta0)),mn0(mna(ksi0,abs(eta0),p,satz166b(eta0,n),o)),t7,ismn0(pl(ksi0,eta0),mna(ksi0,abs(eta0),p,satz166b(eta0,n),o),plpn1(ksi0,eta0,p,n,o))):is(pl(mn0(ksi0),mn0(eta0)),mn0(pl(ksi0,eta0)))
n@[i:is(ksi0,abs(eta0))]
t9:=tris2(rl,abs(eta0),abs(mn0(ksi0)),ksi0,symis(rl,ksi0,abs(eta0),i),lemma177(ksi0,p)):is(abs(eta0),abs(mn0(ksi0)))
t10:=tris(rl,pl(mn0(ksi0),mn0(eta0)),pl(abs(eta0),mn0(ksi0)),0,t4,plpn2(abs(eta0),mn0(ksi0),satz166b(eta0,n),satz176a(ksi0,p),t9)):is(pl(mn0(ksi0),mn0(eta0)),0)
t11:=tris2(rl,pl(mn0(ksi0),mn0(eta0)),mn0(pl(ksi0,eta0)),0,t10,mn00(pl(ksi0,eta0),plpn2(ksi0,eta0,p,n,i))):is(pl(mn0(ksi0),mn0(eta0)),mn0(pl(ksi0,eta0)))
n@[l:less(ksi0,abs(eta0))]
t12:=isless1(ksi0,abs(mn0(ksi0)),abs(eta0),symis(rl,abs(mn0(ksi0)),ksi0,lemma177(ksi0,p)),l):more(abs(eta0),abs(mn0(ksi0)))
t13:=ismna12(abs(eta0),abs(eta0),abs(mn0(ksi0)),ksi0,refis(rl,abs(eta0)),lemma177(ksi0,p),satz166b(eta0,n),satz166b(mn0(ksi0),satz176a(ksi0,p)),t12,satz166b(eta0,n),p,l):is(mna(abs(eta0),abs(mn0(ksi0)),satz166b(eta0,n),satz166b(mn0(ksi0),satz176a(ksi0,p)),t12),mna(abs(eta0),ksi0,satz166b(eta0,n),p,l))
t14:=tr3is(rl,pl(mn0(ksi0),mn0(eta0)),pl(abs(eta0),mn0(ksi0)),mna(abs(eta0),abs(mn0(ksi0)),satz166b(eta0,n),satz166b(mn0(ksi0),satz176a(ksi0,p)),t12),mna(abs(eta0),ksi0,satz166b(eta0,n),p,l),t4,plpn1(abs(eta0),mn0(ksi0),satz166b(eta0,n),satz176a(ksi0,p),t12),t13):is(pl(mn0(ksi0),mn0(eta0)),mna(abs(eta0),ksi0,satz166b(eta0,n),p,l))
t15:=tris(rl,mn0(pl(ksi0,eta0)),mn0(mn0(mna(abs(eta0),ksi0,satz166b(eta0,n),p,l))),mna(abs(eta0),ksi0,satz166b(eta0,n),p,l),ismn0(pl(ksi0,eta0),mn0(mna(abs(eta0),ksi0,satz166b(eta0,n),p,l)),plpn4(ksi0,eta0,p,n,l)),satz177(mna(abs(eta0),ksi0,satz166b(eta0,n),p,l))):is(mn0(pl(ksi0,eta0)),mna(abs(eta0),ksi0,satz166b(eta0,n),p,l))
t16:=tris2(rl,pl(mn0(ksi0),mn0(eta0)),mn0(pl(ksi0,eta0)),mna(abs(eta0),ksi0,satz166b(eta0,n),p,l),t14,t15):is(pl(mn0(ksi0),mn0(eta0)),mn0(pl(ksi0,eta0)))
n@t17:=or3app(is(ksi0,abs(eta0)),more(ksi0,abs(eta0)),less(ksi0,abs(eta0)),is(pl(mn0(ksi0),mn0(eta0)),mn0(pl(ksi0,eta0))),satz167a(ksi0,abs(eta0)),[t:is(ksi0,abs(eta0))]t11(t),[t:more(ksi0,abs(eta0))]t8(t),[t:less(ksi0,abs(eta0))]t16(t)):is(pl(mn0(ksi0),mn0(eta0)),mn0(pl(ksi0,eta0)))
p@t18:=rlapp(eta0,is(pl(mn0(ksi0),mn0(eta0)),mn0(pl(ksi0,eta0))),[t:pos(eta0)]t2(t),[t:is(eta0,0)]t3(t),[t:neg(eta0)]t17(t)):is(pl(mn0(ksi0),mn0(eta0)),mn0(pl(ksi0,eta0)))
m@[i:is(ksi0,0)]
t19:=tris2(rl,pl(mn0(ksi0),mn0(eta0)),mn0(pl(ksi0,eta0)),mn0(eta0),pl01(mn0(ksi0),mn0(eta0),mn00(ksi0,i)),ismn0(pl(ksi0,eta0),eta0,pl01(ksi0,eta0,i))):is(pl(mn0(ksi0),mn0(eta0)),mn0(pl(ksi0,eta0)))
m@[n:neg(ksi0)]
t20:=orapp(more(ksi0,eta0),is(ksi0,eta0),neg(eta0),m,[t:more(ksi0,eta0)]moreen1a(ksi0,eta0,t,n),[t:is(ksi0,eta0)]isp(rl,[x:rl]neg(x),ksi0,eta0,n,t)):neg(eta0)
t21:=tris(rl,mn0(pl(ksi0,eta0)),mn0(mn0(pl(abs(ksi0),abs(eta0)))),pl(abs(ksi0),abs(eta0)),ismn0(pl(ksi0,eta0),mn0(pl(abs(ksi0),abs(eta0))),plnn1(ksi0,eta0,n,t20)),satz177(pl(abs(ksi0),abs(eta0)))):is(mn0(pl(ksi0,eta0)),pl(abs(ksi0),abs(eta0)))
t22:=tris2(rl,pl(mn0(ksi0),mn0(eta0)),mn0(pl(ksi0,eta0)),pl(abs(ksi0),abs(eta0)),ispl12(mn0(ksi0),abs(ksi0),mn0(eta0),abs(eta0),mn0n(ksi0,n),mn0n(eta0,t20)),t21):is(pl(mn0(ksi0),mn0(eta0)),mn0(pl(ksi0,eta0)))
m@t23:=rlapp(ksi0,is(pl(mn0(ksi0),mn0(eta0)),mn0(pl(ksi0,eta0))),[t:pos(ksi0)]t18(t),[t:is(ksi0,0)]t19(t),[t:neg(ksi0)]t22(t)):is(pl(mn0(ksi0),mn0(eta0)),mn0(pl(ksi0,eta0)))
eta0@[l:less(ksi0,eta0)]
t24:=tr3is(rl,pl(mn0(ksi0),mn0(eta0)),pl(mn0(eta0),mn0(ksi0)),mn0(pl(eta0,ksi0)),mn0(pl(ksi0,eta0)),compl(mn0(ksi0),mn0(eta0)),t23(eta0,ksi0,moreisi1(eta0,ksi0,l)),ismn0(pl(eta0,ksi0),pl(ksi0,eta0),compl(eta0,ksi0))):is(pl(mn0(ksi0),mn0(eta0)),mn0(pl(ksi0,eta0)))
-3180
eta0@satz180:=or3app(is(ksi0,eta0),more(ksi0,eta0),less(ksi0,eta0),is(pl(mn0(ksi0),mn0(eta0)),mn0(pl(ksi0,eta0))),satz167a(ksi0,eta0),[t:is(ksi0,eta0)]t23".3180"(moreisi2(ksi0,eta0,t)),[t:more(ksi0,eta0)]t23".3180"(moreisi1(ksi0,eta0,t)),[t:less(ksi0,eta0)]t24".3180"(t)):is(pl(mn0(ksi0),mn0(eta0)),mn0(pl(ksi0,eta0)))
satz180a:=symis(rl,pl(mn0(ksi0),mn0(eta0)),mn0(pl(ksi0,eta0)),satz180):is(mn0(pl(ksi0,eta0)),pl(mn0(ksi0),mn0(eta0)))
mn:=pl(ksi0,mn0(eta0)):rl
[p:pos(ksi0)][q:pos(eta0)][m:more(ksi0,eta0)]
+*iv3
m@t61:=ismore2(eta0,abs(mn0(eta0)),ksi0,symis(rl,abs(mn0(eta0)),eta0,lemma177(eta0,q)),m):more(ksi0,abs(mn0(eta0)))
-iv3
m@mnpp:=tris(rl,mn(ksi0,eta0),mna(ksi0,abs(mn0(eta0)),p,satz166b(mn0(eta0),satz176a(eta0,q)),t61".iv3"),mna(ksi0,eta0,p,q,m),plpn1(ksi0,mn0(eta0),p,satz176a(eta0,q),t61".iv3"),ismna12(ksi0,ksi0,abs(mn0(eta0)),eta0,refis(rl,ksi0),lemma177(eta0,q),p,satz166b(mn0(eta0),satz176a(eta0,q)),t61".iv3",p,q,m)):is(mn(ksi0,eta0),mna(ksi0,eta0,p,q,m))
zeta0@[i:is(ksi0,eta0)]
ismn1:=ispl1(ksi0,eta0,mn0(zeta0),i):is(mn(ksi0,zeta0),mn(eta0,zeta0))
ismn2:=ispl2(mn0(ksi0),mn0(eta0),zeta0,ismn0(ksi0,eta0,i)):is(mn(zeta0,ksi0),mn(zeta0,eta0))
upsilon0@[i:is(ksi0,eta0)][j:is(zeta0,upsilon0)]
ismn12:=ispl12(ksi0,eta0,mn0(zeta0),mn0(upsilon0),i,ismn0(zeta0,upsilon0,j)):is(mn(ksi0,zeta0),mn(eta0,upsilon0))
eta0@satz181:=tr3is(rl,mn0(mn(ksi0,eta0)),pl(mn0(ksi0),mn0(mn0(eta0))),pl(mn0(ksi0),eta0),mn(eta0,ksi0),satz180a(ksi0,mn0(eta0)),ispl2(mn0(mn0(eta0)),eta0,mn0(ksi0),satz177(eta0)),compl(mn0(ksi0),eta0)):is(mn0(mn(ksi0,eta0)),mn(eta0,ksi0))
satz181a:=symis(rl,mn0(mn(eta0,ksi0)),mn(ksi0,eta0),satz181(eta0,ksi0)):is(mn(ksi0,eta0),mn0(mn(eta0,ksi0)))
+3182
pxpy:=pos(pl(ksi0,eta0)):'prop'
0xpy:=is(pl(ksi0,eta0),0):'prop'
nxpy:=neg(pl(ksi0,eta0)):'prop'
mx:=more(ksi0,mn0(eta0)):'prop'
ix:=is(ksi0,mn0(eta0)):'prop'
lx:=less(ksi0,mn0(eta0)):'prop'
[p:pos(ksi0)][q:pos(eta0)]
t1:=pospl(ksi0,eta0,p,q):pxpy
t2:=moreipn(ksi0,mn0(eta0),p,satz176a(eta0,q)):mx
p@[i:is(eta0,0)]
t3:=isp1(rl,[x:rl]pos(x),ksi0,pl(ksi0,eta0),p,pl02(ksi0,eta0,i)):pxpy
t4:=moreip0(ksi0,mn0(eta0),p,mn00(eta0,i)):mx
p@[n:neg(eta0)][m:more(ksi0,abs(eta0))]
t5:=isp1(rl,[x:rl]pos(x),mna(ksi0,abs(eta0),p,satz166b(eta0,n),m),pl(ksi0,eta0),t2"rl.iv3"(ksi0,abs(eta0),p,satz166b(eta0,n),m),plpn1(ksi0,eta0,p,n,m)):pxpy
t6:=ismore2(abs(eta0),mn0(eta0),ksi0,symis(rl,mn0(eta0),abs(eta0),mn0n(eta0,n)),m):mx
n@[i:is(ksi0,abs(eta0))]
t7:=plpn2(ksi0,eta0,p,n,i):0xpy
t8:=tris2(rl,ksi0,mn0(eta0),abs(eta0),i,mn0n(eta0,n)):ix
n@[l:less(ksi0,abs(eta0))]
t9:=isp1(rl,[x:rl]neg(x),mn0(mna(abs(eta0),ksi0,satz166b(eta0,n),p,l)),pl(ksi0,eta0),satz176a(mna(abs(eta0),ksi0,satz166b(eta0,n),p,l),t2"rl.iv3"(abs(eta0),ksi0,satz166b(eta0,n),p,l)),plpn4(ksi0,eta0,p,n,l)):nxpy
t10:=isless2(abs(eta0),mn0(eta0),ksi0,symis(rl,mn0(eta0),abs(eta0),mn0n(eta0,n)),l):lx
eta0@[i:is(ksi0,0)][p:pos(eta0)]
t11:=isp1(rl,[x:rl]pos(x),eta0,pl(ksi0,eta0),p,pl01(ksi0,eta0,i)):pxpy
t12:=morei0n(ksi0,mn0(eta0),i,satz176a(eta0,p)):mx
i@[j:is(eta0,0)]
t13:=tris(rl,pl(ksi0,eta0),eta0,0,pl01(ksi0,eta0,i),j):0xpy
t14:=tris2(rl,ksi0,mn0(eta0),0,i,mn00(eta0,j)):ix
i@[n:neg(eta0)]
t15:=isp1(rl,[x:rl]neg(x),eta0,pl(ksi0,eta0),n,pl01(ksi0,eta0,i)):nxpy
t16:=lessi0p(ksi0,mn0(eta0),i,satz176c(eta0,n)):lx
eta0@[n:neg(ksi0)][p:pos(eta0)][m:more(eta0,abs(ksi0))]
t17:=isp(rl,[x:rl]pos(x),pl(eta0,ksi0),pl(ksi0,eta0),t5(eta0,ksi0,p,n,m),compl(eta0,ksi0)):pxpy
t18:=moreinn(ksi0,mn0(eta0),n,satz176a(eta0,p),ismore1(eta0,abs(mn0(eta0)),abs(ksi0),symis(rl,abs(mn0(eta0)),eta0,lemma177(eta0,p)),m)):mx
p@[i:is(eta0,abs(ksi0))]
t19:=tris(rl,pl(ksi0,eta0),pl(eta0,ksi0),0,compl(ksi0,eta0),t7(eta0,ksi0,p,n,i)):0xpy
t20:=tris2(rl,ksi0,mn0(eta0),mn0(mn0(ksi0)),satz177a(ksi0),ismn0(eta0,mn0(ksi0),tris2(rl,eta0,mn0(ksi0),abs(ksi0),i,mn0n(ksi0,n)))):ix
p@[l:less(eta0,abs(ksi0))]
t21:=isp(rl,[x:rl]neg(x),pl(eta0,ksi0),pl(ksi0,eta0),t9(eta0,ksi0,p,n,l),compl(eta0,ksi0)):nxpy
t22:=lessinn(ksi0,mn0(eta0),n,satz176a(eta0,p),ismore2(eta0,abs(mn0(eta0)),abs(ksi0),symis(rl,abs(mn0(eta0)),eta0,lemma177(eta0,p)),l)):lx
n@[i:is(eta0,0)]
t23:=isp1(rl,[x:rl]neg(x),ksi0,pl(ksi0,eta0),n,pl02(ksi0,eta0,i)):nxpy
t24:=lessin0(ksi0,mn0(eta0),n,mn00(eta0,i)):lx
n@[o:neg(eta0)]
t25:=isp1(rl,[x:rl]neg(x),mn0(pl(abs(ksi0),abs(eta0))),pl(ksi0,eta0),satz176a(pl(abs(ksi0),abs(eta0)),pospl(abs(ksi0),abs(eta0),satz166b(ksi0,n),satz166b(eta0,o))),plnn1(ksi0,eta0,n,o)):nxpy
t26:=lessinp(ksi0,mn0(eta0),n,satz176c(eta0,o)):lx
eta0@t27:=satz167b(ksi0,mn0(eta0)):ec3(ix,mx,lx)
[p:pxpy][m:mx]
t28:=th1"l.iff"(pxpy,mx,p,m):iff(pxpy,mx)
t29:=th2"l.iff"(0xpy,ix,pnot0(pl(ksi0,eta0),p),ec3e21(ix,mx,lx,t27,m)):iff(0xpy,ix)
t30:=th2"l.iff"(nxpy,lx,pnotn(pl(ksi0,eta0),p),ec3e23(ix,mx,lx,t27,m)):iff(nxpy,lx)
eta0@[i:0xpy][j:ix]
t31:=th2"l.iff"(pxpy,mx,0notp(pl(ksi0,eta0),i),ec3e12(ix,mx,lx,t27,j)):iff(pxpy,mx)
t32:=th1"l.iff"(0xpy,ix,i,j):iff(0xpy,ix)
t33:=th2"l.iff"(nxpy,lx,0notn(pl(ksi0,eta0),i),ec3e13(ix,mx,lx,t27,j)):iff(nxpy,lx)
eta0@[n:nxpy][l:lx]
t34:=th2"l.iff"(pxpy,mx,nnotp(pl(ksi0,eta0),n),ec3e32(ix,mx,lx,t27,l)):iff(pxpy,mx)
t35:=th2"l.iff"(0xpy,ix,nnot0(pl(ksi0,eta0),n),ec3e31(ix,mx,lx,t27,l)):iff(0xpy,ix)
t36:=th1"l.iff"(nxpy,lx,n,l):iff(nxpy,lx)
eta0@mxa:=more(ksi0,abs(eta0)):'prop'
ixa:=is(ksi0,abs(eta0)):'prop'
lxa:=less(ksi0,abs(eta0)):'prop'
t37:=satz167a(ksi0,abs(eta0)):or3(ixa,mxa,lxa)
[p:pos(ksi0)][n:neg(eta0)]
t38:=or3app(ixa,mxa,lxa,iff(pxpy,mx),t37,[t:ixa]t31(t7(p,n,t),t8(p,n,t)),[t:mxa]t28(t5(p,n,t),t6(p,n,t)),[t:lxa]t34(t9(p,n,t),t10(p,n,t))):iff(pxpy,mx)
t39:=or3app(ixa,mxa,lxa,iff(0xpy,ix),t37,[t:ixa]t32(t7(p,n,t),t8(p,n,t)),[t:mxa]t29(t5(p,n,t),t6(p,n,t)),[t:lxa]t35(t9(p,n,t),t10(p,n,t))):iff(0xpy,ix)
t40:=or3app(ixa,mxa,lxa,iff(nxpy,lx),t37,[t:ixa]t33(t7(p,n,t),t8(p,n,t)),[t:mxa]t30(t5(p,n,t),t6(p,n,t)),[t:lxa]t36(t9(p,n,t),t10(p,n,t))):iff(nxpy,lx)
p@t41:=rlapp(eta0,iff(pxpy,mx),[t:pos(eta0)]t28(t1(p,t),t2(p,t)),[t:is(eta0,0)]t28(t3(p,t),t4(p,t)),[t:neg(eta0)]t38(t)):iff(pxpy,mx)
t42:=rlapp(eta0,iff(0xpy,ix),[t:pos(eta0)]t29(t1(p,t),t2(p,t)),[t:is(eta0,0)]t29(t3(p,t),t4(p,t)),[t:neg(eta0)]t39(t)):iff(0xpy,ix)
t43:=rlapp(eta0,iff(nxpy,lx),[t:pos(eta0)]t30(t1(p,t),t2(p,t)),[t:is(eta0,0)]t30(t3(p,t),t4(p,t)),[t:neg(eta0)]t40(t)):iff(nxpy,lx)
eta0@[i:is(ksi0,0)]
t44:=rlapp(eta0,iff(pxpy,mx),[t:pos(eta0)]t28(t11(i,t),t12(i,t)),[t:is(eta0,0)]t31(t13(i,t),t14(i,t)),[t:neg(eta0)]t34(t15(i,t),t16(i,t))):iff(pxpy,mx)
t45:=rlapp(eta0,iff(0xpy,ix),[t:pos(eta0)]t29(t11(i,t),t12(i,t)),[t:is(eta0,0)]t32(t13(i,t),t14(i,t)),[t:neg(eta0)]t35(t15(i,t),t16(i,t))):iff(0xpy,ix)
t46:=rlapp(eta0,iff(nxpy,lx),[t:pos(eta0)]t30(t11(i,t),t12(i,t)),[t:is(eta0,0)]t33(t13(i,t),t14(i,t)),[t:neg(eta0)]t36(t15(i,t),t16(i,t))):iff(nxpy,lx)
eta0@mya:=more(eta0,abs(ksi0)):'prop'
iya:=is(eta0,abs(ksi0)):'prop'
lya:=less(eta0,abs(ksi0)):'prop'
t47:=satz167a(eta0,abs(ksi0)):or3(iya,mya,lya)
[n:neg(ksi0)][p:pos(eta0)]
t48:=or3app(iya,mya,lya,iff(pxpy,mx),t47,[t:iya]t31(t19(n,p,t),t20(n,p,t)),[t:mya]t28(t17(n,p,t),t18(n,p,t)),[t:lya]t34(t21(n,p,t),t22(n,p,t))):iff(pxpy,mx)
t49:=or3app(iya,mya,lya,iff(0xpy,ix),t47,[t:iya]t32(t19(n,p,t),t20(n,p,t)),[t:mya]t29(t17(n,p,t),t18(n,p,t)),[t:lya]t35(t21(n,p,t),t22(n,p,t))):iff(0xpy,ix)
t50:=or3app(iya,mya,lya,iff(nxpy,lx),t47,[t:iya]t33(t19(n,p,t),t20(n,p,t)),[t:mya]t30(t17(n,p,t),t18(n,p,t)),[t:lya]t36(t21(n,p,t),t22(n,p,t))):iff(nxpy,lx)
n@t51:=rlapp(eta0,iff(pxpy,mx),[t:pos(eta0)]t48(t),[t:is(eta0,0)]t34(t23(n,t),t24(n,t)),[t:neg(eta0)]t34(t25(n,t),t26(n,t))):iff(pxpy,mx)
t52:=rlapp(eta0,iff(0xpy,ix),[t:pos(eta0)]t49(t),[t:is(eta0,0)]t35(t23(n,t),t24(n,t)),[t:neg(eta0)]t35(t25(n,t),t26(n,t))):iff(0xpy,ix)
t53:=rlapp(eta0,iff(nxpy,lx),[t:pos(eta0)]t50(t),[t:is(eta0,0)]t36(t23(n,t),t24(n,t)),[t:neg(eta0)]t36(t25(n,t),t26(n,t))):iff(nxpy,lx)
eta0@t54:=rlapp(ksi0,iff(pxpy,mx),[t:pos(ksi0)]t41(t),[t:is(ksi0,0)]t44(t),[t:neg(ksi0)]t51(t)):iff(pxpy,mx)
t55:=rlapp(ksi0,iff(0xpy,ix),[t:pos(ksi0)]t42(t),[t:is(ksi0,0)]t45(t),[t:neg(ksi0)]t52(t)):iff(0xpy,ix)
t56:=rlapp(ksi0,iff(nxpy,lx),[t:pos(ksi0)]t43(t),[t:is(ksi0,0)]t46(t),[t:neg(ksi0)]t53(t)):iff(nxpy,lx)
-3182
[p:pos(mn(ksi0,eta0))]
satz182a:=ismore2(mn0(mn0(eta0)),eta0,ksi0,satz177(eta0),th3"l.iff"(pos(mn(ksi0,eta0)),more(ksi0,mn0(mn0(eta0))),t54".3182"(mn0(eta0)),p)):more(ksi0,eta0)
eta0@[i:is(mn(ksi0,eta0),0)]
satz182b:=tris(rl,ksi0,mn0(mn0(eta0)),eta0,th3"l.iff"(is(mn(ksi0,eta0),0),is(ksi0,mn0(mn0(eta0))),t55".3182"(mn0(eta0)),i),satz177(eta0)):is(ksi0,eta0)
eta0@[n:neg(mn(ksi0,eta0))]
satz182c:=isless2(mn0(mn0(eta0)),eta0,ksi0,satz177(eta0),th3"l.iff"(neg(mn(ksi0,eta0)),less(ksi0,mn0(mn0(eta0))),t56".3182"(mn0(eta0)),n)):less(ksi0,eta0)
eta0@[m:more(ksi0,eta0)]
satz182d:=th4"l.iff"(pos(mn(ksi0,eta0)),more(ksi0,mn0(mn0(eta0))),t54".3182"(mn0(eta0)),ismore2(eta0,mn0(mn0(eta0)),ksi0,satz177a(eta0),m)):pos(mn(ksi0,eta0))
eta0@[i:is(ksi0,eta0)]
satz182e:=th4"l.iff"(is(mn(ksi0,eta0),0),is(ksi0,mn0(mn0(eta0))),t55".3182"(mn0(eta0)),tris(rl,ksi0,eta0,mn0(mn0(eta0)),i,satz177a(eta0))):is(mn(ksi0,eta0),0)
eta0@[l:less(ksi0,eta0)]
satz182f:=th4"l.iff"(neg(mn(ksi0,eta0)),less(ksi0,mn0(mn0(eta0))),t56".3182"(mn0(eta0)),isless2(eta0,mn0(mn0(eta0)),ksi0,satz177a(eta0),l)):neg(mn(ksi0,eta0))
+3183
eta0@t1:=tris(rl,mn(mn0(eta0),mn0(ksi0)),pl(mn0(eta0),ksi0),mn(ksi0,eta0),ispl2(mn0(mn0(ksi0)),ksi0,mn0(eta0),satz177(ksi0)),compl(mn0(eta0),ksi0)):is(mn(mn0(eta0),mn0(ksi0)),mn(ksi0,eta0))
t2:=tris1(rl,mn(ksi0,eta0),mn0(mn(mn0(ksi0),mn0(eta0))),mn(mn0(eta0),mn0(ksi0)),t1,satz181a(mn0(eta0),mn0(ksi0))):is(mn(ksi0,eta0),mn0(mn(mn0(ksi0),mn0(eta0))))
t3:=tris2(rl,mn(mn0(ksi0),mn0(eta0)),mn0(mn(ksi0,eta0)),mn(eta0,ksi0),t1(eta0,ksi0),satz181(ksi0,eta0)):is(mn(mn0(ksi0),mn0(eta0)),mn0(mn(ksi0,eta0)))
-3183
eta0@[m:more(ksi0,eta0)]
+*3183
m@t4:=isp(rl,[x:rl]pos(x),mn(ksi0,eta0),mn0(mn(mn0(ksi0),mn0(eta0))),satz182d(ksi0,eta0,m),t2):pos(mn0(mn(mn0(ksi0),mn0(eta0))))
-3183
m@satz183a:=satz182c(mn0(ksi0),mn0(eta0),satz176f(mn(mn0(ksi0),mn0(eta0)),t4".3183")):less(mn0(ksi0),mn0(eta0))
eta0@[i:is(ksi0,eta0)]
+*3183
i@t5:=tris1(rl,mn0(mn(mn0(ksi0),mn0(eta0))),0,mn(ksi0,eta0),t2,satz182e(ksi0,eta0,i)):is(mn0(mn(mn0(ksi0),mn0(eta0))),0)
-3183
i@satz183b:=satz182b(mn0(ksi0),mn0(eta0),satz176e(mn(mn0(ksi0),mn0(eta0)),t5".3183")):is(mn0(ksi0),mn0(eta0))
+*3183
i@andersb:=ismn0(ksi0,eta0,i):is(mn0(ksi0),mn0(eta0))
-3183
eta0@[l:less(ksi0,eta0)]
+*3183
l@t6:=isp(rl,[x:rl]neg(x),mn(ksi0,eta0),mn0(mn(mn0(ksi0),mn0(eta0))),satz182f(ksi0,eta0,l),t2):neg(mn0(mn(mn0(ksi0),mn0(eta0))))
-3183
l@satz183c:=satz182a(mn0(ksi0),mn0(eta0),satz176d(mn(mn0(ksi0),mn0(eta0)),t6".3183")):more(mn0(ksi0),mn0(eta0))
eta0@[l:less(mn0(ksi0),mn0(eta0))]
+*3183
l@t7:=isp(rl,[x:rl]neg(x),mn(mn0(ksi0),mn0(eta0)),mn0(mn(ksi0,eta0)),satz182f(mn0(ksi0),mn0(eta0),l),t3):neg(mn0(mn(ksi0,eta0)))
-3183
l@satz183d:=satz182a(ksi0,eta0,satz176d(mn(ksi0,eta0),t7".3183")):more(ksi0,eta0)
+*3183
l@andersd:=ismore12(mn0(mn0(ksi0)),ksi0,mn0(mn0(eta0)),eta0,satz177(ksi0),satz177(eta0),satz183c(mn0(ksi0),mn0(eta0),l)):more(ksi0,eta0)
-3183
eta0@[i:is(mn0(ksi0),mn0(eta0))]
+*3183
i@t8:=tris1(rl,mn0(mn(ksi0,eta0)),0,mn(mn0(ksi0),mn0(eta0)),t3,satz182e(mn0(ksi0),mn0(eta0),i)):is(mn0(mn(ksi0,eta0)),0)
-3183
i@satz183e:=satz182b(ksi0,eta0,satz176e(mn(ksi0,eta0),t8".3183")):is(ksi0,eta0)
+*3183
i@anderse:=tr3is(rl,ksi0,mn0(mn0(ksi0)),mn0(mn0(eta0)),eta0,satz177a(ksi0),ismn0(mn0(ksi0),mn0(eta0),i),satz177(eta0)):is(ksi0,eta0)
-3183
eta0@[m:more(mn0(ksi0),mn0(eta0))]
+*3183
m@t9:=isp(rl,[x:rl]pos(x),mn(mn0(ksi0),mn0(eta0)),mn0(mn(ksi0,eta0)),satz182d(mn0(ksi0),mn0(eta0),m),t3):pos(mn0(mn(ksi0,eta0)))
-3183
m@satz183f:=satz182c(ksi0,eta0,satz176f(mn(ksi0,eta0),t9".3183")):less(ksi0,eta0)
eta0@[p:pos(ksi0)][q:pos(eta0)][m:more(ksi0,eta0)]
+*iv3
m@t62:=t1(ksi0,eta0,p,q,m):more"rp"(ksi(p),eta(q))
t63:=t2(ksi0,eta0,p,q,m):pos(mna(ksi0,eta0,p,q,m))
t64:=satz182d(ksi0,eta0,m):pos(mn(ksi0,eta0))
t65:=tris(cut,rpofp(mn(ksi0,eta0),t64),rpofp(mna(ksi0,eta0,p,q,m),t63),mn"rp"(ksi(p),eta(q),t62),isperp(mn(ksi0,eta0),t64,mna(ksi0,eta0,p,q,m),t63,mnpp(ksi0,eta0,p,q,m)),isrpp2(mn"rp"(ksi(p),eta(q),t62))):is"rp"(rpofp(mn(ksi0,eta0),t64),mn"rp"(ksi(p),eta(q),t62))
t66:=tris(cut,pl"rp"(eta(q),rpofp(mn(ksi0,eta0),t64)),pl"rp"(eta(q),mn"rp"(ksi(p),eta(q),t62)),ksi(p),ispl2"rp"(rpofp(mn(ksi0,eta0),t64),mn"rp"(ksi(p),eta(q),t62),eta(q),t65),satz140c(ksi(p),eta(q),t62)):is"rp"(pl"rp"(eta(q),rpofp(mn(ksi0,eta0),t64)),ksi(p))
-iv3
m@satz140cp:=tr3is(rl,pl(eta0,mn(ksi0,eta0)),pofrp(pl"rp"(eta".iv3"(q),rpofp(mn(ksi0,eta0),t64".iv3"))),pofrp(ksi".iv3"(p)),ksi0,plpp(eta0,mn(ksi0,eta0),q,t64".iv3"),isrpep(pl"rp"(eta".iv3"(q),rpofp(mn(ksi0,eta0),t64".iv3")),ksi".iv3"(p),t66".iv3"),isprp2(ksi0,p)):is(pl(eta0,mn(ksi0,eta0)),ksi0)
satz140dp:=symis(rl,pl(eta0,mn(ksi0,eta0)),ksi0,satz140cp):is(ksi0,pl(eta0,mn(ksi0,eta0)))
satz140ep:=tris(rl,pl(mn(ksi0,eta0),eta0),pl(eta0,mn(ksi0,eta0)),ksi0,compl(mn(ksi0,eta0),eta0),satz140cp):is(pl(mn(ksi0,eta0),eta0),ksi0)
satz140fp:=symis(rl,pl(mn(ksi0,eta0),eta0),ksi0,satz140ep):is(ksi0,pl(mn(ksi0,eta0),eta0))
zeta0@[p:pos(ksi0)][q:pos(eta0)][r:pos(zeta0)][i:is(pl(eta0,zeta0),ksi0)]
+*iv3
i@t67:=tr3is(rl,pofrp(pl"rp"(eta(q),zeta(r))),pl(eta0,zeta0),ksi0,pofrp(ksi(p)),symis(rl,pl(eta0,zeta0),pofrp(pl"rp"(eta(q),zeta(r))),plpp(eta0,zeta0,q,r)),i,isprp1(ksi0,p)):is(pofrp(pl"rp"(eta(q),zeta(r))),pofrp(ksi(p)))
t68:=isrpip(pl"rp"(eta(q),zeta(r)),ksi(p),t67):is"rp"(pl"rp"(eta(q),zeta(r)),ksi(p))
t69:=moreipp(ksi0,eta0,p,q,ismore1"rp"(pl"rp"(eta(q),zeta(r)),ksi(p),eta(q),t68,satz133(eta(q),zeta(r)))):more(ksi0,eta0)
t70:=t1(ksi0,eta0,p,q,t69):more"rp"(ksi(p),eta(q))
t71:=satz140g(ksi(p),eta(q),zeta(r),t70,t68):is"rp"(zeta(r),mn"rp"(ksi(p),eta(q),t70))
-iv3
i@satz140gp:=tr3is(rl,zeta0,pofrp(zeta".iv3"(r)),mna(ksi0,eta0,p,q,t69".iv3"),mn(ksi0,eta0),isprp1(zeta0,r),isrpep(zeta".iv3"(r),mn"rp"(ksi".iv3"(p),eta".iv3"(q),t70".iv3"),t71".iv3"),symis(rl,mn(ksi0,eta0),mna(ksi0,eta0,p,q,t69".iv3"),mnpp(ksi0,eta0,p,q,t69".iv3"))):is(zeta0,mn(ksi0,eta0))
r@[i:is(pl(zeta0,eta0),ksi0)]
satz140hp:=satz140gp(tris(rl,pl(eta0,zeta0),pl(zeta0,eta0),ksi0,compl(eta0,zeta0),i)):is(zeta0,mn(ksi0,eta0))
+*iv3
r@t72:=pospl(ksi0,eta0,p,q):pos(pl(ksi0,eta0))
t73:=pospl(eta0,zeta0,q,r):pos(pl(eta0,zeta0))
t74:=tris(cut,rpofp(pl(ksi0,eta0),t72),rpofp(pofrp(pl"rp"(ksi(p),eta(q))),posi(pl"rp"(ksi(p),eta(q)))),pl"rp"(ksi(p),eta(q)),isperp(pl(ksi0,eta0),t72,pofrp(pl"rp"(ksi(p),eta(q))),posi(pl"rp"(ksi(p),eta(q))),plpp(ksi0,eta0,p,q)),isrpp2(pl"rp"(ksi(p),eta(q)))):is"rp"(rpofp(pl(ksi0,eta0),t72),pl"rp"(ksi(p),eta(q)))
t75:=symis(cut,rpofp(pl(eta0,zeta0),t73),pl"rp"(eta(q),zeta(r)),t74(eta0,zeta0,ksi0,q,r,p)):is"rp"(pl"rp"(eta(q),zeta(r)),rpofp(pl(eta0,zeta0),t73))
t76:=tr3is(cut,pl"rp"(rpofp(pl(ksi0,eta0),t72),zeta(r)),pl"rp"(pl"rp"(ksi(p),eta(q)),zeta(r)),pl"rp"(ksi(p),pl"rp"(eta(q),zeta(r))),pl"rp"(ksi(p),rpofp(pl(eta0,zeta0),t73)),ispl1"rp"(rpofp(pl(ksi0,eta0),t72),pl"rp"(ksi(p),eta(q)),zeta(r),t74),asspl1(ksi(p),eta(q),zeta(r)),ispl2"rp"(pl"rp"(eta(q),zeta(r)),rpofp(pl(eta0,zeta0),t73),ksi(p),t75)):is"rp"(pl"rp"(rpofp(pl(ksi0,eta0),t72),zeta(r)),pl"rp"(ksi(p),rpofp(pl(eta0,zeta0),t73)))
t77:=tr3is(rl,pl(pl(ksi0,eta0),zeta0),pofrp(pl"rp"(rpofp(pl(ksi0,eta0),t72),zeta(r))),pofrp(pl"rp"(ksi(p),rpofp(pl(eta0,zeta0),t73))),pl(ksi0,pl(eta0,zeta0)),plpp(pl(ksi0,eta0),zeta0,t72,r),isrpep(pl"rp"(rpofp(pl(ksi0,eta0),t72),zeta(r)),pl"rp"(ksi(p),rpofp(pl(eta0,zeta0),t73)),t76),symis(rl,pl(ksi0,pl(eta0,zeta0)),pofrp(pl"rp"(ksi(p),rpofp(pl(eta0,zeta0),t73))),plpp(ksi0,pl(eta0,zeta0),p,t73))):is(pl(pl(ksi0,eta0),zeta0),pl(ksi0,pl(eta0,zeta0)))
-iv3
r@asspl1p:=t77".iv3":is(pl(pl(ksi0,eta0),zeta0),pl(ksi0,pl(eta0,zeta0)))
asspl2p:=symis(rl,pl(pl(ksi0,eta0),zeta0),pl(ksi0,pl(eta0,zeta0)),t77".iv3"):is(pl(ksi0,pl(eta0,zeta0)),pl(pl(ksi0,eta0),zeta0))
@1rl:=pofrp(1rp):rl
pos1:=posi(1rp):pos(1rl)
+3184
ksi0@[p:pos(ksi0)]
t1:=pospl(ksi0,1rl,p,pos1):pos(pl(ksi0,1rl))
t2:=satz140gp(pl(ksi0,1rl),1rl,ksi0,t1,pos1,p,compl(1rl,ksi0)):is(ksi0,mn(pl(ksi0,1rl),1rl))
t3:=and3i(pos(pl(ksi0,1rl)),pos(1rl),is(ksi0,mn(pl(ksi0,1rl),1rl)),t1,pos1,t2):and3(pos(pl(ksi0,1rl)),pos(1rl),is(ksi0,mn(pl(ksi0,1rl),1rl)))
t4:=somei(rl,[x:rl]and3(pos(pl(ksi0,1rl)),pos(x),is(ksi0,mn(pl(ksi0,1rl),x))),1rl,t3):some([x:rl]and3(pos(pl(ksi0,1rl)),pos(x),is(ksi0,mn(pl(ksi0,1rl),x))))
t5:=somei(rl,[x:rl]some([y:rl]and3(pos(x),pos(y),is(ksi0,mn(x,y)))),pl(ksi0,1rl),t4):some([x:rl]some([y:rl]and3(pos(x),pos(y),is(ksi0,mn(x,y)))))
ksi0@[i:is(ksi0,0)]
t6:=tris2(rl,ksi0,mn(1rl,1rl),0,i,satz182e(1rl,1rl,refis(rl,1rl))):is(ksi0,mn(1rl,1rl))
t7:=and3i(pos(1rl),pos(1rl),is(ksi0,mn(1rl,1rl)),pos1,pos1,t6):and3(pos(1rl),pos(1rl),is(ksi0,mn(1rl,1rl)))
t8:=somei(rl,[x:rl]and3(pos(1rl),pos(x),is(ksi0,mn(1rl,x))),1rl,t7):some([x:rl]and3(pos(1rl),pos(x),is(ksi0,mn(1rl,x))))
t9:=somei(rl,[x:rl]some([y:rl]and3(pos(x),pos(y),is(ksi0,mn(x,y)))),1rl,t8):some([x:rl]some([y:rl]and3(pos(x),pos(y),is(ksi0,mn(x,y)))))
ksi0@[n:neg(ksi0)]
t10:=t2(mn0(ksi0),satz176c(ksi0,n)):is(mn0(ksi0),mn(pl(mn0(ksi0),1rl),1rl))
t11:=tr3is(rl,ksi0,mn0(mn0(ksi0)),mn0(mn(pl(mn0(ksi0),1rl),1rl)),mn(1rl,pl(mn0(ksi0),1rl)),satz177a(ksi0),ismn0(mn0(ksi0),mn(pl(mn0(ksi0),1rl),1rl),t10),satz181(pl(mn0(ksi0),1rl),1rl)):is(ksi0,mn(1rl,pl(mn0(ksi0),1rl)))
t12:=and3i(pos(1rl),pos(pl(mn0(ksi0),1rl)),is(ksi0,mn(1rl,pl(mn0(ksi0),1rl))),pos1,t1(mn0(ksi0),satz176c(ksi0,n)),t11):and3(pos(1rl),pos(pl(mn0(ksi0),1rl)),is(ksi0,mn(1rl,pl(mn0(ksi0),1rl))))
t13:=somei(rl,[x:rl]and3(pos(1rl),pos(x),is(ksi0,mn(1rl,x))),pl(mn0(ksi0),1rl),t12):some([x:rl]and3(pos(1rl),pos(x),is(ksi0,mn(1rl,x))))
t14:=somei(rl,[x:rl]some([y:rl]and3(pos(x),pos(y),is(ksi0,mn(x,y)))),1rl,t13):some([x:rl]some([y:rl]and3(pos(x),pos(y),is(ksi0,mn(x,y)))))
-3184
ksi0@satz184:=rlapp(ksi0,some([x:rl]some([y:rl]and3(pos(x),pos(y),is(ksi0,mn(x,y))))),[t:pos(ksi0)]t5".3184"(t),[t:is(ksi0,0)]t9".3184"(t),[t:neg(ksi0)]t14".3184"(t)):some([x:rl]some([y:rl]and3(pos(x),pos(y),is(ksi0,mn(x,y)))))
[p:'prop'][p1:[x:rl][y:rl][t:pos(x)][u:pos(y)][v:is(ksi0,mn(x,y))]p]
+*3184
p1@[eta0:rl][s:some([x:rl]and3(pos(eta0),pos(x),is(ksi0,mn(eta0,x))))][zeta0:rl][a:and3(pos(eta0),pos(zeta0),is(ksi0,mn(eta0,zeta0)))]
t15:=and3e1(pos(eta0),pos(zeta0),is(ksi0,mn(eta0,zeta0)),a):pos(eta0)
t16:=and3e2(pos(eta0),pos(zeta0),is(ksi0,mn(eta0,zeta0)),a):pos(zeta0)
t17:=and3e3(pos(eta0),pos(zeta0),is(ksi0,mn(eta0,zeta0)),a):is(ksi0,mn(eta0,zeta0))
t18:=<t17><t16><t15><zeta0><eta0>p1:p
s@t19:=someapp(rl,[x:rl]and3(pos(eta0),pos(x),is(ksi0,mn(eta0,x))),s,p,[x:rl][t:and3(pos(eta0),pos(x),is(ksi0,mn(eta0,x)))]t18(x,t)):p
-3184
p1@satz184app:=someapp(rl,[x:rl]some([y:rl]and3(pos(x),pos(y),is(ksi0,mn(x,y)))),satz184,p,[x:rl][t:some([y:rl]and3(pos(x),pos(y),is(ksi0,mn(x,y))))]t19".3184"(x,t)):p
ksi0@[eta0:rl][ksi1:rl][ksi2:rl][eta1:rl][eta2:rl][p1:pos(ksi1)][p2:pos(ksi2)][q1:pos(eta1)][q2:pos(eta2)][ix:is(ksi0,mn(ksi1,ksi2))][iy:is(eta0,mn(eta1,eta2))]
+3185
[i:is(ksi0,0)]
t1:=satz182b(ksi1,ksi2,tris1(rl,mn(ksi1,ksi2),0,ksi0,ix,i)):is(ksi1,ksi2)
t2:=pl01(ksi0,eta0,i):is(pl(ksi0,eta0),eta0)
[m:more(eta1,eta2)]
t3:=tris1(rl,pl(ksi2,eta2),pl(eta2,ksi1),pl(ksi1,eta2),ispl1(ksi1,ksi2,eta2,t1),compl(ksi1,eta2)):is(pl(ksi2,eta2),pl(eta2,ksi1))
t4:=tr4is(rl,pl(mn(eta1,eta2),pl(ksi2,eta2)),pl(mn(eta1,eta2),pl(eta2,ksi1)),pl(pl(mn(eta1,eta2),eta2),ksi1),pl(eta1,ksi1),pl(ksi1,eta1),ispl2(pl(ksi2,eta2),pl(eta2,ksi1),mn(eta1,eta2),t3),asspl2p(mn(eta1,eta2),eta2,ksi1,satz182d(eta1,eta2,m),q2,p1),ispl1(pl(mn(eta1,eta2),eta2),eta1,ksi1,satz140ep(eta1,eta2,q1,q2,m)),compl(eta1,ksi1)):is(pl(mn(eta1,eta2),pl(ksi2,eta2)),pl(ksi1,eta1))
t5:=tris(rl,eta0,mn(eta1,eta2),mn(pl(ksi1,eta1),pl(ksi2,eta2)),iy,satz140hp(pl(ksi1,eta1),pl(ksi2,eta2),mn(eta1,eta2),pospl(ksi1,eta1,p1,q1),pospl(ksi2,eta2,p2,q2),satz182d(eta1,eta2,m),t4)):is(eta0,mn(pl(ksi1,eta1),pl(ksi2,eta2)))
i@[j:is(eta1,eta2)]
t6:=symis(rl,mn(pl(ksi1,eta1),pl(ksi2,eta2)),0,satz182e(pl(ksi1,eta1),pl(ksi2,eta2),ispl12(ksi1,ksi2,eta1,eta2,t1,j))):is(0,mn(pl(ksi1,eta1),pl(ksi2,eta2)))
t7:=tr3is(rl,eta0,mn(eta1,eta2),0,mn(pl(ksi1,eta1),pl(ksi2,eta2)),iy,satz182e(eta1,eta2,j),t6):is(eta0,mn(pl(ksi1,eta1),pl(ksi2,eta2)))
i@[l:less(eta1,eta2)]
t8:=tris2(rl,ksi0,mn(ksi2,ksi1),0,i,satz182e(ksi2,ksi1,symis(rl,ksi1,ksi2,t1))):is(ksi0,mn(ksi2,ksi1))
t9:=tris(rl,mn0(eta0),mn0(mn(eta1,eta2)),mn(eta2,eta1),ismn0(eta0,mn(eta1,eta2),iy),satz181(eta1,eta2)):is(mn0(eta0),mn(eta2,eta1))
t10:=t5(ksi0,mn0(eta0),ksi2,ksi1,eta2,eta1,p2,p1,q2,q1,t8,t9,i,l):is(mn0(eta0),mn(pl(ksi2,eta2),pl(ksi1,eta1)))
t11:=tr3is(rl,eta0,mn0(mn0(eta0)),mn0(mn(pl(ksi2,eta2),pl(ksi1,eta1))),mn(pl(ksi1,eta1),pl(ksi2,eta2)),satz177a(eta0),ismn0(mn0(eta0),mn(pl(ksi2,eta2),pl(ksi1,eta1)),t10),satz181(pl(ksi2,eta2),pl(ksi1,eta1))):is(eta0,mn(pl(ksi1,eta1),pl(ksi2,eta2)))
i@t12:=or3app(is(eta1,eta2),more(eta1,eta2),less(eta1,eta2),is(eta0,mn(pl(ksi1,eta1),pl(ksi2,eta2))),satz167a(eta1,eta2),[t:is(eta1,eta2)]t7(t),[t:more(eta1,eta2)]t5(t),[t:less(eta1,eta2)]t11(t)):is(eta0,mn(pl(ksi1,eta1),pl(ksi2,eta2)))
t13:=tris(rl,pl(ksi0,eta0),eta0,mn(pl(ksi1,eta1),pl(ksi2,eta2)),t2,t12):is(pl(ksi0,eta0),mn(pl(ksi1,eta1),pl(ksi2,eta2)))
iy@[p:pos(ksi0)]
t13a:=satz182a(ksi1,ksi2,isp(rl,[x:rl]pos(x),ksi0,mn(ksi1,ksi2),p,ix)):more(ksi1,ksi2)
[q:pos(eta0)]
@[alpha:rl][beta:rl][gamma:rl][delta:rl][pa:pos(alpha)][pb:pos(beta)][pc:pos(gamma)][pd:pos(delta)]
t14:=pospl(alpha,beta,pa,pb):pos(pl(alpha,beta))
t15:=pospl(beta,delta,pb,pd):pos(pl(beta,delta))
t16:=tr3is(rl,pl(pl(alpha,beta),pl(gamma,delta)),pl(pl(alpha,beta),pl(delta,gamma)),pl(pl(pl(alpha,beta),delta),gamma),pl(gamma,pl(pl(alpha,beta),delta)),ispl2(pl(gamma,delta),pl(delta,gamma),pl(alpha,beta),compl(gamma,delta)),asspl2p(pl(alpha,beta),delta,gamma,t14,pd,pc),compl(pl(pl(alpha,beta),delta),gamma)):is(pl(pl(alpha,beta),pl(gamma,delta)),pl(gamma,pl(pl(alpha,beta),delta)))
t17:=tr3is(rl,pl(pl(alpha,beta),pl(gamma,delta)),pl(gamma,pl(pl(alpha,beta),delta)),pl(gamma,pl(alpha,pl(beta,delta))),pl(pl(gamma,alpha),pl(beta,delta)),t16,ispl2(pl(pl(alpha,beta),delta),pl(alpha,pl(beta,delta)),gamma,asspl1p(alpha,beta,delta,pa,pb,pd)),asspl2p(gamma,alpha,pl(beta,delta),pc,pa,t15)):is(pl(pl(alpha,beta),pl(gamma,delta)),pl(pl(gamma,alpha),pl(beta,delta)))
q@t18:=tris(rl,pl(ksi2,ksi0),pl(ksi2,mn(ksi1,ksi2)),ksi1,ispl2(ksi0,mn(ksi1,ksi2),ksi2,ix),satz140cp(ksi1,ksi2,p1,p2,t13a)):is(pl(ksi2,ksi0),ksi1)
t19:=tris(rl,pl(eta0,eta2),pl(eta2,eta0),eta1,compl(eta0,eta2),t18(eta0,ksi0,eta1,eta2,ksi1,ksi2,q1,q2,p1,p2,iy,ix,q,p)):is(pl(eta0,eta2),eta1)
t20:=tris(rl,pl(pl(ksi0,eta0),pl(ksi2,eta2)),pl(pl(ksi2,ksi0),pl(eta0,eta2)),pl(ksi1,eta1),t17(ksi0,eta0,ksi2,eta2,p,q,p2,q2),ispl12(pl(ksi2,ksi0),ksi1,pl(eta0,eta2),eta1,t18,t19)):is(pl(pl(ksi0,eta0),pl(ksi2,eta2)),pl(ksi1,eta1))
t21:=satz140hp(pl(ksi1,eta1),pl(ksi2,eta2),pl(ksi0,eta0),pospl(ksi1,eta1,p1,q1),pospl(ksi2,eta2,p2,q2),pospl(ksi0,eta0,p,q),t20):is(pl(ksi0,eta0),mn(pl(ksi1,eta1),pl(ksi2,eta2)))
iy@[i:is(eta0,0)]
t22:=tr3is(rl,pl(ksi0,eta0),pl(eta0,ksi0),mn(pl(eta1,ksi1),pl(eta2,ksi2)),mn(pl(ksi1,eta1),pl(ksi2,eta2)),compl(ksi0,eta0),t13(eta0,ksi0,eta1,eta2,ksi1,ksi2,q1,q2,p1,p2,iy,ix,i),ismn12(pl(eta1,ksi1),pl(ksi1,eta1),pl(eta2,ksi2),pl(ksi2,eta2),compl(eta1,ksi1),compl(eta2,ksi2))):is(pl(ksi0,eta0),mn(pl(ksi1,eta1),pl(ksi2,eta2)))
p@[n:neg(eta0)]
t23:=isp(rl,[x:rl]pos(x),ksi0,mn(ksi1,ksi2),p,ix):pos(mn(ksi1,ksi2))
t24:=tr3is(rl,abs(eta0),mn0(eta0),mn0(mn(eta1,eta2)),mn(eta2,eta1),symis(rl,mn0(eta0),abs(eta0),mn0n(eta0,n)),ismn0(eta0,mn(eta1,eta2),iy),satz181(eta1,eta2)):is(abs(eta0),mn(eta2,eta1))
t25:=isp(rl,[x:rl]pos(x),abs(eta0),mn(eta2,eta1),satz166b(eta0,n),t24):pos(mn(eta2,eta1))
t26:=satz182a(ksi1,ksi2,t23):more(ksi1,ksi2)
t27:=satz182a(eta2,eta1,t25):more(eta2,eta1)
[m:more(ksi0,abs(eta0))]
t28:=ismore12(ksi0,mn(ksi1,ksi2),abs(eta0),mn(eta2,eta1),ix,t24,m):more(mn(ksi1,ksi2),mn(eta2,eta1))
t29:=tr3is(rl,pl(ksi1,eta1),pl(pl(mn(ksi1,ksi2),ksi2),eta1),pl(mn(ksi1,ksi2),pl(ksi2,eta1)),pl(pl(ksi2,eta1),mn(ksi1,ksi2)),ispl1(ksi1,pl(mn(ksi1,ksi2),ksi2),eta1,satz140fp(ksi1,ksi2,p1,p2,t26)),asspl1p(mn(ksi1,ksi2),ksi2,eta1,t23,p2,q1),compl(mn(ksi1,ksi2),pl(ksi2,eta1))):is(pl(ksi1,eta1),pl(pl(ksi2,eta1),mn(ksi1,ksi2)))
t30:=tr3is(rl,pl(ksi1,eta1),pl(pl(ksi2,eta1),mn(ksi1,ksi2)),pl(pl(ksi2,eta1),pl(mn(eta2,eta1),mn(mn(ksi1,ksi2),mn(eta2,eta1)))),pl(pl(pl(ksi2,eta1),mn(eta2,eta1)),mn(mn(ksi1,ksi2),mn(eta2,eta1))),t29,ispl2(mn(ksi1,ksi2),pl(mn(eta2,eta1),mn(mn(ksi1,ksi2),mn(eta2,eta1))),pl(ksi2,eta1),satz140dp(mn(ksi1,ksi2),mn(eta2,eta1),t23,t25,t28)),asspl2p(pl(ksi2,eta1),mn(eta2,eta1),mn(mn(ksi1,ksi2),mn(eta2,eta1)),pospl(ksi2,eta1,p2,q1),t25,satz182d(mn(ksi1,ksi2),mn(eta2,eta1),t28))):is(pl(ksi1,eta1),pl(pl(pl(ksi2,eta1),mn(eta2,eta1)),mn(mn(ksi1,ksi2),mn(eta2,eta1))))
t31:=tris(rl,pl(ksi2,eta2),pl(ksi2,pl(eta1,mn(eta2,eta1))),pl(pl(ksi2,eta1),mn(eta2,eta1)),ispl2(eta2,pl(eta1,mn(eta2,eta1)),ksi2,satz140dp(eta2,eta1,q2,q1,t27)),asspl2p(ksi2,eta1,mn(eta2,eta1),p2,q1,t25)):is(pl(ksi2,eta2),pl(pl(ksi2,eta1),mn(eta2,eta1)))
t32:=ismn12(ksi0,mn(ksi1,ksi2),abs(eta0),mn(eta2,eta1),ix,t24):is(mn(ksi0,abs(eta0)),mn(mn(ksi1,ksi2),mn(eta2,eta1)))
t33:=tris2(rl,pl(pl(ksi2,eta2),mn(ksi0,abs(eta0))),pl(ksi1,eta1),pl(pl(pl(ksi2,eta1),mn(eta2,eta1)),mn(mn(ksi1,ksi2),mn(eta2,eta1))),ispl12(pl(ksi2,eta2),pl(pl(ksi2,eta1),mn(eta2,eta1)),mn(ksi0,abs(eta0)),mn(mn(ksi1,ksi2),mn(eta2,eta1)),t31,t32),t30):is(pl(pl(ksi2,eta2),mn(ksi0,abs(eta0))),pl(ksi1,eta1))
t33a:=tris(rl,eta0,mn0(mn0(eta0)),mn0(abs(eta0)),satz177a(eta0),ismn0(mn0(eta0),abs(eta0),mn0n(eta0,n))):is(eta0,mn0(abs(eta0)))
t34:=tris(rl,pl(ksi0,eta0),mn(ksi0,abs(eta0)),mn(pl(ksi1,eta1),pl(ksi2,eta2)),ispl2(eta0,mn0(abs(eta0)),ksi0,t33a),satz140gp(pl(ksi1,eta1),pl(ksi2,eta2),mn(ksi0,abs(eta0)),pospl(ksi1,eta1,p1,q1),pospl(ksi2,eta2,p2,q2),satz182d(ksi0,abs(eta0),m),t33)):is(pl(ksi0,eta0),mn(pl(ksi1,eta1),pl(ksi2,eta2)))
n@[l:less(ksi0,abs(eta0))]
t35:=satz176c(eta0,n):pos(mn0(eta0))
t36:=satz176a(ksi0,p):neg(mn0(ksi0))
t37:=ismore12(abs(eta0),mn0(eta0),ksi0,abs(mn0(ksi0)),symis(rl,mn0(eta0),abs(eta0),mn0n(eta0,n)),symis(rl,abs(mn0(ksi0)),ksi0,lemma177(ksi0,p)),l):more(mn0(eta0),abs(mn0(ksi0)))
t38:=tris(rl,mn0(ksi0),mn0(mn(ksi1,ksi2)),mn(ksi2,ksi1),ismn0(ksi0,mn(ksi1,ksi2),ix),satz181(ksi1,ksi2)):is(mn0(ksi0),mn(ksi2,ksi1))
t39:=tris(rl,mn0(eta0),mn0(mn(eta1,eta2)),mn(eta2,eta1),ismn0(eta0,mn(eta1,eta2),iy),satz181(eta1,eta2)):is(mn0(eta0),mn(eta2,eta1))
t40:=t34(mn0(eta0),mn0(ksi0),eta2,eta1,ksi2,ksi1,q2,q1,p2,p1,t39,t38,t35,t36,t37):is(pl(mn0(eta0),mn0(ksi0)),mn(pl(eta2,ksi2),pl(eta1,ksi1)))
t41:=tr3is(rl,mn0(pl(eta0,ksi0)),pl(mn0(eta0),mn0(ksi0)),mn(pl(eta2,ksi2),pl(eta1,ksi1)),mn(pl(ksi2,eta2),pl(ksi1,eta1)),satz180a(eta0,ksi0),t40,ismn12(pl(eta2,ksi2),pl(ksi2,eta2),pl(eta1,ksi1),pl(ksi1,eta1),compl(eta2,ksi2),compl(eta1,ksi1))):is(mn0(pl(eta0,ksi0)),mn(pl(ksi2,eta2),pl(ksi1,eta1)))
t42:=tr4is(rl,pl(ksi0,eta0),pl(eta0,ksi0),mn0(mn0(pl(eta0,ksi0))),mn0(mn(pl(ksi2,eta2),pl(ksi1,eta1))),mn(pl(ksi1,eta1),pl(ksi2,eta2)),compl(ksi0,eta0),satz177a(pl(eta0,ksi0)),ismn0(mn0(pl(eta0,ksi0)),mn(pl(ksi2,eta2),pl(ksi1,eta1)),t41),satz181(pl(ksi2,eta2),pl(ksi1,eta1))):is(pl(ksi0,eta0),mn(pl(ksi1,eta1),pl(ksi2,eta2)))
n@[i:is(ksi0,abs(eta0))]
t43:=tr3is(rl,mn(ksi1,ksi2),ksi0,abs(eta0),mn(eta2,eta1),symis(rl,ksi0,mn(ksi1,ksi2),ix),i,t24):is(mn(ksi1,ksi2),mn(eta2,eta1))
t44:=tris(rl,ksi1,pl(ksi2,mn(ksi1,ksi2)),pl(ksi2,mn(eta2,eta1)),satz140dp(ksi1,ksi2,p1,p2,t26),ispl2(mn(ksi1,ksi2),mn(eta2,eta1),ksi2,t43)):is(ksi1,pl(ksi2,mn(eta2,eta1)))
t45:=tr3is(rl,pl(ksi1,eta1),pl(pl(ksi2,mn(eta2,eta1)),eta1),pl(ksi2,pl(mn(eta2,eta1),eta1)),pl(ksi2,eta2),ispl1(ksi1,pl(ksi2,mn(eta2,eta1)),eta1,t44),asspl1p(ksi2,mn(eta2,eta1),eta1,p2,t25,q1),ispl2(pl(mn(eta2,eta1),eta1),eta2,ksi2,satz140ep(eta2,eta1,q2,q1,t27))):is(pl(ksi1,eta1),pl(ksi2,eta2))
t46:=tris2(rl,pl(ksi0,eta0),mn(pl(ksi1,eta1),pl(ksi2,eta2)),0,plpn2(ksi0,eta0,p,n,i),satz182e(pl(ksi1,eta1),pl(ksi2,eta2),t45)):is(pl(ksi0,eta0),mn(pl(ksi1,eta1),pl(ksi2,eta2)))
n@t47:=or3app(is(ksi0,abs(eta0)),more(ksi0,abs(eta0)),less(ksi0,abs(eta0)),is(pl(ksi0,eta0),mn(pl(ksi1,eta1),pl(ksi2,eta2))),satz167a(ksi0,abs(eta0)),[t:is(ksi0,abs(eta0))]t46(t),[t:more(ksi0,abs(eta0))]t34(t),[t:less(ksi0,abs(eta0))]t42(t)):is(pl(ksi0,eta0),mn(pl(ksi1,eta1),pl(ksi2,eta2)))
p@t48:=rlapp(eta0,is(pl(ksi0,eta0),mn(pl(ksi1,eta1),pl(ksi2,eta2))),[t:pos(eta0)]t21(t),[t:is(eta0,0)]t22(t),[t:neg(eta0)]t47(t)):is(pl(ksi0,eta0),mn(pl(ksi1,eta1),pl(ksi2,eta2)))
iy@[n:neg(ksi0)][p:pos(eta0)]
t49:=tr3is(rl,pl(ksi0,eta0),pl(eta0,ksi0),mn(pl(eta1,ksi1),pl(eta2,ksi2)),mn(pl(ksi1,eta1),pl(ksi2,eta2)),compl(ksi0,eta0),t47(eta0,ksi0,eta1,eta2,ksi1,ksi2,q1,q2,p1,p2,iy,ix,p,n),ismn12(pl(eta1,ksi1),pl(ksi1,eta1),pl(eta2,ksi2),pl(ksi2,eta2),compl(eta1,ksi1),compl(eta2,ksi2))):is(pl(ksi0,eta0),mn(pl(ksi1,eta1),pl(ksi2,eta2)))
n@[o:neg(eta0)]
t50:=satz176c(ksi0,n):pos(mn0(ksi0))
t51:=satz176c(eta0,o):pos(mn0(eta0))
t52:=tris(rl,mn0(ksi0),mn0(mn(ksi1,ksi2)),mn(ksi2,ksi1),ismn0(ksi0,mn(ksi1,ksi2),ix),satz181(ksi1,ksi2)):is(mn0(ksi0),mn(ksi2,ksi1))
t53:=tris(rl,mn0(eta0),mn0(mn(eta1,eta2)),mn(eta2,eta1),ismn0(eta0,mn(eta1,eta2),iy),satz181(eta1,eta2)):is(mn0(eta0),mn(eta2,eta1))
t54:=t21(mn0(ksi0),mn0(eta0),ksi2,ksi1,eta2,eta1,p2,p1,q2,q1,t52,t53,t50,t51):is(pl(mn0(ksi0),mn0(eta0)),mn(pl(ksi2,eta2),pl(ksi1,eta1)))
t55:=tris(rl,mn0(pl(ksi0,eta0)),pl(mn0(ksi0),mn0(eta0)),mn(pl(ksi2,eta2),pl(ksi1,eta1)),satz180a(ksi0,eta0),t54):is(mn0(pl(ksi0,eta0)),mn(pl(ksi2,eta2),pl(ksi1,eta1)))
t56:=tr3is(rl,pl(ksi0,eta0),mn0(mn0(pl(ksi0,eta0))),mn0(mn(pl(ksi2,eta2),pl(ksi1,eta1))),mn(pl(ksi1,eta1),pl(ksi2,eta2)),satz177a(pl(ksi0,eta0)),ismn0(mn0(pl(ksi0,eta0)),mn(pl(ksi2,eta2),pl(ksi1,eta1)),t55),satz181(pl(ksi2,eta2),pl(ksi1,eta1))):is(pl(ksi0,eta0),mn(pl(ksi1,eta1),pl(ksi2,eta2)))
n@t57:=rlapp(eta0,is(pl(ksi0,eta0),mn(pl(ksi1,eta1),pl(ksi2,eta2))),[t:pos(eta0)]t49(t),[t:is(eta0,0)]t22(t),[t:neg(eta0)]t56(t)):is(pl(ksi0,eta0),mn(pl(ksi1,eta1),pl(ksi2,eta2)))
-3185
satz185:=rlapp(ksi0,is(pl(ksi0,eta0),mn(pl(ksi1,eta1),pl(ksi2,eta2))),[t:pos(ksi0)]t48".3185"(t),[t:is(ksi0,0)]t13".3185"(t),[t:neg(ksi0)]t57".3185"(t)):is(pl(ksi0,eta0),mn(pl(ksi1,eta1),pl(ksi2,eta2)))
satz185a:=symis(rl,pl(ksi0,eta0),mn(pl(ksi1,eta1),pl(ksi2,eta2)),satz185):is(mn(pl(ksi1,eta1),pl(ksi2,eta2)),pl(ksi0,eta0))
eta0@[zeta0:rl]
+3186
[ksi1:rl][ksi2:rl][p1:pos(ksi1)][p2:pos(ksi2)][ix:is(ksi0,mn(ksi1,ksi2))][eta1:rl][eta2:rl][q1:pos(eta1)][q2:pos(eta2)][iy:is(eta0,mn(eta1,eta2))][zeta1:rl][zeta2:rl][r1:pos(zeta1)][r2:pos(zeta2)][iz:is(zeta0,mn(zeta1,zeta2))]
t1:=satz185(ksi0,eta0,ksi1,ksi2,eta1,eta2,p1,p2,q1,q2,ix,iy):is(pl(ksi0,eta0),mn(pl(ksi1,eta1),pl(ksi2,eta2)))
t2:=satz185(mn(pl(ksi1,eta1),pl(ksi2,eta2)),zeta0,pl(ksi1,eta1),pl(ksi2,eta2),zeta1,zeta2,pospl(ksi1,eta1,p1,q1),pospl(ksi2,eta2,p2,q2),r1,r2,refis(rl,mn(pl(ksi1,eta1),pl(ksi2,eta2))),iz):is(pl(mn(pl(ksi1,eta1),pl(ksi2,eta2)),zeta0),mn(pl(pl(ksi1,eta1),zeta1),pl(pl(ksi2,eta2),zeta2)))
t3:=asspl1p(ksi1,eta1,zeta1,p1,q1,r1):is(pl(pl(ksi1,eta1),zeta1),pl(ksi1,pl(eta1,zeta1)))
t4:=asspl1p(ksi2,eta2,zeta2,p2,q2,r2):is(pl(pl(ksi2,eta2),zeta2),pl(ksi2,pl(eta2,zeta2)))
t5:=ismn12(pl(pl(ksi1,eta1),zeta1),pl(ksi1,pl(eta1,zeta1)),pl(pl(ksi2,eta2),zeta2),pl(ksi2,pl(eta2,zeta2)),t3,t4):is(mn(pl(pl(ksi1,eta1),zeta1),pl(pl(ksi2,eta2),zeta2)),mn(pl(ksi1,pl(eta1,zeta1)),pl(ksi2,pl(eta2,zeta2))))
t6:=satz185a(ksi0,mn(pl(eta1,zeta1),pl(eta2,zeta2)),ksi1,ksi2,pl(eta1,zeta1),pl(eta2,zeta2),p1,p2,pospl(eta1,zeta1,q1,r1),pospl(eta2,zeta2,q2,r2),ix,refis(rl,mn(pl(eta1,zeta1),pl(eta2,zeta2)))):is(mn(pl(ksi1,pl(eta1,zeta1)),pl(ksi2,pl(eta2,zeta2))),pl(ksi0,mn(pl(eta1,zeta1),pl(eta2,zeta2))))
t7:=satz185a(eta0,zeta0,eta1,eta2,zeta1,zeta2,q1,q2,r1,r2,iy,iz):is(mn(pl(eta1,zeta1),pl(eta2,zeta2)),pl(eta0,zeta0))
t8:=tr3is(rl,pl(pl(ksi0,eta0),zeta0),pl(mn(pl(ksi1,eta1),pl(ksi2,eta2)),zeta0),mn(pl(pl(ksi1,eta1),zeta1),pl(pl(ksi2,eta2),zeta2)),mn(pl(ksi1,pl(eta1,zeta1)),pl(ksi2,pl(eta2,zeta2))),ispl1(pl(ksi0,eta0),mn(pl(ksi1,eta1),pl(ksi2,eta2)),zeta0,t1),t2,t5):is(pl(pl(ksi0,eta0),zeta0),mn(pl(ksi1,pl(eta1,zeta1)),pl(ksi2,pl(eta2,zeta2))))
t9:=tr3is(rl,pl(pl(ksi0,eta0),zeta0),mn(pl(ksi1,pl(eta1,zeta1)),pl(ksi2,pl(eta2,zeta2))),pl(ksi0,mn(pl(eta1,zeta1),pl(eta2,zeta2))),pl(ksi0,pl(eta0,zeta0)),t8,t6,ispl2(mn(pl(eta1,zeta1),pl(eta2,zeta2)),pl(eta0,zeta0),ksi0,t7)):is(pl(pl(ksi0,eta0),zeta0),pl(ksi0,pl(eta0,zeta0)))
iy@t10:=satz184app(zeta0,is(pl(pl(ksi0,eta0),zeta0),pl(ksi0,pl(eta0,zeta0))),[x:rl][y:rl][t:pos(x)][u:pos(y)][v:is(zeta0,mn(x,y))]t9(x,y,t,u,v)):is(pl(pl(ksi0,eta0),zeta0),pl(ksi0,pl(eta0,zeta0)))
ix@t11:=satz184app(eta0,is(pl(pl(ksi0,eta0),zeta0),pl(ksi0,pl(eta0,zeta0))),[x:rl][y:rl][t:pos(x)][u:pos(y)][v:is(eta0,mn(x,y))]t10(x,y,t,u,v)):is(pl(pl(ksi0,eta0),zeta0),pl(ksi0,pl(eta0,zeta0)))
-3186
satz186:=satz184app(ksi0,is(pl(pl(ksi0,eta0),zeta0),pl(ksi0,pl(eta0,zeta0))),[x:rl][y:rl][t:pos(x)][u:pos(y)][v:is(ksi0,mn(x,y))]t11".3186"(x,y,t,u,v)):is(pl(pl(ksi0,eta0),zeta0),pl(ksi0,pl(eta0,zeta0)))
asspl1:=satz186:is(pl(pl(ksi0,eta0),zeta0),pl(ksi0,pl(eta0,zeta0)))
asspl2:=symis(rl,pl(pl(ksi0,eta0),zeta0),pl(ksi0,pl(eta0,zeta0)),satz186):is(pl(ksi0,pl(eta0,zeta0)),pl(pl(ksi0,eta0),zeta0))
eta0@satz187a:=tr3is(rl,pl(eta0,mn(ksi0,eta0)),pl(mn(ksi0,eta0),eta0),pl(ksi0,pl(mn0(eta0),eta0)),ksi0,compl(eta0,mn(ksi0,eta0)),asspl1(ksi0,mn0(eta0),eta0),pl02(ksi0,pl(mn0(eta0),eta0),satz179a(eta0))):is(pl(eta0,mn(ksi0,eta0)),ksi0)
satz187b:=somei(rl,[x:rl]is(pl(eta0,x),ksi0),mn(ksi0,eta0),satz187a):some([x:rl]is(pl(eta0,x),ksi0))
[upsilon0:rl][i:is(pl(eta0,upsilon0),ksi0)]
satz187c:=tr4is(rl,mn(ksi0,eta0),pl(mn0(eta0),ksi0),pl(mn0(eta0),pl(eta0,upsilon0)),pl(pl(mn0(eta0),eta0),upsilon0),upsilon0,compl(ksi0,mn0(eta0)),ispl2(ksi0,pl(eta0,upsilon0),mn0(eta0),symis(rl,pl(eta0,upsilon0),ksi0,i)),asspl2(mn0(eta0),eta0,upsilon0),pl01(pl(mn0(eta0),eta0),upsilon0,satz179a(eta0))):is(mn(ksi0,eta0),upsilon0)
satz187d:=symis(rl,mn(ksi0,eta0),upsilon0,satz187c):is(upsilon0,mn(ksi0,eta0))
upsilon0@[i:is(pl(upsilon0,eta0),ksi0)]
+3187
t1:=tris(rl,pl(eta0,upsilon0),pl(upsilon0,eta0),ksi0,compl(eta0,upsilon0),i):is(pl(eta0,upsilon0),ksi0)
-3187
satz187e:=satz187c(t1".3187"):is(mn(ksi0,eta0),upsilon0)
satz187f:=satz187d(t1".3187"):is(upsilon0,mn(ksi0,eta0))
+*3187
eta0@[zeta0:rl][upsilon0:rl][i:is(pl(eta0,zeta0),ksi0)][j:is(pl(eta0,upsilon0),ksi0)]
t2:=tris1(rl,zeta0,upsilon0,mn(ksi0,eta0),satz187c(zeta0,i),satz187c(upsilon0,j)):is(zeta0,upsilon0)
eta0@t3:=[x:rl][y:rl][t:is(pl(eta0,x),ksi0)][u:is(pl(eta0,y),ksi0)]t2(x,y,t,u):amone(rl,[x:rl]is(pl(eta0,x),ksi0))
-3187
eta0@satz187:=onei(rl,[x:rl]is(pl(eta0,x),ksi0),t3".3187",satz187b):one([x:rl]is(pl(eta0,x),ksi0))
+3188
zeta0@t1:=tris(rl,mn0(pl(eta0,zeta0)),mn0(pl(zeta0,eta0)),pl(mn0(zeta0),mn0(eta0)),ismn0(pl(eta0,zeta0),pl(zeta0,eta0),compl(eta0,zeta0)),satz180a(zeta0,eta0)):is(mn0(pl(eta0,zeta0)),pl(mn0(zeta0),mn0(eta0)))
t2:=tris(rl,pl(pl(ksi0,zeta0),mn0(zeta0)),pl(ksi0,pl(zeta0,mn0(zeta0))),ksi0,asspl1(ksi0,zeta0,mn0(zeta0)),pl02(ksi0,pl(zeta0,mn0(zeta0)),satz179(zeta0))):is(pl(pl(ksi0,zeta0),mn0(zeta0)),ksi0)
t3:=tr3is(rl,mn(pl(ksi0,zeta0),pl(eta0,zeta0)),pl(pl(ksi0,zeta0),pl(mn0(zeta0),mn0(eta0))),pl(pl(pl(ksi0,zeta0),mn0(zeta0)),mn0(eta0)),mn(ksi0,eta0),ispl2(mn0(pl(eta0,zeta0)),pl(mn0(zeta0),mn0(eta0)),pl(ksi0,zeta0),t1),asspl2(pl(ksi0,zeta0),mn0(zeta0),mn0(eta0)),ispl1(pl(pl(ksi0,zeta0),mn0(zeta0)),ksi0,mn0(eta0),t2)):is(mn(pl(ksi0,zeta0),pl(eta0,zeta0)),mn(ksi0,eta0))
-3188
zeta0@[m:more(pl(ksi0,zeta0),pl(eta0,zeta0))]
+*3188
m@t4:=isp(rl,[x:rl]pos(x),mn(pl(ksi0,zeta0),pl(eta0,zeta0)),mn(ksi0,eta0),satz182d(pl(ksi0,zeta0),pl(eta0,zeta0),m),t3):pos(mn(ksi0,eta0))
-3188
m@satz188a:=satz182a(ksi0,eta0,t4".3188"):more(ksi0,eta0)
zeta0@[i:is(pl(ksi0,zeta0),pl(eta0,zeta0))]
+*3188
i@t5:=tris1(rl,mn(ksi0,eta0),0,mn(pl(ksi0,zeta0),pl(eta0,zeta0)),t3,satz182e(pl(ksi0,zeta0),pl(eta0,zeta0),i)):is(mn(ksi0,eta0),0)
-3188
i@satz188b:=satz182b(ksi0,eta0,t5".3188"):is(ksi0,eta0)
zeta0@[l:less(pl(ksi0,zeta0),pl(eta0,zeta0))]
+*3188
l@t6:=isp(rl,[x:rl]neg(x),mn(pl(ksi0,zeta0),pl(eta0,zeta0)),mn(ksi0,eta0),satz182f(pl(ksi0,zeta0),pl(eta0,zeta0),l),t3):neg(mn(ksi0,eta0))
-3188
l@satz188c:=satz182c(ksi0,eta0,t6".3188"):less(ksi0,eta0)
zeta0@[m:more(ksi0,eta0)]
+*3188
m@t7:=isp1(rl,[x:rl]pos(x),mn(ksi0,eta0),mn(pl(ksi0,zeta0),pl(eta0,zeta0)),satz182d(ksi0,eta0,m),t3):pos(mn(pl(ksi0,zeta0),pl(eta0,zeta0)))
-3188
m@satz188d:=satz182a(pl(ksi0,zeta0),pl(eta0,zeta0),t7".3188"):more(pl(ksi0,zeta0),pl(eta0,zeta0))
zeta0@[i:is(ksi0,eta0)]
+*3188
i@t8:=tris(rl,mn(pl(ksi0,zeta0),pl(eta0,zeta0)),mn(ksi0,eta0),0,t3,satz182e(ksi0,eta0,i)):is(mn(pl(ksi0,zeta0),pl(eta0,zeta0)),0)
-3188
i@satz188e:=satz182b(pl(ksi0,zeta0),pl(eta0,zeta0),t8".3188"):is(pl(ksi0,zeta0),pl(eta0,zeta0))
zeta0@[l:less(ksi0,eta0)]
+*3188
l@t9:=isp1(rl,[x:rl]neg(x),mn(ksi0,eta0),mn(pl(ksi0,zeta0),pl(eta0,zeta0)),satz182f(ksi0,eta0,l),t3):neg(mn(pl(ksi0,zeta0),pl(eta0,zeta0)))
-3188
l@satz188f:=satz182c(pl(ksi0,zeta0),pl(eta0,zeta0),t9".3188"):less(pl(ksi0,zeta0),pl(eta0,zeta0))
zeta0@[m:more(pl(zeta0,ksi0),pl(zeta0,eta0))]
satz188g:=satz188a(ksi0,eta0,zeta0,ismore12(pl(zeta0,ksi0),pl(ksi0,zeta0),pl(zeta0,eta0),pl(eta0,zeta0),compl(zeta0,ksi0),compl(zeta0,eta0),m)):more(ksi0,eta0)
zeta0@[i:is(pl(zeta0,ksi0),pl(zeta0,eta0))]
satz188h:=satz188b(ksi0,eta0,zeta0,tr3is(rl,pl(ksi0,zeta0),pl(zeta0,ksi0),pl(zeta0,eta0),pl(eta0,zeta0),compl(ksi0,zeta0),i,compl(zeta0,eta0))):is(ksi0,eta0)
zeta0@[l:less(pl(zeta0,ksi0),pl(zeta0,eta0))]
satz188j:=satz188c(ksi0,eta0,zeta0,isless12(pl(zeta0,ksi0),pl(ksi0,zeta0),pl(zeta0,eta0),pl(eta0,zeta0),compl(zeta0,ksi0),compl(zeta0,eta0),l)):less(ksi0,eta0)
zeta0@[m:more(ksi0,eta0)]
satz188k:=ismore12(pl(ksi0,zeta0),pl(zeta0,ksi0),pl(eta0,zeta0),pl(zeta0,eta0),compl(ksi0,zeta0),compl(eta0,zeta0),satz188d(ksi0,eta0,zeta0,m)):more(pl(zeta0,ksi0),pl(zeta0,eta0))
zeta0@[i:is(ksi0,eta0)]
satz188l:=tr3is(rl,pl(zeta0,ksi0),pl(ksi0,zeta0),pl(eta0,zeta0),pl(zeta0,eta0),compl(zeta0,ksi0),satz188e(ksi0,eta0,zeta0,i),compl(eta0,zeta0)):is(pl(zeta0,ksi0),pl(zeta0,eta0))
zeta0@[l:less(ksi0,eta0)]
satz188m:=isless12(pl(ksi0,zeta0),pl(zeta0,ksi0),pl(eta0,zeta0),pl(zeta0,eta0),compl(ksi0,zeta0),compl(eta0,zeta0),satz188f(ksi0,eta0,zeta0,l)):less(pl(zeta0,ksi0),pl(zeta0,eta0))
zeta0@[upsilon0:rl][i:is(ksi0,eta0)][m:more(zeta0,upsilon0)]
satz188n:=ismore2(pl(ksi0,upsilon0),pl(eta0,upsilon0),pl(ksi0,zeta0),ispl1(ksi0,eta0,upsilon0,i),satz188k(zeta0,upsilon0,ksi0,m)):more(pl(ksi0,zeta0),pl(eta0,upsilon0))
satz188o:=ismore12(pl(ksi0,zeta0),pl(zeta0,ksi0),pl(eta0,upsilon0),pl(upsilon0,eta0),compl(ksi0,zeta0),compl(eta0,upsilon0),satz188n):more(pl(zeta0,ksi0),pl(upsilon0,eta0))
i@[l:less(zeta0,upsilon0)]
satz188p:=isless2(pl(ksi0,upsilon0),pl(eta0,upsilon0),pl(ksi0,zeta0),ispl1(ksi0,eta0,upsilon0,i),satz188m(zeta0,upsilon0,ksi0,l)):less(pl(ksi0,zeta0),pl(eta0,upsilon0))
satz188q:=isless12(pl(ksi0,zeta0),pl(zeta0,ksi0),pl(eta0,upsilon0),pl(upsilon0,eta0),compl(ksi0,zeta0),compl(eta0,upsilon0),satz188p):less(pl(zeta0,ksi0),pl(upsilon0,eta0))
upsilon0@[m:more(ksi0,eta0)][n:more(zeta0,upsilon0)]
+3189
t1:=satz188d(ksi0,eta0,zeta0,m):more(pl(ksi0,zeta0),pl(eta0,zeta0))
t2:=ismore12(pl(zeta0,eta0),pl(eta0,zeta0),pl(upsilon0,eta0),pl(eta0,upsilon0),compl(zeta0,eta0),compl(upsilon0,eta0),satz188d(zeta0,upsilon0,eta0,n)):more(pl(eta0,zeta0),pl(eta0,upsilon0))
-3189
satz189:=trmore(pl(ksi0,zeta0),pl(eta0,zeta0),pl(eta0,upsilon0),t1".3189",t2".3189"):more(pl(ksi0,zeta0),pl(eta0,upsilon0))
upsilon0@[l:less(ksi0,eta0)][k:less(zeta0,upsilon0)]
satz189a:=satz189(eta0,ksi0,upsilon0,zeta0,l,k):less(pl(ksi0,zeta0),pl(eta0,upsilon0))
upsilon0@[m:moreis(ksi0,eta0)][n:more(zeta0,upsilon0)]
satz190a:=orapp(more(ksi0,eta0),is(ksi0,eta0),more(pl(ksi0,zeta0),pl(eta0,upsilon0)),m,[t:more(ksi0,eta0)]satz189(t,n),[t:is(ksi0,eta0)]satz188n(t,n)):more(pl(ksi0,zeta0),pl(eta0,upsilon0))
upsilon0@[m:more(ksi0,eta0)][n:moreis(zeta0,upsilon0)]
satz190b:=orapp(more(zeta0,upsilon0),is(zeta0,upsilon0),more(pl(ksi0,zeta0),pl(eta0,upsilon0)),n,[t:more(zeta0,upsilon0)]satz189(m,t),[t:is(zeta0,upsilon0)]satz188o(zeta0,upsilon0,ksi0,eta0,t,m)):more(pl(ksi0,zeta0),pl(eta0,upsilon0))
upsilon0@[l:lessis(ksi0,eta0)][k:less(zeta0,upsilon0)]
satz190c:=satz190a(eta0,ksi0,upsilon0,zeta0,satz168b(ksi0,eta0,l),k):less(pl(ksi0,zeta0),pl(eta0,upsilon0))
upsilon0@[l:less(ksi0,eta0)][k:lessis(zeta0,upsilon0)]
satz190d:=satz190b(eta0,ksi0,upsilon0,zeta0,l,satz168b(zeta0,upsilon0,k)):less(pl(ksi0,zeta0),pl(eta0,upsilon0))
upsilon0@[m:moreis(ksi0,eta0)][n:moreis(zeta0,upsilon0)]
+3191
[i:is(ksi0,eta0)][j:is(zeta0,upsilon0)]
t1:=moreisi2(pl(ksi0,zeta0),pl(eta0,upsilon0),ispl12(ksi0,eta0,zeta0,upsilon0,i,j)):moreis(pl(ksi0,zeta0),pl(eta0,upsilon0))
i@[o:more(zeta0,upsilon0)]
t2:=moreisi1(pl(ksi0,zeta0),pl(eta0,upsilon0),satz190a(m,o)):moreis(pl(ksi0,zeta0),pl(eta0,upsilon0))
i@t3:=orapp(more(zeta0,upsilon0),is(zeta0,upsilon0),moreis(pl(ksi0,zeta0),pl(eta0,upsilon0)),n,[t:more(zeta0,upsilon0)]t2(t),[t:is(zeta0,upsilon0)]t1(t)):moreis(pl(ksi0,zeta0),pl(eta0,upsilon0))
n@[o:more(ksi0,eta0)]
t4:=moreisi1(pl(ksi0,zeta0),pl(eta0,upsilon0),satz190b(o,n)):moreis(pl(ksi0,zeta0),pl(eta0,upsilon0))
-3191
satz191:=orapp(more(ksi0,eta0),is(ksi0,eta0),moreis(pl(ksi0,zeta0),pl(eta0,upsilon0)),m,[t:more(ksi0,eta0)]t4".3191"(t),[t:is(ksi0,eta0)]t3".3191"(t)):moreis(pl(ksi0,zeta0),pl(eta0,upsilon0))
upsilon0@[l:lessis(ksi0,eta0)][k:lessis(zeta0,upsilon0)]
satz191a:=satz168a(pl(eta0,upsilon0),pl(ksi0,zeta0),satz191(eta0,ksi0,upsilon0,zeta0,satz168b(ksi0,eta0,l),satz168b(zeta0,upsilon0,k))):lessis(pl(ksi0,zeta0),pl(eta0,upsilon0))
ksi0@[p:pos(ksi0)]
+iv4
ksi:=rpofp(ksi0,p):cut
-iv4
eta0@[p:pos(eta0)]
+*iv4
p@eta:=rpofp(eta0,p):cut
-iv4
eta0@[p:pos(ksi0)][q:pos(eta0)]
ts1a:=pofrp(ts(ksi".iv4"(p),eta".iv4"(q))):rl
+*iv4
q@t1:=posi(ts(ksi(p),eta(q))):pos(ts1a)
-iv4
q@[r:pos(eta0)]
+*iv4
r@t2:=isrpep(ts(ksi(p),eta(q)),ts(ksi(p),eta(r)),ists2(eta(q),eta(r),ksi(p),isperp(eta0,q,eta0,r,refis(rl,eta0)))):is(ts1a(q),ts1a(r))
eta0@py:=pos(eta0):'prop'
-iv4
p@ts1b:=ite"l.r"(py".iv4",rl,[t:py".iv4"]ts1a(t),[t:not(py".iv4")]0,[t:py".iv4"][u:py".iv4"]t2".iv4"(t,u),[t:not(py".iv4")][u:not(py".iv4")]refis(rl,0)):rl
+*iv4
q@t3:=itet"l.r"(py,rl,[t:py]ts1a(t),[t:not(py)]0,[t:py][u:py]t2(t,u),[t:not(py)][u:not(py)]refis(rl,0),q):is(ts1b,ts1a(q))
-iv4
p@[n:not(pos(eta0))]
+*iv4
n@t4:=itef"l.r"(py,rl,[t:py]ts1a(t),[t:not(py)]0,[t:py][u:py]t2(t,u),[t:not(py)][u:not(py)]refis(rl,0),n):is(ts1b,0)
-iv4
p@[n:neg(eta0)]
+*iv4
p@t5:=satz166a(ksi0,p):pos(abs(ksi0))
n@t6:=satz166b(eta0,n):pos(abs(eta0))
-iv4
n@ts1c:=mn0(ts1a(abs(ksi0),abs(eta0),t5".iv4",t6".iv4")):rl
[o:neg(eta0)]
+*iv4
o@t7:=ismn0(ts1a(abs(ksi0),abs(eta0),t5,t6),ts1a(abs(ksi0),abs(eta0),t5,t6(o)),t2(abs(ksi0),abs(eta0),t5,t6,t6(o))):is(ts1c(n),ts1c(o))
eta0@ny:=neg(eta0):'prop'
-iv4
p@ts1:=ite"l.r"(ny".iv4",rl,[t:ny".iv4"]ts1c(t),[t:not(ny".iv4")]ts1b,[t:ny".iv4"][u:ny".iv4"]t7".iv4"(t,u),[t:not(ny".iv4")][u:not(ny".iv4")]refis(rl,ts1b)):rl
+*iv4
n@t8:=itet"l.r"(ny,rl,[t:ny]ts1c(t),[t:not(ny)]ts1b,[t:ny][u:ny]t7(t,u),[t:not(ny)][u:not(ny)]refis(rl,ts1b),n):is(ts1,ts1c(n))
-iv4
p@[n:not(neg(eta0))]
+*iv4
n@t9:=itef"l.r"(ny,rl,[t:ny]ts1c(t),[t:not(ny)]ts1b,[t:ny][u:ny]t7(t,u),[t:not(ny)][u:not(ny)]refis(rl,ts1b),n):is(ts1,ts1b)
-iv4
p@[q:pos(ksi0)][r:pos(eta0)]
+*iv4
r@t10:=tris(rl,ts1,ts1b,ts1a(r),t9(pnotn(eta0,r)),t3(r)):is(ts1,ts1a(r))
t11:=isrpep(ts(ksi(p),eta(r)),ts(ksi(q),eta(r)),ists1(ksi(p),ksi(q),eta(r),isperp(ksi0,p,ksi0,q,refis(rl,ksi0)))):is(ts1a(p,r),ts1a(q,r))
t12:=tr3is(rl,ts1(p),ts1a(p,r),ts1a(q,r),ts1(q),t10,t11,symis(rl,ts1(q),ts1a(q,r),t10(q,p,r))):is(ts1(p),ts1(q))
-iv4
q@[i:is(eta0,0)]
+*iv4
i@t13:=tris(rl,ts1,ts1b,0,t9(0notn(eta0,i)),t4(0notp(eta0,i))):is(ts1,0)
t14:=tris2(rl,ts1(p),ts1(q),0,t13,t13(q,p,i)):is(ts1(p),ts1(q))
-iv4
q@[n:neg(eta0)]
+*iv4
n@t15:=ismn0(ts1a(abs(ksi0),abs(eta0),t5,t6(n)),ts1a(abs(ksi0),abs(eta0),t5(q),t6(q,n)),t11(abs(ksi0),abs(eta0),t5,t5(q),satz166b(eta0,n))):is(ts1c(p,n),ts1c(q,n))
t16:=tr3is(rl,ts1(p),ts1c(p,n),ts1c(q,n),ts1(q),t8(p,n),t15,symis(rl,ts1(q),ts1c(q,n),t8(q,n))):is(ts1(p),ts1(q))
q@t17:=rlapp(eta0,is(ts1(p),ts1(q)),[t:pos(eta0)]t12(t),[t:is(eta0,0)]t14(t),[t:neg(eta0)]t16(t)):is(ts1(p),ts1(q))
ksi0@px:=pos(ksi0):'prop'
-iv4
eta0@ts2:=ite"l.r"(px".iv4",rl,[t:px".iv4"]ts1(t),[t:not(px".iv4")]0,[t:px".iv4"][u:px".iv4"]t17".iv4"(t,u),[t:not(px".iv4")][u:not(px".iv4")]refis(rl,0)):rl
+*iv4
p@t18:=itet"l.r"(px,rl,[t:px]ts1(t),[t:not(px)]0,[t:px][u:px]t17(t,u),[t:not(px)][u:not(px)]refis(rl,0),p):is(ts2,ts1(p))
-iv4
eta0@[n:not(pos(ksi0))]
+*iv4
n@t19:=itef"l.r"(px,rl,[t:px]ts1(t),[t:not(px)]0,[t:px][u:px]t17(t,u),[t:not(px)][u:not(px)]refis(rl,0),n):is(ts2,0)
-iv4
eta0@[n:neg(ksi0)][p:pos(eta0)]
+*iv4
n@t20:=satz166b(ksi0,n):pos(abs(ksi0))
p@t21:=satz166a(eta0,p):pos(abs(eta0))
-iv4
p@ts3a:=mn0(ts1a(abs(ksi0),abs(eta0),t20".iv4",t21".iv4")):rl
[q:pos(eta0)]
+*iv4
q@t22:=ismn0(ts1a(abs(ksi0),abs(eta0),t20,t21),ts1a(abs(ksi0),abs(eta0),t20,t21(q)),t2(abs(ksi0),abs(eta0),t20,t21,t21(q))):is(ts3a(p),ts3a(q))
-iv4
n@ts3b:=ite"l.r"(py".iv4",rl,[t:py".iv4"]ts3a(t),[t:not(py".iv4")]0,[t:py".iv4"][u:py".iv4"]t22".iv4"(t,u),[t:not(py".iv4")][u:not(py".iv4")]refis(rl,0)):rl
+*iv4
p@t23:=itet"l.r"(py,rl,[t:py]ts3a(t),[t:not(py)]0,[t:py][u:py]t22(t,u),[t:not(py)][u:not(py)]refis(rl,0),p):is(ts3b,ts3a(p))
-iv4
n@[o:not(pos(eta0))]
+*iv4
o@t24:=itef"l.r"(py,rl,[t:py]ts3a(t),[t:not(py)]0,[t:py][u:py]t22(t,u),[t:not(py)][u:not(py)]refis(rl,0),o):is(ts3b,0)
-iv4
n@[o:neg(eta0)]
+*iv4
o@t25:=satz166b(eta0,o):pos(abs(eta0))
-iv4
o@ts3c:=ts1a(abs(ksi0),abs(eta0),t20".iv4",t25".iv4"):rl
[p:neg(eta0)]
+*iv4
p@t26:=t2(abs(ksi0),abs(eta0),t20,t25,t25(p)):is(ts3c(o),ts3c(p))
-iv4
n@ts3:=ite"l.r"(ny".iv4",rl,[t:ny".iv4"]ts3c(t),[t:not(ny".iv4")]ts3b,[t:ny".iv4"][u:ny".iv4"]t26".iv4"(t,u),[t:not(ny".iv4")][u:not(ny".iv4")]refis(rl,ts3b)):rl
+*iv4
o@t27:=itet"l.r"(ny,rl,[t:ny]ts3c(t),[t:not(ny)]ts3b,[t:ny][u:ny]t26(t,u),[t:not(ny)][u:not(ny)]refis(rl,ts3b),o):is(ts3,ts3c(o))
-iv4
n@[o:not(neg(eta0))]
+*iv4
o@t28:=itef"l.r"(ny,rl,[t:ny]ts3c(t),[t:not(ny)]ts3b,[t:ny][u:ny]t26(t,u),[t:not(ny)][u:not(ny)]refis(rl,ts3b),o):is(ts3,ts3b)
-iv4
n@[o:neg(ksi0)][p:pos(eta0)]
+*iv4
p@t29:=tris(rl,ts3,ts3b,ts3a(p),t28(pnotn(eta0,p)),t23(p)):is(ts3,ts3a(p))
t30:=ismn0(ts1a(abs(ksi0),abs(eta0),t20,t21(p)),ts1a(abs(ksi0),abs(eta0),t20(o),t21(o,p)),t11(abs(ksi0),abs(eta0),t20,t20(o),satz166a(eta0,p))):is(ts3a(n,p),ts3a(o,p))
t31:=tr3is(rl,ts3(n),ts3a(n,p),ts3a(o,p),ts3(o),t29,t30,symis(rl,ts3(o),ts3a(o,p),t29(o,n,p))):is(ts3(n),ts3(o))
-iv4
o@[i:is(eta0,0)]
+*iv4
i@t32:=tris(rl,ts3,ts3b,0,t28(0notn(eta0,i)),t24(0notp(eta0,i))):is(ts3,0)
t33:=tris2(rl,ts3(n),ts3(o),0,t32,t32(o,n,i)):is(ts3(n),ts3(o))
-iv4
o@[p:neg(eta0)]
+*iv4
p@t34:=tr3is(rl,ts3(n),ts3c(n,p),ts3c(o,p),ts3(o),t27(n,p),t11(abs(ksi0),abs(eta0),t20(n),t20(o),satz166b(eta0,p)),symis(rl,ts3(o),ts3c(o,p),t27(o,p))):is(ts3(n),ts3(o))
o@t35:=rlapp(eta0,is(ts3(n),ts3(o)),[t:pos(eta0)]t31(t),[t:is(eta0,0)]t33(t),[t:neg(eta0)]t34(t)):is(ts3(n),ts3(o))
ksi0@nx:=neg(ksi0):'prop'
-iv4
eta0@ts:=ite"l.r"(nx".iv4",rl,[t:nx".iv4"]ts3(t),[t:not(nx".iv4")]ts2,[t:nx".iv4"][u:nx".iv4"]t35".iv4"(t,u),[t:not(nx".iv4")][u:not(nx".iv4")]refis(rl,ts2)):rl
+*iv4
n@t36:=itet"l.r"(nx,rl,[t:nx]ts3(t),[t:not(nx)]ts2,[t:nx][u:nx]t35(t,u),[t:not(nx)][u:not(nx)]refis(rl,ts2),n):is(ts,ts3(n))
-iv4
eta0@[n:not(neg(ksi0))]
+*iv4
n@t37:=itef"l.r"(nx,rl,[t:nx]ts3(t),[t:not(nx)]ts2,[t:nx][u:nx]t35(t,u),[t:not(nx)][u:not(nx)]refis(rl,ts2),n):is(ts,ts2)
-iv4
eta0@[p:pos(ksi0)][q:pos(eta0)]
tspp:=tr3is(rl,ts,ts2,ts1(p),ts1a(p,q),t37".iv4"(pnotn(ksi0,p)),t18".iv4"(p),t10".iv4"(p,p,q)):is(ts(ksi0,eta0),pofrp(ts"rp"(rpofp(ksi0,p),rpofp(eta0,q))))
tspp1:=tspp:is(ts(ksi0,eta0),ts1a(ksi0,eta0,p,q))
posts:=isp1(rl,[x:rl]pos(x),ts1a(p,q),ts,t1".iv4"(p,q),tspp1):pos(ts(ksi0,eta0))
p@[n:neg(eta0)]
tspn:=tr3is(rl,ts,ts2,ts1(p),ts1c(p,n),t37".iv4"(pnotn(ksi0,p)),t18".iv4"(p),t8".iv4"(p,n)):is(ts(ksi0,eta0),mn0(ts1a(abs(ksi0),abs(eta0),satz166a(ksi0,p),satz166b(eta0,n))))
tspn1:=tris2(rl,ts(ksi0,eta0),mn0(ts(abs(ksi0),abs(eta0))),mn0(ts1a(abs(ksi0),abs(eta0),satz166a(ksi0,p),satz166b(eta0,n))),tspn,ismn0(ts(abs(ksi0),abs(eta0)),ts1a(abs(ksi0),abs(eta0),satz166a(ksi0,p),satz166b(eta0,n)),tspp1(abs(ksi0),abs(eta0),satz166a(ksi0,p),satz166b(eta0,n)))):is(ts(ksi0,eta0),mn0(ts(abs(ksi0),abs(eta0))))
eta0@[n:neg(ksi0)][p:pos(eta0)]
tsnp:=tris(rl,ts,ts3(n),ts3a(n,p),t36".iv4"(n),t29".iv4"(n,n,p)):is(ts(ksi0,eta0),mn0(ts1a(abs(ksi0),abs(eta0),satz166b(ksi0,n),satz166a(eta0,p))))
tsnp1:=tris2(rl,ts(ksi0,eta0),mn0(ts(abs(ksi0),abs(eta0))),mn0(ts1a(abs(ksi0),abs(eta0),satz166b(ksi0,n),satz166a(eta0,p))),tsnp,ismn0(ts(abs(ksi0),abs(eta0)),ts1a(abs(ksi0),abs(eta0),satz166b(ksi0,n),satz166a(eta0,p)),tspp1(abs(ksi0),abs(eta0),satz166b(ksi0,n),satz166a(eta0,p)))):is(ts(ksi0,eta0),mn0(ts(abs(ksi0),abs(eta0))))
n@[o:neg(eta0)]
tsnn:=tris(rl,ts,ts3(n),ts3c(n,o),t36".iv4"(n),t27".iv4"(n,o)):is(ts(ksi0,eta0),ts1a(abs(ksi0),abs(eta0),satz166b(ksi0,n),satz166b(eta0,o)))
tsnn1:=tris2(rl,ts(ksi0,eta0),ts(abs(ksi0),abs(eta0)),ts1a(abs(ksi0),abs(eta0),satz166b(ksi0,n),satz166b(eta0,o)),tsnn,tspp1(abs(ksi0),abs(eta0),satz166b(ksi0,n),satz166b(eta0,o))):is(ts(ksi0,eta0),ts(abs(ksi0),abs(eta0)))
eta0@[i:is(ksi0,0)]
ts01:=tris(rl,ts,ts2,0,t37".iv4"(0notn(ksi0,i)),t19".iv4"(0notp(ksi0,i))):is(ts(ksi0,eta0),0)
eta0@[i:is(eta0,0)][p:pos(ksi0)]
+*iv4
p@t38:=tr3is(rl,ts,ts2,ts1(p),0,t37(pnotn(ksi0,p)),t18(p),t13(p,p,i)):is(ts,0)
-iv4
i@[n:neg(ksi0)]
+*iv4
n@t39:=tris(rl,ts,ts3(n),0,t36(n),t32(n,n,i)):is(ts,0)
-iv4
i@ts02:=rlapp(ksi0,is(ts,0),[t:pos(ksi0)]t38".iv4"(t),[t:is(ksi0,0)]ts01(t),[t:neg(ksi0)]t39".iv4"(t)):is(ts(ksi0,eta0),0)
eta0@[p:pos(ksi0)][n:neg(eta0)]
negts1:=isp1(rl,[x:rl]neg(x),mn0(ts(abs(ksi0),abs(eta0))),ts(ksi0,eta0),satz176a(ts(abs(ksi0),abs(eta0)),posts(abs(ksi0),abs(eta0),satz166a(ksi0,p),satz166b(eta0,n))),tspn1(ksi0,eta0,p,n)):neg(ts(ksi0,eta0))
eta0@[n:neg(ksi0)][p:pos(eta0)]
negts2:=isp1(rl,[x:rl]neg(x),mn0(ts(abs(ksi0),abs(eta0))),ts(ksi0,eta0),satz176a(ts(abs(ksi0),abs(eta0)),posts(abs(ksi0),abs(eta0),satz166b(ksi0,n),satz166a(eta0,p))),tsnp1(ksi0,eta0,n,p)):neg(ts(ksi0,eta0))
n@[o:neg(eta0)]
posts1:=isp1(rl,[x:rl]pos(x),ts(abs(ksi0),abs(eta0)),ts(ksi0,eta0),posts(abs(ksi0),abs(eta0),satz166b(ksi0,n),satz166b(eta0,o)),tsnn1(ksi0,eta0,n,o)):pos(ts(ksi0,eta0))
zeta0@[i:is(ksi0,eta0)]
ists1:=isf(rl,rl,[x:rl]ts(x,zeta0),ksi0,eta0,i):is(ts(ksi0,zeta0),ts(eta0,zeta0))
ists2:=isf(rl,rl,[x:rl]ts(zeta0,x),ksi0,eta0,i):is(ts(zeta0,ksi0),ts(zeta0,eta0))
upsilon0@[i:is(ksi0,eta0)][j:is(zeta0,upsilon0)]
ists12:=tris(rl,ts(ksi0,zeta0),ts(eta0,zeta0),ts(eta0,upsilon0),ists1(ksi0,eta0,zeta0,i),ists2(zeta0,upsilon0,eta0,j)):is(ts(ksi0,zeta0),ts(eta0,upsilon0))
eta0@[i:is(ksi0,0)]
satz192a:=ts01(ksi0,eta0,i):is(ts(ksi0,eta0),0)
eta0@[i:is(eta0,0)]
satz192b:=ts02(ksi0,eta0,i):is(ts(ksi0,eta0),0)
eta0@[i:is(ts(ksi0,eta0),0)]
+4192
t1:=0notp(ts(ksi0,eta0),i):not(pos(ts(ksi0,eta0)))
t2:=0notn(ts(ksi0,eta0),i):not(neg(ts(ksi0,eta0)))
[p:pos(ksi0)]
t3:=th3"l.imp"(pos(eta0),pos(ts(ksi0,eta0)),t1,[t:pos(eta0)]posts(ksi0,eta0,p,t)):not(pos(eta0))
t4:=th3"l.imp"(neg(eta0),neg(ts(ksi0,eta0)),t2,[t:neg(eta0)]negts1(ksi0,eta0,p,t)):not(neg(eta0))
t5:=ori2(is(ksi0,0),is(eta0,0),or3e1(is(eta0,0),pos(eta0),neg(eta0),axrlo(eta0),t3,t4)):or(is(ksi0,0),is(eta0,0))
i@[j:is(ksi0,0)]
t6:=ori1(is(ksi0,0),is(eta0,0),j):or(is(ksi0,0),is(eta0,0))
i@[n:neg(ksi0)]
t7:=th3"l.imp"(pos(eta0),neg(ts(ksi0,eta0)),t2,[t:pos(eta0)]negts2(ksi0,eta0,n,t)):not(pos(eta0))
t8:=th3"l.imp"(neg(eta0),pos(ts(ksi0,eta0)),t1,[t:neg(eta0)]posts1(ksi0,eta0,n,t)):not(neg(eta0))
t9:=ori2(is(ksi0,0),is(eta0,0),or3e1(is(eta0,0),pos(eta0),neg(eta0),axrlo(eta0),t7,t8)):or(is(ksi0,0),is(eta0,0))
-4192
satz192c:=rlapp(ksi0,or(is(ksi0,0),is(eta0,0)),[t:pos(ksi0)]t5".4192"(t),[t:is(ksi0,0)]t6".4192"(t),[t:neg(ksi0)]t9".4192"(t)):or(is(ksi0,0),is(eta0,0))
eta0@[n:nis(ksi0,0)][o:nis(eta0,0)]
satz192d:=th3"l.imp"(is(ts(ksi0,eta0),0),or(is(ksi0,0),is(eta0,0)),th3"l.or"(is(ksi0,0),is(eta0,0),n,o),[t:is(ts(ksi0,eta0),0)]satz192c(t)):nis(ts(ksi0,eta0),0)
+4193
eta0@[p:pos(ksi0)][q:pos(eta0)]
t1:=absp(ts(ksi0,eta0),posts(ksi0,eta0,p,q)):is(abs(ts(ksi0,eta0)),ts(ksi0,eta0))
t2:=ists12(abs(ksi0),ksi0,abs(eta0),eta0,absp(ksi0,p),absp(eta0,q)):is(ts(abs(ksi0),abs(eta0)),ts(ksi0,eta0))
t3:=tris2(rl,abs(ts(ksi0,eta0)),ts(abs(ksi0),abs(eta0)),ts(ksi0,eta0),t1,t2):is(abs(ts(ksi0,eta0)),ts(abs(ksi0),abs(eta0)))
eta0@[i:is(eta0,0)]
t4:=abs0(ts(ksi0,eta0),ts02(ksi0,eta0,i)):is(abs(ts(ksi0,eta0)),0)
t5:=ts02(abs(ksi0),abs(eta0),abs0(eta0,i)):is(ts(abs(ksi0),abs(eta0)),0)
t6:=tris2(rl,abs(ts(ksi0,eta0)),ts(abs(ksi0),abs(eta0)),0,t4,t5):is(abs(ts(ksi0,eta0)),ts(abs(ksi0),abs(eta0)))
p@[n:neg(eta0)]
t7:=tris(rl,abs(ts(ksi0,eta0)),abs(mn0(ts(abs(ksi0),abs(eta0)))),ts(abs(ksi0),abs(eta0)),isabs(ts(ksi0,eta0),mn0(ts(abs(ksi0),abs(eta0))),tspn1(ksi0,eta0,p,n)),lemma177(ts(abs(ksi0),abs(eta0)),posts(abs(ksi0),abs(eta0),satz166a(ksi0,p),satz166b(eta0,n)))):is(abs(ts(ksi0,eta0)),ts(abs(ksi0),abs(eta0)))
p@t8:=rlapp(eta0,is(abs(ts(ksi0,eta0)),ts(abs(ksi0),abs(eta0))),[t:pos(eta0)]t3(t),[t:is(eta0,0)]t6(t),[t:neg(eta0)]t7(t)):is(abs(ts(ksi0,eta0)),ts(abs(ksi0),abs(eta0)))
eta0@[i:is(ksi0,0)]
t9:=abs0(ts(ksi0,eta0),ts01(ksi0,eta0,i)):is(abs(ts(ksi0,eta0)),0)
t10:=ts01(abs(ksi0),abs(eta0),abs0(ksi0,i)):is(ts(abs(ksi0),abs(eta0)),0)
t11:=tris2(rl,abs(ts(ksi0,eta0)),ts(abs(ksi0),abs(eta0)),0,t9,t10):is(abs(ts(ksi0,eta0)),ts(abs(ksi0),abs(eta0)))
eta0@[n:neg(ksi0)][p:pos(eta0)]
t12:=tris(rl,abs(ts(ksi0,eta0)),abs(mn0(ts(abs(ksi0),abs(eta0)))),ts(abs(ksi0),abs(eta0)),isabs(ts(ksi0,eta0),mn0(ts(abs(ksi0),abs(eta0))),tsnp1(ksi0,eta0,n,p)),lemma177(ts(abs(ksi0),abs(eta0)),posts(abs(ksi0),abs(eta0),satz166b(ksi0,n),satz166a(eta0,p)))):is(abs(ts(ksi0,eta0)),ts(abs(ksi0),abs(eta0)))
n@[o:neg(eta0)]
t13:=tris(rl,abs(ts(ksi0,eta0)),ts(ksi0,eta0),ts(abs(ksi0),abs(eta0)),absp(ts(ksi0,eta0),posts1(ksi0,eta0,n,o)),tsnn1(ksi0,eta0,n,o)):is(abs(ts(ksi0,eta0)),ts(abs(ksi0),abs(eta0)))
n@t14:=rlapp(eta0,is(abs(ts(ksi0,eta0)),ts(abs(ksi0),abs(eta0))),[t:pos(eta0)]t12(t),[t:is(eta0,0)]t6(t),[t:neg(eta0)]t13(t)):is(abs(ts(ksi0,eta0)),ts(abs(ksi0),abs(eta0)))
-4193
eta0@satz193:=rlapp(ksi0,is(abs(ts(ksi0,eta0)),ts(abs(ksi0),abs(eta0))),[t:pos(ksi0)]t8".4193"(t),[t:is(ksi0,0)]t11".4193"(t),[t:neg(ksi0)]t14".4193"(t)):is(abs(ts(ksi0,eta0)),ts(abs(ksi0),abs(eta0)))
satz193a:=symis(rl,abs(ts(ksi0,eta0)),ts(abs(ksi0),abs(eta0)),satz193):is(ts(abs(ksi0),abs(eta0)),abs(ts(ksi0,eta0)))
+4194
[p:pos(ksi0)][q:pos(eta0)]
t1:=isrpep(ts"rp"(rpofp(ksi0,p),rpofp(eta0,q)),ts"rp"(rpofp(eta0,q),rpofp(ksi0,p)),satz142(rpofp(ksi0,p),rpofp(eta0,q))):is(ts1a(ksi0,eta0,p,q),ts1a(eta0,ksi0,q,p))
t2:=tr3is(rl,ts(ksi0,eta0),ts1a(ksi0,eta0,p,q),ts1a(eta0,ksi0,q,p),ts(eta0,ksi0),tspp(ksi0,eta0,p,q),t1,symis(rl,ts(eta0,ksi0),ts1a(eta0,ksi0,q,p),tspp(eta0,ksi0,q,p))):is(ts(ksi0,eta0),ts(eta0,ksi0))
eta0@[i:is(eta0,0)]
t3:=tris2(rl,ts(ksi0,eta0),ts(eta0,ksi0),0,ts02(ksi0,eta0,i),ts01(eta0,ksi0,i)):is(ts(ksi0,eta0),ts(eta0,ksi0))
p@[n:neg(eta0)]
t4:=tr3is(rl,ts(ksi0,eta0),mn0(ts(abs(ksi0),abs(eta0))),mn0(ts(abs(eta0),abs(ksi0))),ts(eta0,ksi0),tspn1(ksi0,eta0,p,n),ismn0(ts(abs(ksi0),abs(eta0)),ts(abs(eta0),abs(ksi0)),t2(abs(ksi0),abs(eta0),satz166a(ksi0,p),satz166b(eta0,n))),symis(rl,ts(eta0,ksi0),mn0(ts(abs(eta0),abs(ksi0))),tsnp1(eta0,ksi0,n,p))):is(ts(ksi0,eta0),ts(eta0,ksi0))
p@t5:=rlapp(eta0,is(ts(ksi0,eta0),ts(eta0,ksi0)),[t:pos(eta0)]t2(t),[t:is(eta0,0)]t3(t),[t:neg(eta0)]t4(t)):is(ts(ksi0,eta0),ts(eta0,ksi0))
eta0@[i:is(ksi0,0)]
t6:=tris2(rl,ts(ksi0,eta0),ts(eta0,ksi0),0,ts01(ksi0,eta0,i),ts02(eta0,ksi0,i)):is(ts(ksi0,eta0),ts(eta0,ksi0))
eta0@[n:neg(ksi0)][p:pos(eta0)]
t7:=symis(rl,ts(eta0,ksi0),ts(ksi0,eta0),t5(eta0,ksi0,p)):is(ts(ksi0,eta0),ts(eta0,ksi0))
n@[o:neg(eta0)]
t8:=tr3is(rl,ts(ksi0,eta0),ts(abs(ksi0),abs(eta0)),ts(abs(eta0),abs(ksi0)),ts(eta0,ksi0),tsnn1(ksi0,eta0,n,o),t2(abs(ksi0),abs(eta0),satz166b(ksi0,n),satz166b(eta0,o)),symis(rl,ts(eta0,ksi0),ts(abs(eta0),abs(ksi0)),tsnn1(eta0,ksi0,o,n))):is(ts(ksi0,eta0),ts(eta0,ksi0))
n@t9:=rlapp(eta0,is(ts(ksi0,eta0),ts(eta0,ksi0)),[t:pos(eta0)]t7(t),[t:is(eta0,0)]t3(t),[t:neg(eta0)]t8(t)):is(ts(ksi0,eta0),ts(eta0,ksi0))
-4194
satz194:=rlapp(ksi0,is(ts(ksi0,eta0),ts(eta0,ksi0)),[t:pos(ksi0)]t5".4194"(t),[t:is(ksi0,0)]t6".4194"(t),[t:neg(ksi0)]t9".4194"(t)):is(ts(ksi0,eta0),ts(eta0,ksi0))
comts:=satz194:is(ts(ksi0,eta0),ts(eta0,ksi0))
+4195
ksi0@[p:pos(ksi0)]
ksi:=rpofp(ksi0,p):cut
t1:=tris(cut,ts"rp"(ksi,rpofp(1rl,pos1)),ts"rp"(ksi,1rp),ksi,ists2"rp"(rpofp(1rl,pos1),1rp,ksi,isrpp2(1rp)),satz151(ksi)):is"rp"(ts"rp"(ksi,rpofp(1rl,pos1)),ksi)
t2:=tr3is(rl,ts(ksi0,1rl),pofrp(ts"rp"(ksi,rpofp(1rl,pos1))),pofrp(ksi),ksi0,tspp(ksi0,1rl,p,pos1),isrpep(ts"rp"(ksi,rpofp(1rl,pos1)),ksi,t1),isprp2(ksi0,p)):is(ts(ksi0,1rl),ksi0)
ksi0@[i:is(ksi0,0)]
t3:=tris2(rl,ts(ksi0,1rl),ksi0,0,ts01(ksi0,1rl,i),i):is(ts(ksi0,1rl),ksi0)
ksi0@[n:neg(ksi0)]
t4:=tr3is(rl,ts(abs(ksi0),abs(1rl)),ts(abs(ksi0),1rl),abs(ksi0),mn0(ksi0),ists2(abs(1rl),1rl,abs(ksi0),absp(1rl,pos1)),t2(abs(ksi0),satz166b(ksi0,n)),absn1(ksi0,n)):is(ts(abs(ksi0),abs(1rl)),mn0(ksi0))
t5:=tr3is(rl,ts(ksi0,1rl),mn0(ts(abs(ksi0),abs(1rl))),mn0(mn0(ksi0)),ksi0,tsnp1(ksi0,1rl,n,pos1),ismn0(ts(abs(ksi0),abs(1rl)),mn0(ksi0),t4),satz177(ksi0)):is(ts(ksi0,1rl),ksi0)
-4195
ksi0@satz195:=rlapp(ksi0,is(ts(ksi0,1rl),ksi0),[t:pos(ksi0)]t2".4195"(t),[t:is(ksi0,0)]t3".4195"(t),[t:neg(ksi0)]t5".4195"(t)):is(ts(ksi0,1rl),ksi0)
satz195a:=symis(rl,ts(ksi0,1rl),ksi0,satz195):is(ksi0,ts(ksi0,1rl))
satz195b:=tris(rl,ts(1rl,ksi0),ts(ksi0,1rl),ksi0,comts(1rl,ksi0),satz195):is(ts(1rl,ksi0),ksi0)
satz195c:=symis(rl,ts(1rl,ksi0),ksi0,satz195b):is(ksi0,ts(1rl,ksi0))
[i:is(ksi0,mn0(ksi0))]
+4196
[p:pos(ksi0)]
t1:=isp1(rl,[x:rl]neg(x),mn0(ksi0),ksi0,satz176a(ksi0,p),i):neg(ksi0)
i@t2:=[t:pos(ksi0)]<t1(t)>pnotn(ksi0,t):not(pos(ksi0))
[n:neg(ksi0)]
t3:=isp1(rl,[x:rl]pos(x),mn0(ksi0),ksi0,satz176c(ksi0,n),i):pos(ksi0)
i@t4:=[t:neg(ksi0)]<t3(t)>nnotp(ksi0,t):not(neg(ksi0))
-4196
lemma196:=or3e1(is(ksi0,0),pos(ksi0),neg(ksi0),axrlo(ksi0),t2".4196",t4".4196"):is(ksi0,0)
eta0@[p:pos(ksi0)][q:pos(eta0)]
+*4196
q@ksi:=rpofp(ksi0,p):cut
eta:=rpofp(eta0,q):cut
ksia:=rpofp(abs(ksi0),satz166a(ksi0,p)):cut
etaa:=rpofp(abs(eta0),satz166a(eta0,q)):cut
t5:=ists12"rp"(ksi,ksia,eta,etaa,isperp(ksi0,p,abs(ksi0),satz166a(ksi0,p),symis(rl,abs(ksi0),ksi0,absp(ksi0,p))),isperp(eta0,q,abs(eta0),satz166a(eta0,q),symis(rl,abs(eta0),eta0,absp(eta0,q)))):is"rp"(ts"rp"(ksi,eta),ts"rp"(ksia,etaa))
-4196
q@satz196a:=tr3is(rl,ts(ksi0,eta0),pofrp(ts"rp"(ksi".4196",eta".4196")),pofrp(ts"rp"(ksia".4196",etaa".4196")),ts(abs(ksi0),abs(eta0)),tspp(ksi0,eta0,p,q),isrpep(ts"rp"(ksi".4196",eta".4196"),ts"rp"(ksia".4196",etaa".4196"),t5".4196"),symis(rl,ts(abs(ksi0),abs(eta0)),pofrp(ts"rp"(ksia".4196",etaa".4196")),tspp(abs(ksi0),abs(eta0),satz166a(ksi0,p),satz166a(eta0,q)))):is(ts(ksi0,eta0),ts(abs(ksi0),abs(eta0)))
eta0@[n:neg(ksi0)][o:neg(eta0)]
satz196b:=tsnn1(ksi0,eta0,n,o):is(ts(ksi0,eta0),ts(abs(ksi0),abs(eta0)))
eta0@[p:pos(ksi0)][n:neg(eta0)]
satz196c:=tspn1(ksi0,eta0,p,n):is(ts(ksi0,eta0),mn0(ts(abs(ksi0),abs(eta0))))
eta0@[n:neg(ksi0)][p:pos(eta0)]
satz196d:=tsnp1(ksi0,eta0,n,p):is(ts(ksi0,eta0),mn0(ts(abs(ksi0),abs(eta0))))
eta0@[n:nis(ksi0,0)][o:nis(eta0,0)][i:is(ts(ksi0,eta0),ts(abs(ksi0),abs(eta0)))]
+*4196
eta0@pospos:=and(pos(ksi0),pos(eta0)):'prop'
negneg:=and(neg(ksi0),neg(eta0)):'prop'
posneg:=and(pos(ksi0),neg(eta0)):'prop'
negpos:=and(neg(ksi0),pos(eta0)):'prop'
i@[p:pos(ksi0)][q:neg(eta0)]
t6:=tris1(rl,ts(abs(ksi0),abs(eta0)),mn0(ts(abs(ksi0),abs(eta0))),ts(ksi0,eta0),i,tspn1(ksi0,eta0,p,q)):is(ts(abs(ksi0),abs(eta0)),mn0(ts(abs(ksi0),abs(eta0))))
t7:=lemma196(ts(abs(ksi0),abs(eta0)),t6):is(ts(abs(ksi0),abs(eta0)),0)
t8:=tris(rl,ts(ksi0,eta0),ts(abs(ksi0),abs(eta0)),0,i,t7):is(ts(ksi0,eta0),0)
p@t9:=[t:neg(eta0)]<t8(t)>satz192d(n,o):not(neg(eta0))
t10:=or3e2(is(eta0,0),pos(eta0),neg(eta0),axrlo(eta0),t9,o):pos(eta0)
t11:=andi(pos(ksi0),pos(eta0),p,t10):pospos
t12:=ori1(pospos,negneg,t11):or(pospos,negneg)
i@[p:neg(ksi0)][q:pos(eta0)]
t13:=tris1(rl,ts(abs(ksi0),abs(eta0)),mn0(ts(abs(ksi0),abs(eta0))),ts(ksi0,eta0),i,tsnp1(ksi0,eta0,p,q)):is(ts(abs(ksi0),abs(eta0)),mn0(ts(abs(ksi0),abs(eta0))))
t14:=lemma196(ts(abs(ksi0),abs(eta0)),t13):is(ts(abs(ksi0),abs(eta0)),0)
t15:=tris(rl,ts(ksi0,eta0),ts(abs(ksi0),abs(eta0)),0,i,t14):is(ts(ksi0,eta0),0)
p@t16:=[t:pos(eta0)]<t15(t)>satz192d(n,o):not(pos(eta0))
t17:=or3e3(is(eta0,0),pos(eta0),neg(eta0),axrlo(eta0),o,t16):neg(eta0)
t18:=andi(neg(ksi0),neg(eta0),p,t17):negneg
t19:=ori2(pospos,negneg,t18):or(pospos,negneg)
-4196
i@satz196e:=rlapp(ksi0,or(pospos".4196",negneg".4196"),[t:pos(ksi0)]t12".4196"(t),th2"l.imp"(is(ksi0,0),or(pospos".4196",negneg".4196"),n),[t:neg(ksi0)]t19".4196"(t)):or(and(pos(ksi0),pos(eta0)),and(neg(ksi0),neg(eta0)))
o@[i:is(ts(ksi0,eta0),mn0(ts(abs(ksi0),abs(eta0))))]
+*4196
i@[p:pos(ksi0)][q:pos(eta0)]
t20:=tris1(rl,ts(abs(ksi0),abs(eta0)),mn0(ts(abs(ksi0),abs(eta0))),ts(ksi0,eta0),satz196a(ksi0,eta0,p,q),i):is(ts(abs(ksi0),abs(eta0)),mn0(ts(abs(ksi0),abs(eta0))))
t21:=lemma196(ts(abs(ksi0),abs(eta0)),t20):is(ts(abs(ksi0),abs(eta0)),0)
t22:=tris(rl,ts(ksi0,eta0),ts(abs(ksi0),abs(eta0)),0,satz196a(ksi0,eta0,p,q),t21):is(ts(ksi0,eta0),0)
p@t23:=[t:pos(eta0)]<t22(t)>satz192d(n,o):not(pos(eta0))
t24:=or3e3(is(eta0,0),pos(eta0),neg(eta0),axrlo(eta0),o,t23):neg(eta0)
t25:=andi(pos(ksi0),neg(eta0),p,t24):posneg
t26:=ori1(posneg,negpos,t25):or(posneg,negpos)
i@[p:neg(ksi0)][q:neg(eta0)]
t27:=tris1(rl,ts(abs(ksi0),abs(eta0)),mn0(ts(abs(ksi0),abs(eta0))),ts(ksi0,eta0),tsnn1(ksi0,eta0,p,q),i):is(ts(abs(ksi0),abs(eta0)),mn0(ts(abs(ksi0),abs(eta0))))
t28:=lemma196(ts(abs(ksi0),abs(eta0)),t27):is(ts(abs(ksi0),abs(eta0)),0)
t29:=tris(rl,ts(ksi0,eta0),ts(abs(ksi0),abs(eta0)),0,tsnn1(ksi0,eta0,p,q),t28):is(ts(ksi0,eta0),0)
p@t30:=[t:neg(eta0)]<t29(t)>satz192d(n,o):not(neg(eta0))
t31:=or3e2(is(eta0,0),pos(eta0),neg(eta0),axrlo(eta0),t30,o):pos(eta0)
t32:=andi(neg(ksi0),pos(eta0),p,t31):negpos
t33:=ori2(posneg,negpos,t32):or(posneg,negpos)
-4196
i@satz196f:=rlapp(ksi0,or(posneg".4196",negpos".4196"),[t:pos(ksi0)]t26".4196"(t),th2"l.imp"(is(ksi0,0),or(posneg".4196",negpos".4196"),n),[t:neg(ksi0)]t33".4196"(t)):or(and(pos(ksi0),neg(eta0)),and(neg(ksi0),pos(eta0)))
eta0@[r:pos(ts(ksi0,eta0))]
+*4196
r@t34:=th3"l.imp"(is(ksi0,0),is(ts(ksi0,eta0),0),pnot0(ts(ksi0,eta0),r),[t:is(ksi0,0)]ts01(ksi0,eta0,t)):nis(ksi0,0)
t35:=th3"l.imp"(is(eta0,0),is(ts(ksi0,eta0),0),pnot0(ts(ksi0,eta0),r),[t:is(eta0,0)]ts02(ksi0,eta0,t)):nis(eta0,0)
t36:=tris1(rl,ts(ksi0,eta0),ts(abs(ksi0),abs(eta0)),abs(ts(ksi0,eta0)),absp(ts(ksi0,eta0),r),satz193(ksi0,eta0)):is(ts(ksi0,eta0),ts(abs(ksi0),abs(eta0)))
-4196
r@satz196g:=satz196e(t34".4196",t35".4196",t36".4196"):or(and(pos(ksi0),pos(eta0)),and(neg(ksi0),neg(eta0)))
eta0@[m:neg(ts(ksi0,eta0))]
+*4196
m@t37:=th3"l.imp"(is(ksi0,0),is(ts(ksi0,eta0),0),nnot0(ts(ksi0,eta0),m),[t:is(ksi0,0)]ts01(ksi0,eta0,t)):nis(ksi0,0)
t38:=th3"l.imp"(is(eta0,0),is(ts(ksi0,eta0),0),nnot0(ts(ksi0,eta0),m),[t:is(eta0,0)]ts02(ksi0,eta0,t)):nis(eta0,0)
t39:=tris(rl,ts(ksi0,eta0),mn0(mn0(ts(ksi0,eta0))),mn0(ts(abs(ksi0),abs(eta0))),satz177a(ts(ksi0,eta0)),ismn0(mn0(ts(ksi0,eta0)),ts(abs(ksi0),abs(eta0)),tris(rl,mn0(ts(ksi0,eta0)),abs(ts(ksi0,eta0)),ts(abs(ksi0),abs(eta0)),mn0n(ts(ksi0,eta0),m),satz193(ksi0,eta0)))):is(ts(ksi0,eta0),mn0(ts(abs(ksi0),abs(eta0))))
-4196
m@satz196h:=satz196f(t37".4196",t38".4196",t39".4196"):or(and(pos(ksi0),neg(eta0)),and(neg(ksi0),pos(eta0)))
+4197
eta0@[i:is(ksi0,0)]
t1:=mn00(ts(ksi0,eta0),ts01(ksi0,eta0,i)):is(mn0(ts(ksi0,eta0)),0)
t2:=tris2(rl,ts(mn0(ksi0),eta0),mn0(ts(ksi0,eta0)),0,ts01(mn0(ksi0),eta0,mn00(ksi0,i)),t1):is(ts(mn0(ksi0),eta0),mn0(ts(ksi0,eta0)))
t3:=tris2(rl,ts(ksi0,mn0(eta0)),mn0(ts(ksi0,eta0)),0,ts01(ksi0,mn0(eta0),i),t1):is(ts(ksi0,mn0(eta0)),mn0(ts(ksi0,eta0)))
eta0@[i:is(eta0,0)]
t4:=mn00(ts(ksi0,eta0),ts02(ksi0,eta0,i)):is(mn0(ts(ksi0,eta0)),0)
t5:=tris2(rl,ts(mn0(ksi0),eta0),mn0(ts(ksi0,eta0)),0,ts02(mn0(ksi0),eta0,i),t4):is(ts(mn0(ksi0),eta0),mn0(ts(ksi0,eta0)))
t6:=tris2(rl,ts(ksi0,mn0(eta0)),mn0(ts(ksi0,eta0)),0,ts02(ksi0,mn0(eta0),mn00(eta0,i)),t4):is(ts(ksi0,mn0(eta0)),mn0(ts(ksi0,eta0)))
eta0@t7:=tris(rl,abs(ts(mn0(ksi0),eta0)),ts(abs(mn0(ksi0)),abs(eta0)),ts(abs(ksi0),abs(eta0)),satz193(mn0(ksi0),eta0),ists1(abs(mn0(ksi0)),abs(ksi0),abs(eta0),satz178(ksi0))):is(abs(ts(mn0(ksi0),eta0)),ts(abs(ksi0),abs(eta0)))
t8:=tris(rl,abs(ts(ksi0,mn0(eta0))),ts(abs(ksi0),abs(mn0(eta0))),ts(abs(ksi0),abs(eta0)),satz193(ksi0,mn0(eta0)),ists2(abs(mn0(eta0)),abs(eta0),abs(ksi0),satz178(eta0))):is(abs(ts(ksi0,mn0(eta0))),ts(abs(ksi0),abs(eta0)))
t9:=tris(rl,abs(mn0(ts(ksi0,eta0))),abs(ts(ksi0,eta0)),ts(abs(ksi0),abs(eta0)),satz178(ts(ksi0,eta0)),satz193(ksi0,eta0)):is(abs(mn0(ts(ksi0,eta0))),ts(abs(ksi0),abs(eta0)))
t10:=tris2(rl,abs(ts(mn0(ksi0),eta0)),abs(mn0(ts(ksi0,eta0))),ts(abs(ksi0),abs(eta0)),t7,t9):is(abs(ts(mn0(ksi0),eta0)),abs(mn0(ts(ksi0,eta0))))
t11:=tris2(rl,abs(ts(ksi0,mn0(eta0))),abs(mn0(ts(ksi0,eta0))),ts(abs(ksi0),abs(eta0)),t8,t9):is(abs(ts(ksi0,mn0(eta0))),abs(mn0(ts(ksi0,eta0))))
[p:pos(ts(mn0(ksi0),eta0))][q:pos(ts(ksi0,mn0(eta0)))][r:pos(mn0(ts(ksi0,eta0)))]
t12:=satz166c(ts(mn0(ksi0),eta0),mn0(ts(ksi0,eta0)),p,r,t10):is(ts(mn0(ksi0),eta0),mn0(ts(ksi0,eta0)))
t13:=satz166c(ts(ksi0,mn0(eta0)),mn0(ts(ksi0,eta0)),q,r,t11):is(ts(ksi0,mn0(eta0)),mn0(ts(ksi0,eta0)))
eta0@[n:neg(ts(mn0(ksi0),eta0))][o:neg(ts(ksi0,mn0(eta0)))][p:neg(mn0(ts(ksi0,eta0)))]
t14:=satz166d(ts(mn0(ksi0),eta0),mn0(ts(ksi0,eta0)),n,p,t10):is(ts(mn0(ksi0),eta0),mn0(ts(ksi0,eta0)))
t15:=satz166d(ts(ksi0,mn0(eta0)),mn0(ts(ksi0,eta0)),o,p,t11):is(ts(ksi0,mn0(eta0)),mn0(ts(ksi0,eta0)))
eta0@[p:pos(ksi0)][q:pos(eta0)]
t16:=negts2(mn0(ksi0),eta0,satz176a(ksi0,p),q):neg(ts(mn0(ksi0),eta0))
t17:=negts1(ksi0,mn0(eta0),p,satz176a(eta0,q)):neg(ts(ksi0,mn0(eta0)))
t18:=satz176a(ts(ksi0,eta0),posts(ksi0,eta0,p,q)):neg(mn0(ts(ksi0,eta0)))
p@[n:neg(eta0)]
t19:=posts1(mn0(ksi0),eta0,satz176a(ksi0,p),n):pos(ts(mn0(ksi0),eta0))
t20:=posts(ksi0,mn0(eta0),p,satz176c(eta0,n)):pos(ts(ksi0,mn0(eta0)))
t21:=satz176c(ts(ksi0,eta0),negts1(ksi0,eta0,p,n)):pos(mn0(ts(ksi0,eta0)))
p@t22:=rlapp(eta0,is(ts(mn0(ksi0),eta0),mn0(ts(ksi0,eta0))),[t:pos(eta0)]t14(t16(t),t17(t),t18(t)),[t:is(eta0,0)]t5(t),[t:neg(eta0)]t12(t19(t),t20(t),t21(t))):is(ts(mn0(ksi0),eta0),mn0(ts(ksi0,eta0)))
t23:=rlapp(eta0,is(ts(ksi0,mn0(eta0)),mn0(ts(ksi0,eta0))),[t:pos(eta0)]t15(t16(t),t17(t),t18(t)),[t:is(eta0,0)]t6(t),[t:neg(eta0)]t13(t19(t),t20(t),t21(t))):is(ts(ksi0,mn0(eta0)),mn0(ts(ksi0,eta0)))
eta0@[n:neg(ksi0)][p:pos(eta0)]
t24:=posts(mn0(ksi0),eta0,satz176c(ksi0,n),p):pos(ts(mn0(ksi0),eta0))
t25:=posts1(ksi0,mn0(eta0),n,satz176a(eta0,p)):pos(ts(ksi0,mn0(eta0)))
t26:=satz176c(ts(ksi0,eta0),negts2(ksi0,eta0,n,p)):pos(mn0(ts(ksi0,eta0)))
n@[o:neg(eta0)]
t27:=negts1(mn0(ksi0),eta0,satz176c(ksi0,n),o):neg(ts(mn0(ksi0),eta0))
t28:=negts2(ksi0,mn0(eta0),n,satz176c(eta0,o)):neg(ts(ksi0,mn0(eta0)))
t29:=satz176a(ts(ksi0,eta0),posts1(ksi0,eta0,n,o)):neg(mn0(ts(ksi0,eta0)))
n@t30:=rlapp(eta0,is(ts(mn0(ksi0),eta0),mn0(ts(ksi0,eta0))),[t:pos(eta0)]t12(t24(t),t25(t),t26(t)),[t:is(eta0,0)]t5(t),[t:neg(eta0)]t14(t27(t),t28(t),t29(t))):is(ts(mn0(ksi0),eta0),mn0(ts(ksi0,eta0)))
t31:=rlapp(eta0,is(ts(ksi0,mn0(eta0)),mn0(ts(ksi0,eta0))),[t:pos(eta0)]t13(t24(t),t25(t),t26(t)),[t:is(eta0,0)]t6(t),[t:neg(eta0)]t15(t27(t),t28(t),t29(t))):is(ts(ksi0,mn0(eta0)),mn0(ts(ksi0,eta0)))
-4197
eta0@satz197a:=rlapp(ksi0,is(ts(mn0(ksi0),eta0),mn0(ts(ksi0,eta0))),[t:pos(ksi0)]t22".4197"(t),[t:is(ksi0,0)]t2".4197"(t),[t:neg(ksi0)]t30".4197"(t)):is(ts(mn0(ksi0),eta0),mn0(ts(ksi0,eta0)))
satz197b:=rlapp(ksi0,is(ts(ksi0,mn0(eta0)),mn0(ts(ksi0,eta0))),[t:pos(ksi0)]t23".4197"(t),[t:is(ksi0,0)]t3".4197"(t),[t:neg(ksi0)]t31".4197"(t)):is(ts(ksi0,mn0(eta0)),mn0(ts(ksi0,eta0)))
satz197c:=tris2(rl,ts(mn0(ksi0),eta0),ts(ksi0,mn0(eta0)),mn0(ts(ksi0,eta0)),satz197a,satz197b):is(ts(mn0(ksi0),eta0),ts(ksi0,mn0(eta0)))
satz197d:=symis(rl,ts(mn0(ksi0),eta0),ts(ksi0,mn0(eta0)),satz197c):is(ts(ksi0,mn0(eta0)),ts(mn0(ksi0),eta0))
satz197e:=symis(rl,ts(mn0(ksi0),eta0),mn0(ts(ksi0,eta0)),satz197a):is(mn0(ts(ksi0,eta0)),ts(mn0(ksi0),eta0))
satz197f:=symis(rl,ts(ksi0,mn0(eta0)),mn0(ts(ksi0,eta0)),satz197b):is(mn0(ts(ksi0,eta0)),ts(ksi0,mn0(eta0)))
satz198:=tris(rl,ts(mn0(ksi0),mn0(eta0)),ts(ksi0,mn0(mn0(eta0))),ts(ksi0,eta0),satz197c(ksi0,mn0(eta0)),ists2(mn0(mn0(eta0)),eta0,ksi0,satz177(eta0))):is(ts(mn0(ksi0),mn0(eta0)),ts(ksi0,eta0))
satz198a:=symis(rl,ts(mn0(ksi0),mn0(eta0)),ts(ksi0,eta0),satz198):is(ts(ksi0,eta0),ts(mn0(ksi0),mn0(eta0)))
+4199
zeta0@[p:pos(ksi0)][q:pos(eta0)][r:pos(zeta0)]
ksi:=rpofp(ksi0,p):cut
eta:=rpofp(eta0,q):cut
zeta:=rpofp(zeta0,r):cut
t1:=posts(ksi0,eta0,p,q):pos(ts(ksi0,eta0))
t2:=posts(eta0,zeta0,q,r):pos(ts(eta0,zeta0))
t3:=tris(cut,rpofp(ts(ksi0,eta0),t1),rpofp(pofrp(ts"rp"(ksi,eta)),posi(ts"rp"(ksi,eta))),ts"rp"(ksi,eta),isperp(ts(ksi0,eta0),t1,pofrp(ts"rp"(ksi,eta)),posi(ts"rp"(ksi,eta)),tspp(ksi0,eta0,p,q)),isrpp2(ts"rp"(ksi,eta))):is"rp"(rpofp(ts(ksi0,eta0),t1),ts"rp"(ksi,eta))
t4:=symis(cut,rpofp(ts(eta0,zeta0),t2),ts"rp"(eta,zeta),t3(eta0,zeta0,ksi0,q,r,p)):is"rp"(ts"rp"(eta,zeta),rpofp(ts(eta0,zeta0),t2))
t5:=tr3is(cut,ts"rp"(rpofp(ts(ksi0,eta0),t1),zeta),ts"rp"(ts"rp"(ksi,eta),zeta),ts"rp"(ksi,ts"rp"(eta,zeta)),ts"rp"(ksi,rpofp(ts(eta0,zeta0),t2)),ists1"rp"(rpofp(ts(ksi0,eta0),t1),ts"rp"(ksi,eta),zeta,t3),assts1(ksi,eta,zeta),ists2"rp"(ts"rp"(eta,zeta),rpofp(ts(eta0,zeta0),t2),ksi,t4)):is"rp"(ts"rp"(rpofp(ts(ksi0,eta0),t1),zeta),ts"rp"(ksi,rpofp(ts(eta0,zeta0),t2)))
t6:=tr3is(rl,ts(ts(ksi0,eta0),zeta0),pofrp(ts"rp"(rpofp(ts(ksi0,eta0),t1),zeta)),pofrp(ts"rp"(ksi,rpofp(ts(eta0,zeta0),t2))),ts(ksi0,ts(eta0,zeta0)),tspp(ts(ksi0,eta0),zeta0,t1,r),isrpep(ts"rp"(rpofp(ts(ksi0,eta0),t1),zeta),ts"rp"(ksi,rpofp(ts(eta0,zeta0),t2)),t5),symis(rl,ts(ksi0,ts(eta0,zeta0)),pofrp(ts"rp"(ksi,rpofp(ts(eta0,zeta0),t2))),tspp(ksi0,ts(eta0,zeta0),p,t2))):is(ts(ts(ksi0,eta0),zeta0),ts(ksi0,ts(eta0,zeta0)))
zeta0@[i:is(ksi0,0)]
t7:=ts01(ts(ksi0,eta0),zeta0,ts01(ksi0,eta0,i)):is(ts(ts(ksi0,eta0),zeta0),0)
t8:=tris2(rl,ts(ts(ksi0,eta0),zeta0),ts(ksi0,ts(eta0,zeta0)),0,t7,ts01(ksi0,ts(eta0,zeta0),i)):is(ts(ts(ksi0,eta0),zeta0),ts(ksi0,ts(eta0,zeta0)))
zeta0@[i:is(eta0,0)]
t9:=ts01(ts(ksi0,eta0),zeta0,ts02(ksi0,eta0,i)):is(ts(ts(ksi0,eta0),zeta0),0)
t10:=ts02(ksi0,ts(eta0,zeta0),ts01(eta0,zeta0,i)):is(ts(ksi0,ts(eta0,zeta0)),0)
t11:=tris2(rl,ts(ts(ksi0,eta0),zeta0),ts(ksi0,ts(eta0,zeta0)),0,t9,t10):is(ts(ts(ksi0,eta0),zeta0),ts(ksi0,ts(eta0,zeta0)))
zeta0@[i:is(zeta0,0)]
t12:=ts02(ksi0,ts(eta0,zeta0),ts02(eta0,zeta0,i)):is(ts(ksi0,ts(eta0,zeta0)),0)
t13:=tris2(rl,ts(ts(ksi0,eta0),zeta0),ts(ksi0,ts(eta0,zeta0)),0,ts02(ts(ksi0,eta0),zeta0,i),t12):is(ts(ts(ksi0,eta0),zeta0),ts(ksi0,ts(eta0,zeta0)))
zeta0@[n:nis(ksi0,0)][o:nis(eta0,0)][p:nis(zeta0,0)]
t14:=tr3is(rl,abs(ts(ts(ksi0,eta0),zeta0)),ts(abs(ts(ksi0,eta0)),abs(zeta0)),ts(ts(abs(ksi0),abs(eta0)),abs(zeta0)),ts(abs(ksi0),ts(abs(eta0),abs(zeta0))),satz193(ts(ksi0,eta0),zeta0),ists1(abs(ts(ksi0,eta0)),ts(abs(ksi0),abs(eta0)),abs(zeta0),satz193(ksi0,eta0)),t6(abs(ksi0),abs(eta0),abs(zeta0),satz166e(ksi0,n),satz166e(eta0,o),satz166e(zeta0,p))):is(abs(ts(ts(ksi0,eta0),zeta0)),ts(abs(ksi0),ts(abs(eta0),abs(zeta0))))
t15:=tr3is(rl,abs(ts(ts(ksi0,eta0),zeta0)),ts(abs(ksi0),ts(abs(eta0),abs(zeta0))),ts(abs(ksi0),abs(ts(eta0,zeta0))),abs(ts(ksi0,ts(eta0,zeta0))),t14,ists2(ts(abs(eta0),abs(zeta0)),abs(ts(eta0,zeta0)),abs(ksi0),satz193a(eta0,zeta0)),satz193a(ksi0,ts(eta0,zeta0))):is(abs(ts(ts(ksi0,eta0),zeta0)),abs(ts(ksi0,ts(eta0,zeta0))))
[q:pos(ts(ts(ksi0,eta0),zeta0))][r:pos(ts(ksi0,ts(eta0,zeta0)))]
t16:=satz166c(ts(ts(ksi0,eta0),zeta0),ts(ksi0,ts(eta0,zeta0)),q,r,t15):is(ts(ts(ksi0,eta0),zeta0),ts(ksi0,ts(eta0,zeta0)))
p@[q:neg(ts(ts(ksi0,eta0),zeta0))][r:neg(ts(ksi0,ts(eta0,zeta0)))]
t17:=satz166d(ts(ts(ksi0,eta0),zeta0),ts(ksi0,ts(eta0,zeta0)),q,r,t15):is(ts(ts(ksi0,eta0),zeta0),ts(ksi0,ts(eta0,zeta0)))
zeta0@assoc:=is(ts(ts(ksi0,eta0),zeta0),ts(ksi0,ts(eta0,zeta0))):'prop'
[p:pos(ksi0)][q:pos(eta0)][r:pos(zeta0)]
t18:=posts(ts(ksi0,eta0),zeta0,posts(ksi0,eta0,p,q),r):pos(ts(ts(ksi0,eta0),zeta0))
t19:=posts(ksi0,ts(eta0,zeta0),p,posts(eta0,zeta0,q,r)):pos(ts(ksi0,ts(eta0,zeta0)))
q@[n:neg(zeta0)]
t20:=negts1(ts(ksi0,eta0),zeta0,posts(ksi0,eta0,p,q),n):neg(ts(ts(ksi0,eta0),zeta0))
t21:=negts1(ksi0,ts(eta0,zeta0),p,negts1(eta0,zeta0,q,n)):neg(ts(ksi0,ts(eta0,zeta0)))
q@t22:=rlapp(zeta0,assoc,[t:pos(zeta0)]t16(pnot0(ksi0,p),pnot0(eta0,q),pnot0(zeta0,t),t18(t),t19(t)),[t:is(zeta0,0)]t13(t),[t:neg(zeta0)]t17(pnot0(ksi0,p),pnot0(eta0,q),nnot0(zeta0,t),t20(t),t21(t))):assoc
p@[n:neg(eta0)][q:pos(zeta0)]
t23:=negts2(ts(ksi0,eta0),zeta0,negts1(ksi0,eta0,p,n),q):neg(ts(ts(ksi0,eta0),zeta0))
t24:=negts1(ksi0,ts(eta0,zeta0),p,negts2(eta0,zeta0,n,q)):neg(ts(ksi0,ts(eta0,zeta0)))
n@[o:neg(zeta0)]
t25:=posts1(ts(ksi0,eta0),zeta0,negts1(ksi0,eta0,p,n),o):pos(ts(ts(ksi0,eta0),zeta0))
t26:=posts(ksi0,ts(eta0,zeta0),p,posts1(eta0,zeta0,n,o)):pos(ts(ksi0,ts(eta0,zeta0)))
n@t27:=rlapp(zeta0,assoc,[t:pos(zeta0)]t17(pnot0(ksi0,p),nnot0(eta0,n),pnot0(zeta0,t),t23(t),t24(t)),[t:is(zeta0,0)]t13(t),[t:neg(zeta0)]t16(pnot0(ksi0,p),nnot0(eta0,n),nnot0(zeta0,t),t25(t),t26(t))):assoc
p@t28:=rlapp(eta0,assoc,[t:pos(eta0)]t22(t),[t:is(eta0,0)]t11(t),[t:neg(eta0)]t27(t)):assoc
zeta0@[n:neg(ksi0)][p:pos(eta0)][q:pos(zeta0)]
t29:=negts2(ts(ksi0,eta0),zeta0,negts2(ksi0,eta0,n,p),q):neg(ts(ts(ksi0,eta0),zeta0))
t30:=negts2(ksi0,ts(eta0,zeta0),n,posts(eta0,zeta0,p,q)):neg(ts(ksi0,ts(eta0,zeta0)))
p@[o:neg(zeta0)]
t31:=posts1(ts(ksi0,eta0),zeta0,negts2(ksi0,eta0,n,p),o):pos(ts(ts(ksi0,eta0),zeta0))
t32:=posts1(ksi0,ts(eta0,zeta0),n,negts1(eta0,zeta0,p,o)):pos(ts(ksi0,ts(eta0,zeta0)))
p@t33:=rlapp(zeta0,assoc,[t:pos(zeta0)]t17(nnot0(ksi0,n),pnot0(eta0,p),pnot0(zeta0,t),t29(t),t30(t)),[t:is(zeta0,0)]t13(t),[t:neg(zeta0)]t16(nnot0(ksi0,n),pnot0(eta0,p),nnot0(zeta0,t),t31(t),t32(t))):assoc
n@[o:neg(eta0)][p:pos(zeta0)]
t34:=posts(ts(ksi0,eta0),zeta0,posts1(ksi0,eta0,n,o),p):pos(ts(ts(ksi0,eta0),zeta0))
t35:=posts1(ksi0,ts(eta0,zeta0),n,negts2(eta0,zeta0,o,p)):pos(ts(ksi0,ts(eta0,zeta0)))
o@[p:neg(zeta0)]
t36:=negts1(ts(ksi0,eta0),zeta0,posts1(ksi0,eta0,n,o),p):neg(ts(ts(ksi0,eta0),zeta0))
t37:=negts2(ksi0,ts(eta0,zeta0),n,posts1(eta0,zeta0,o,p)):neg(ts(ksi0,ts(eta0,zeta0)))
o@t38:=rlapp(zeta0,assoc,[t:pos(zeta0)]t16(nnot0(ksi0,n),nnot0(eta0,o),pnot0(zeta0,t),t34(t),t35(t)),[t:is(zeta0,0)]t13(t),[t:neg(zeta0)]t17(nnot0(ksi0,n),nnot0(eta0,o),nnot0(zeta0,t),t36(t),t37(t))):assoc
n@t39:=rlapp(eta0,assoc,[t:pos(eta0)]t33(t),[t:is(eta0,0)]t11(t),[t:neg(eta0)]t38(t)):assoc
-4199
zeta0@satz199:=rlapp(ksi0,assoc".4199",[t:pos(ksi0)]t28".4199"(t),[t:is(ksi0,0)]t8".4199"(t),[t:neg(ksi0)]t39".4199"(t)):is(ts(ts(ksi0,eta0),zeta0),ts(ksi0,ts(eta0,zeta0)))
assts1:=satz199:is(ts(ts(ksi0,eta0),zeta0),ts(ksi0,ts(eta0,zeta0)))
assts2:=symis(rl,ts(ts(ksi0,eta0),zeta0),ts(ksi0,ts(eta0,zeta0)),satz199):is(ts(ksi0,ts(eta0,zeta0)),ts(ts(ksi0,eta0),zeta0))
[p:pos(ksi0)][q:pos(eta0)][r:pos(zeta0)]
+*iv4
r@zeta:=rpofp(zeta0,r):cut
t38a:=pospl(eta0,zeta0,q,r):pos(pl(eta0,zeta0))
t39a:=posts(ksi0,eta0,p,q):pos(ts(ksi0,eta0))
t40:=posts(ksi0,zeta0,p,r):pos(ts(ksi0,zeta0))
t41:=tris(cut,rpofp(pl(eta0,zeta0),t38a),rpofp(pofrp(pl"rp"(eta(q),zeta(r))),posi(pl"rp"(eta(q),zeta(r)))),pl"rp"(eta(q),zeta(r)),isperp(pl(eta0,zeta0),t38a,pofrp(pl"rp"(eta(q),zeta(r))),posi(pl"rp"(eta(q),zeta(r))),plpp(eta0,zeta0,q,r)),isrpp2(pl"rp"(eta(q),zeta(r)))):is"rp"(rpofp(pl(eta0,zeta0),t38a),pl"rp"(eta(q),zeta(r)))
t42:=tris2(cut,ts"rp"(ksi(p),eta(q)),rpofp(ts(ksi0,eta0),t39a),rpofp(pofrp(ts"rp"(ksi(p),eta(q))),posi(ts"rp"(ksi(p),eta(q)))),isrpp1(ts"rp"(ksi(p),eta(q))),isperp(ts(ksi0,eta0),t39a,pofrp(ts"rp"(ksi(p),eta(q))),posi(ts"rp"(ksi(p),eta(q))),tspp(ksi0,eta0,p,q))):is"rp"(ts"rp"(ksi(p),eta(q)),rpofp(ts(ksi0,eta0),t39a))
t43:=t42(ksi0,zeta0,eta0,p,r,q):is"rp"(ts"rp"(ksi(p),zeta(r)),rpofp(ts(ksi0,zeta0),t40))
t44:=tr3is(cut,ts"rp"(ksi(p),rpofp(pl(eta0,zeta0),t38a)),ts"rp"(ksi(p),pl"rp"(eta(q),zeta(r))),pl"rp"(ts"rp"(ksi(p),eta(q)),ts"rp"(ksi(p),zeta(r))),pl"rp"(rpofp(ts(ksi0,eta0),t39a),rpofp(ts(ksi0,zeta0),t40)),ists2"rp"(rpofp(pl(eta0,zeta0),t38a),pl"rp"(eta(q),zeta(r)),ksi(p),t41),disttp2(ksi(p),eta(q),zeta(r)),ispl12"rp"(ts"rp"(ksi(p),eta(q)),rpofp(ts(ksi0,eta0),t39a),ts"rp"(ksi(p),zeta(r)),rpofp(ts(ksi0,zeta0),t40),t42,t43)):is"rp"(ts"rp"(ksi(p),rpofp(pl(eta0,zeta0),t38a)),pl"rp"(rpofp(ts(ksi0,eta0),t39a),rpofp(ts(ksi0,zeta0),t40)))
t45:=tr3is(rl,ts(ksi0,pl(eta0,zeta0)),pofrp(ts"rp"(ksi(p),rpofp(pl(eta0,zeta0),t38a))),pofrp(pl"rp"(rpofp(ts(ksi0,eta0),t39a),rpofp(ts(ksi0,zeta0),t40))),pl(ts(ksi0,eta0),ts(ksi0,zeta0)),tspp(ksi0,pl(eta0,zeta0),p,t38a),isrpep(ts"rp"(ksi(p),rpofp(pl(eta0,zeta0),t38a)),pl"rp"(rpofp(ts(ksi0,eta0),t39a),rpofp(ts(ksi0,zeta0),t40)),t44),symis(rl,pl(ts(ksi0,eta0),ts(ksi0,zeta0)),pofrp(pl"rp"(rpofp(ts(ksi0,eta0),t39a),rpofp(ts(ksi0,zeta0),t40))),plpp(ts(ksi0,eta0),ts(ksi0,zeta0),t39a,t40))):is(ts(ksi0,pl(eta0,zeta0)),pl(ts(ksi0,eta0),ts(ksi0,zeta0)))
-iv4
r@disttp2p:=t45".iv4":is(ts(ksi0,pl(eta0,zeta0)),pl(ts(ksi0,eta0),ts(ksi0,zeta0)))
distpt2p:=symis(rl,ts(ksi0,pl(eta0,zeta0)),pl(ts(ksi0,eta0),ts(ksi0,zeta0)),disttp2p):is(pl(ts(ksi0,eta0),ts(ksi0,zeta0)),ts(ksi0,pl(eta0,zeta0)))
zeta0@[p:pos(ksi0)][q:pos(eta0)][r:pos(zeta0)]
+4200
[m:more(eta0,zeta0)]
t1:=satz182d(eta0,zeta0,m):pos(mn(eta0,zeta0))
t2:=tris(rl,pl(mn(eta0,zeta0),zeta0),pl(zeta0,mn(eta0,zeta0)),eta0,compl(mn(eta0,zeta0),zeta0),satz187a(eta0,zeta0)):is(pl(mn(eta0,zeta0),zeta0),eta0)
t3:=tris(rl,pl(ts(ksi0,mn(eta0,zeta0)),ts(ksi0,zeta0)),ts(ksi0,pl(mn(eta0,zeta0),zeta0)),ts(ksi0,eta0),distpt2p(ksi0,mn(eta0,zeta0),zeta0,p,t1,r),ists2(pl(mn(eta0,zeta0),zeta0),eta0,ksi0,t2)):is(pl(ts(ksi0,mn(eta0,zeta0)),ts(ksi0,zeta0)),ts(ksi0,eta0))
t4:=satz187f(ts(ksi0,eta0),ts(ksi0,zeta0),ts(ksi0,mn(eta0,zeta0)),t3):is(ts(ksi0,mn(eta0,zeta0)),mn(ts(ksi0,eta0),ts(ksi0,zeta0)))
r@[i:is(eta0,zeta0)]
t5:=ists2(eta0,zeta0,ksi0,i):is(ts(ksi0,eta0),ts(ksi0,zeta0))
t6:=tris2(rl,ts(ksi0,mn(eta0,zeta0)),mn(ts(ksi0,eta0),ts(ksi0,zeta0)),0,ts02(ksi0,mn(eta0,zeta0),satz182e(eta0,zeta0,i)),satz182e(ts(ksi0,eta0),ts(ksi0,zeta0),t5)):is(ts(ksi0,mn(eta0,zeta0)),mn(ts(ksi0,eta0),ts(ksi0,zeta0)))
r@[l:less(eta0,zeta0)]
t7:=t4(ksi0,zeta0,eta0,p,r,q,l):is(ts(ksi0,mn(zeta0,eta0)),mn(ts(ksi0,zeta0),ts(ksi0,eta0)))
t8:=tr4is(rl,ts(ksi0,mn(eta0,zeta0)),ts(ksi0,mn0(mn(zeta0,eta0))),mn0(ts(ksi0,mn(zeta0,eta0))),mn0(mn(ts(ksi0,zeta0),ts(ksi0,eta0))),mn(ts(ksi0,eta0),ts(ksi0,zeta0)),ists2(mn(eta0,zeta0),mn0(mn(zeta0,eta0)),ksi0,satz181a(eta0,zeta0)),satz197b(ksi0,mn(zeta0,eta0)),ismn0(ts(ksi0,mn(zeta0,eta0)),mn(ts(ksi0,zeta0),ts(ksi0,eta0)),t7),satz181(ts(ksi0,zeta0),ts(ksi0,eta0))):is(ts(ksi0,mn(eta0,zeta0)),mn(ts(ksi0,eta0),ts(ksi0,zeta0)))
-4200
satz200:=or3app(is(eta0,zeta0),more(eta0,zeta0),less(eta0,zeta0),is(ts(ksi0,mn(eta0,zeta0)),mn(ts(ksi0,eta0),ts(ksi0,zeta0))),satz167a(eta0,zeta0),[t:is(eta0,zeta0)]t6".4200"(t),[t:more(eta0,zeta0)]t4".4200"(t),[t:less(eta0,zeta0)]t8".4200"(t)):is(ts(ksi0,mn(eta0,zeta0)),mn(ts(ksi0,eta0),ts(ksi0,zeta0)))
satz200a:=symis(rl,ts(ksi0,mn(eta0,zeta0)),mn(ts(ksi0,eta0),ts(ksi0,zeta0)),satz200):is(mn(ts(ksi0,eta0),ts(ksi0,zeta0)),ts(ksi0,mn(eta0,zeta0)))
+4201
zeta0@[p:pos(ksi0)][eta1:rl][eta2:rl][q1:pos(eta1)][q2:pos(eta2)][i:is(eta0,mn(eta1,eta2))][zeta1:rl][zeta2:rl][r1:pos(zeta1)][r2:pos(zeta2)][j:is(zeta0,mn(zeta1,zeta2))]
t1:=satz185(eta0,zeta0,eta1,eta2,zeta1,zeta2,q1,q2,r1,r2,i,j):is(pl(eta0,zeta0),mn(pl(eta1,zeta1),pl(eta2,zeta2)))
t2:=tr3is(rl,ts(ksi0,pl(eta0,zeta0)),ts(ksi0,mn(pl(eta1,zeta1),pl(eta2,zeta2))),mn(ts(ksi0,pl(eta1,zeta1)),ts(ksi0,pl(eta2,zeta2))),mn(pl(ts(ksi0,eta1),ts(ksi0,zeta1)),pl(ts(ksi0,eta2),ts(ksi0,zeta2))),ists2(pl(eta0,zeta0),mn(pl(eta1,zeta1),pl(eta2,zeta2)),ksi0,t1),satz200(ksi0,pl(eta1,zeta1),pl(eta2,zeta2),p,pospl(eta1,zeta1,q1,r1),pospl(eta2,zeta2,q2,r2)),ismn12(ts(ksi0,pl(eta1,zeta1)),pl(ts(ksi0,eta1),ts(ksi0,zeta1)),ts(ksi0,pl(eta2,zeta2)),pl(ts(ksi0,eta2),ts(ksi0,zeta2)),disttp2p(ksi0,eta1,zeta1,p,q1,r1),disttp2p(ksi0,eta2,zeta2,p,q2,r2))):is(ts(ksi0,pl(eta0,zeta0)),mn(pl(ts(ksi0,eta1),ts(ksi0,zeta1)),pl(ts(ksi0,eta2),ts(ksi0,zeta2))))
t3:=tris(rl,ts(ksi0,pl(eta0,zeta0)),mn(pl(ts(ksi0,eta1),ts(ksi0,zeta1)),pl(ts(ksi0,eta2),ts(ksi0,zeta2))),pl(mn(ts(ksi0,eta1),ts(ksi0,eta2)),mn(ts(ksi0,zeta1),ts(ksi0,zeta2))),t2,satz185a(mn(ts(ksi0,eta1),ts(ksi0,eta2)),mn(ts(ksi0,zeta1),ts(ksi0,zeta2)),ts(ksi0,eta1),ts(ksi0,eta2),ts(ksi0,zeta1),ts(ksi0,zeta2),posts(ksi0,eta1,p,q1),posts(ksi0,eta2,p,q2),posts(ksi0,zeta1,p,r1),posts(ksi0,zeta2,p,r2),refis(rl,mn(ts(ksi0,eta1),ts(ksi0,eta2))),refis(rl,mn(ts(ksi0,zeta1),ts(ksi0,zeta2))))):is(ts(ksi0,pl(eta0,zeta0)),pl(mn(ts(ksi0,eta1),ts(ksi0,eta2)),mn(ts(ksi0,zeta1),ts(ksi0,zeta2))))
t4:=tris(rl,mn(ts(ksi0,eta1),ts(ksi0,eta2)),ts(ksi0,mn(eta1,eta2)),ts(ksi0,eta0),satz200a(ksi0,eta1,eta2,p,q1,q2),ists2(mn(eta1,eta2),eta0,ksi0,symis(rl,eta0,mn(eta1,eta2),i))):is(mn(ts(ksi0,eta1),ts(ksi0,eta2)),ts(ksi0,eta0))
t5:=t4(ksi0,zeta0,eta0,p,zeta1,zeta2,r1,r2,j,eta1,eta2,q1,q2,i):is(mn(ts(ksi0,zeta1),ts(ksi0,zeta2)),ts(ksi0,zeta0))
t6:=tris(rl,ts(ksi0,pl(eta0,zeta0)),pl(mn(ts(ksi0,eta1),ts(ksi0,eta2)),mn(ts(ksi0,zeta1),ts(ksi0,zeta2))),pl(ts(ksi0,eta0),ts(ksi0,zeta0)),t3,ispl12(mn(ts(ksi0,eta1),ts(ksi0,eta2)),ts(ksi0,eta0),mn(ts(ksi0,zeta1),ts(ksi0,zeta2)),ts(ksi0,zeta0),t4,t5)):is(ts(ksi0,pl(eta0,zeta0)),pl(ts(ksi0,eta0),ts(ksi0,zeta0)))
i@t7:=satz184app(zeta0,is(ts(ksi0,pl(eta0,zeta0)),pl(ts(ksi0,eta0),ts(ksi0,zeta0))),[x:rl][y:rl][t:pos(x)][u:pos(y)][v:is(zeta0,mn(x,y))]t6(x,y,t,u,v)):is(ts(ksi0,pl(eta0,zeta0)),pl(ts(ksi0,eta0),ts(ksi0,zeta0)))
p@t8:=satz184app(eta0,is(ts(ksi0,pl(eta0,zeta0)),pl(ts(ksi0,eta0),ts(ksi0,zeta0))),[x:rl][y:rl][t:pos(x)][u:pos(y)][v:is(eta0,mn(x,y))]t7(x,y,t,u,v)):is(ts(ksi0,pl(eta0,zeta0)),pl(ts(ksi0,eta0),ts(ksi0,zeta0)))
zeta0@[i:is(ksi0,0)]
t9:=tris2(rl,ts(ksi0,pl(eta0,zeta0)),pl(ts(ksi0,eta0),ts(ksi0,zeta0)),0,ts01(ksi0,pl(eta0,zeta0),i),tris(rl,pl(ts(ksi0,eta0),ts(ksi0,zeta0)),ts(ksi0,zeta0),0,pl01(ts(ksi0,eta0),ts(ksi0,zeta0),ts01(ksi0,eta0,i)),ts01(ksi0,zeta0,i))):is(ts(ksi0,pl(eta0,zeta0)),pl(ts(ksi0,eta0),ts(ksi0,zeta0)))
zeta0@[n:neg(ksi0)]
t10:=tris(rl,mn0(ts(ksi0,pl(eta0,zeta0))),ts(mn0(ksi0),pl(eta0,zeta0)),pl(ts(mn0(ksi0),eta0),ts(mn0(ksi0),zeta0)),satz197e(ksi0,pl(eta0,zeta0)),t8(mn0(ksi0),eta0,zeta0,satz176c(ksi0,n))):is(mn0(ts(ksi0,pl(eta0,zeta0))),pl(ts(mn0(ksi0),eta0),ts(mn0(ksi0),zeta0)))
t11:=tr3is(rl,ts(ksi0,pl(eta0,zeta0)),mn0(mn0(ts(ksi0,pl(eta0,zeta0)))),mn0(pl(ts(mn0(ksi0),eta0),ts(mn0(ksi0),zeta0))),pl(mn0(ts(mn0(ksi0),eta0)),mn0(ts(mn0(ksi0),zeta0))),satz177a(ts(ksi0,pl(eta0,zeta0))),ismn0(mn0(ts(ksi0,pl(eta0,zeta0))),pl(ts(mn0(ksi0),eta0),ts(mn0(ksi0),zeta0)),t10),satz180a(ts(mn0(ksi0),eta0),ts(mn0(ksi0),zeta0))):is(ts(ksi0,pl(eta0,zeta0)),pl(mn0(ts(mn0(ksi0),eta0)),mn0(ts(mn0(ksi0),zeta0))))
t12:=tris(rl,mn0(ts(mn0(ksi0),eta0)),ts(mn0(mn0(ksi0)),eta0),ts(ksi0,eta0),satz197e(mn0(ksi0),eta0),ists1(mn0(mn0(ksi0)),ksi0,eta0,satz177(ksi0))):is(mn0(ts(mn0(ksi0),eta0)),ts(ksi0,eta0))
t13:=t12(ksi0,zeta0,eta0,n):is(mn0(ts(mn0(ksi0),zeta0)),ts(ksi0,zeta0))
t14:=tris(rl,ts(ksi0,pl(eta0,zeta0)),pl(mn0(ts(mn0(ksi0),eta0)),mn0(ts(mn0(ksi0),zeta0))),pl(ts(ksi0,eta0),ts(ksi0,zeta0)),t11,ispl12(mn0(ts(mn0(ksi0),eta0)),ts(ksi0,eta0),mn0(ts(mn0(ksi0),zeta0)),ts(ksi0,zeta0),t12,t13)):is(ts(ksi0,pl(eta0,zeta0)),pl(ts(ksi0,eta0),ts(ksi0,zeta0)))
-4201
zeta0@satz201:=rlapp(ksi0,is(ts(ksi0,pl(eta0,zeta0)),pl(ts(ksi0,eta0),ts(ksi0,zeta0))),[t:pos(ksi0)]t8".4201"(t),[t:is(ksi0,0)]t9".4201"(t),[t:neg(ksi0)]t14".4201"(t)):is(ts(ksi0,pl(eta0,zeta0)),pl(ts(ksi0,eta0),ts(ksi0,zeta0)))
disttp1:=tr3is(rl,ts(pl(ksi0,eta0),zeta0),ts(zeta0,pl(ksi0,eta0)),pl(ts(zeta0,ksi0),ts(zeta0,eta0)),pl(ts(ksi0,zeta0),ts(eta0,zeta0)),comts(pl(ksi0,eta0),zeta0),satz201(zeta0,ksi0,eta0),ispl12(ts(zeta0,ksi0),ts(ksi0,zeta0),ts(zeta0,eta0),ts(eta0,zeta0),comts(zeta0,ksi0),comts(zeta0,eta0))):is(ts(pl(ksi0,eta0),zeta0),pl(ts(ksi0,zeta0),ts(eta0,zeta0)))
disttp2:=satz201:is(ts(ksi0,pl(eta0,zeta0)),pl(ts(ksi0,eta0),ts(ksi0,zeta0)))
distpt1:=symis(rl,ts(pl(ksi0,eta0),zeta0),pl(ts(ksi0,zeta0),ts(eta0,zeta0)),disttp1):is(pl(ts(ksi0,zeta0),ts(eta0,zeta0)),ts(pl(ksi0,eta0),zeta0))
distpt2:=symis(rl,ts(ksi0,pl(eta0,zeta0)),pl(ts(ksi0,eta0),ts(ksi0,zeta0)),disttp2):is(pl(ts(ksi0,eta0),ts(ksi0,zeta0)),ts(ksi0,pl(eta0,zeta0)))
satz202:=tris(rl,ts(ksi0,mn(eta0,zeta0)),pl(ts(ksi0,eta0),ts(ksi0,mn0(zeta0))),mn(ts(ksi0,eta0),ts(ksi0,zeta0)),disttp2(ksi0,eta0,mn0(zeta0)),ispl2(ts(ksi0,mn0(zeta0)),mn0(ts(ksi0,zeta0)),ts(ksi0,eta0),satz197b(ksi0,zeta0))):is(ts(ksi0,mn(eta0,zeta0)),mn(ts(ksi0,eta0),ts(ksi0,zeta0)))
disttm1:=tris(rl,ts(mn(ksi0,eta0),zeta0),pl(ts(ksi0,zeta0),ts(mn0(eta0),zeta0)),mn(ts(ksi0,zeta0),ts(eta0,zeta0)),disttp1(ksi0,mn0(eta0),zeta0),ispl2(ts(mn0(eta0),zeta0),mn0(ts(eta0,zeta0)),ts(ksi0,zeta0),satz197a(eta0,zeta0))):is(ts(mn(ksi0,eta0),zeta0),mn(ts(ksi0,zeta0),ts(eta0,zeta0)))
disttm2:=satz202:is(ts(ksi0,mn(eta0,zeta0)),mn(ts(ksi0,eta0),ts(ksi0,zeta0)))
distmt1:=symis(rl,ts(mn(ksi0,eta0),zeta0),mn(ts(ksi0,zeta0),ts(eta0,zeta0)),disttm1):is(mn(ts(ksi0,zeta0),ts(eta0,zeta0)),ts(mn(ksi0,eta0),zeta0))
distmt2:=symis(rl,ts(ksi0,mn(eta0,zeta0)),mn(ts(ksi0,eta0),ts(ksi0,zeta0)),disttm2):is(mn(ts(ksi0,eta0),ts(ksi0,zeta0)),ts(ksi0,mn(eta0,zeta0)))
[m:more(ksi0,eta0)]
+4203
t1:=satz182d(ksi0,eta0,m):pos(mn(ksi0,eta0))
-4203
[p:pos(zeta0)]
+*4203
p@t2:=isp(rl,[x:rl]pos(x),ts(mn(ksi0,eta0),zeta0),mn(ts(ksi0,zeta0),ts(eta0,zeta0)),posts(mn(ksi0,eta0),zeta0,t1,p),disttm1(ksi0,eta0,zeta0)):pos(mn(ts(ksi0,zeta0),ts(eta0,zeta0)))
-4203
p@satz203a:=satz182a(ts(ksi0,zeta0),ts(eta0,zeta0),t2".4203"):more(ts(ksi0,zeta0),ts(eta0,zeta0))
m@[i:is(zeta0,0)]
+*4203
i@t3:=tris1(rl,mn(ts(ksi0,zeta0),ts(eta0,zeta0)),0,ts(mn(ksi0,eta0),zeta0),disttm1(ksi0,eta0,zeta0),ts02(mn(ksi0,eta0),zeta0,i)):is(mn(ts(ksi0,zeta0),ts(eta0,zeta0)),0)
-4203
i@satz203b:=satz182b(ts(ksi0,zeta0),ts(eta0,zeta0),t3".4203"):is(ts(ksi0,zeta0),ts(eta0,zeta0))
+*4203
i@andersb:=tris2(rl,ts(ksi0,zeta0),ts(eta0,zeta0),0,ts02(ksi0,zeta0,i),ts02(eta0,zeta0,i)):is(ts(ksi0,zeta0),ts(eta0,zeta0))
-4203
m@[n:neg(zeta0)]
+*4203
n@t4:=isp(rl,[x:rl]neg(x),ts(mn(ksi0,eta0),zeta0),mn(ts(ksi0,zeta0),ts(eta0,zeta0)),negts1(mn(ksi0,eta0),zeta0,t1,n),disttm1(ksi0,eta0,zeta0)):neg(mn(ts(ksi0,zeta0),ts(eta0,zeta0)))
-4203
n@satz203c:=satz182c(ts(ksi0,zeta0),ts(eta0,zeta0),t4".4203"):less(ts(ksi0,zeta0),ts(eta0,zeta0))
p@satz203d:=ismore12(ts(ksi0,zeta0),ts(zeta0,ksi0),ts(eta0,zeta0),ts(zeta0,eta0),comts(ksi0,zeta0),comts(eta0,zeta0),satz203a):more(ts(zeta0,ksi0),ts(zeta0,eta0))
i@satz203e:=tr3is(rl,ts(zeta0,ksi0),ts(ksi0,zeta0),ts(eta0,zeta0),ts(zeta0,eta0),comts(zeta0,ksi0),satz203b,comts(eta0,zeta0)):is(ts(zeta0,ksi0),ts(zeta0,eta0))
n@satz203f:=isless12(ts(ksi0,zeta0),ts(zeta0,ksi0),ts(eta0,zeta0),ts(zeta0,eta0),comts(ksi0,zeta0),comts(eta0,zeta0),satz203c):less(ts(zeta0,ksi0),ts(zeta0,eta0))
zeta0@[l:less(ksi0,eta0)][p:pos(zeta0)]
satz203g:=satz203a(eta0,ksi0,zeta0,l,p):less(ts(ksi0,zeta0),ts(eta0,zeta0))
l@[i:is(zeta0,0)]
satz203h:=symis(rl,ts(eta0,zeta0),ts(ksi0,zeta0),satz203b(eta0,ksi0,zeta0,l,i)):is(ts(ksi0,zeta0),ts(eta0,zeta0))
l@[n:neg(zeta0)]
satz203j:=satz203c(eta0,ksi0,zeta0,l,n):more(ts(ksi0,zeta0),ts(eta0,zeta0))
p@satz203k:=satz203d(eta0,ksi0,zeta0,l,p):less(ts(zeta0,ksi0),ts(zeta0,eta0))
i@satz203l:=symis(rl,ts(zeta0,eta0),ts(zeta0,ksi0),satz203e(eta0,ksi0,zeta0,l,i)):is(ts(zeta0,ksi0),ts(zeta0,eta0))
n@satz203m:=satz203f(eta0,ksi0,zeta0,l,n):more(ts(zeta0,ksi0),ts(zeta0,eta0))
eta0@[p:pos(ksi0)][q:pos(eta0)]
ova:=pofrp(ov(rpofp(ksi0,p),rpofp(eta0,q))):rl
+*iv4
q@t46:=posi(ov(ksi(p),eta(q))):pos(ova)
t47:=tris(cut,ts"rp"(eta(q),rpofp(ova,t46)),ts"rp"(eta(q),ov(ksi(p),eta(q))),ksi(p),ists2"rp"(rpofp(ova,t46),ov(ksi(p),eta(q)),eta(q),isrpp2(ov(ksi(p),eta(q)))),satz153c(ksi(p),eta(q))):is"rp"(ts"rp"(eta(q),rpofp(ova,t46)),ksi(p))
-iv4
q@satz153cp:=tr3is(rl,ts(eta0,ova(ksi0,eta0,p,q)),pofrp(ts"rp"(eta".iv4"(q),rpofp(ova(ksi0,eta0,p,q),t46".iv4"))),pofrp(rpofp(ksi0,p)),ksi0,tspp(eta0,ova(ksi0,eta0,p,q),q,t46".iv4"),isrpep(ts"rp"(eta".iv4"(q),rpofp(ova(ksi0,eta0,p,q),t46".iv4")),ksi".iv4"(p),t47".iv4"),isprp2(ksi0,p)):is(ts(eta0,ova(ksi0,eta0,p,q)),ksi0)
eta0@[n:nis(eta0,0)][upsilon1:rl][upsilon2:rl][i:is(ts(eta0,upsilon1),ksi0)][j:is(ts(eta0,upsilon2),ksi0)]
+4204
t1:=tris2(rl,ts(eta0,upsilon1),ts(eta0,upsilon2),ksi0,i,j):is(ts(eta0,upsilon1),ts(eta0,upsilon2))
t2:=tris(rl,ts(eta0,mn(upsilon1,upsilon2)),mn(ts(eta0,upsilon1),ts(eta0,upsilon2)),0,disttm2(eta0,upsilon1,upsilon2),satz182e(ts(eta0,upsilon1),ts(eta0,upsilon2),t1)):is(ts(eta0,mn(upsilon1,upsilon2)),0)
t3:=ore2(is(eta0,0),is(mn(upsilon1,upsilon2),0),satz192c(eta0,mn(upsilon1,upsilon2),t2),n):is(mn(upsilon1,upsilon2),0)
-4204
satz204b:=satz182b(upsilon1,upsilon2,t3".4204"):is(upsilon1,upsilon2)
+*4204
n@t4:=[x:rl][y:rl][t:is(ts(eta0,x),ksi0)][u:is(ts(eta0,y),ksi0)]satz204b(x,y,t,u):amone(rl,[x:rl]is(ts(eta0,x),ksi0))
eta0@[p:pos(eta0)]
zeta0:=ts(ova(1rl,eta0,pos1,p),ksi0):rl
t5:=tr3is(rl,ts(eta0,zeta0),ts(ts(eta0,ova(1rl,eta0,pos1,p)),ksi0),ts(1rl,ksi0),ksi0,assts2(eta0,ova(1rl,eta0,pos1,p),ksi0),ists1(ts(eta0,ova(1rl,eta0,pos1,p)),1rl,ksi0,satz153cp(1rl,eta0,pos1,p)),satz195b(ksi0)):is(ts(eta0,zeta0),ksi0)
t6:=somei(rl,[x:rl]is(ts(eta0,x),ksi0),zeta0,t5):some([x:rl]is(ts(eta0,x),ksi0))
eta0@[n:neg(eta0)]
upsilon0:=mn0(ts(ova(1rl,abs(eta0),pos1,satz166b(eta0,n)),ksi0)):rl
t7:=tr3is(rl,ksi0,ts(abs(eta0),ts(ova(1rl,abs(eta0),pos1,satz166b(eta0,n)),ksi0)),ts(abs(eta0),mn0(upsilon0)),ts(mn0(abs(eta0)),upsilon0),symis(rl,ts(abs(eta0),zeta0(abs(eta0),satz166b(eta0,n))),ksi0,t5(abs(eta0),satz166b(eta0,n))),ists2(zeta0(abs(eta0),satz166b(eta0,n)),mn0(upsilon0),abs(eta0),satz177a(zeta0(abs(eta0),satz166b(eta0,n)))),satz197d(abs(eta0),upsilon0)):is(ksi0,ts(mn0(abs(eta0)),upsilon0))
t8:=tris(rl,ksi0,ts(mn0(abs(eta0)),upsilon0),ts(eta0,upsilon0),t7,ists1(mn0(abs(eta0)),eta0,upsilon0,tris(rl,mn0(abs(eta0)),mn0(mn0(eta0)),eta0,ismn0(abs(eta0),mn0(eta0),absn1(eta0,n)),satz177(eta0)))):is(ksi0,ts(eta0,upsilon0))
t9:=somei(rl,[x:rl]is(ts(eta0,x),ksi0),upsilon0,symis(rl,ksi0,ts(eta0,upsilon0),t8)):some([x:rl]is(ts(eta0,x),ksi0))
-4204
n@satz204a:=rlapp(eta0,some([x:rl]is(ts(eta0,x),ksi0)),[t:pos(eta0)]t6".4204"(t),th2"l.imp"(is(eta0,0),some([x:rl]is(ts(eta0,x),ksi0)),n),[t:neg(eta0)]t9".4204"(t)):some([x:rl]is(ts(eta0,x),ksi0))
satz204:=onei(rl,[x:rl]is(ts(eta0,x),ksi0),t4".4204",satz204a):one([x:rl]is(ts(eta0,x),ksi0))
ov:=ind(rl,[x:rl]is(ts(eta0,x),ksi0),satz204):rl
satz204c:=oneax(rl,[x:rl]is(ts(eta0,x),ksi0),satz204):is(ts(eta0,ov(ksi0,eta0,n)),ksi0)
satz204d:=symis(rl,ts(eta0,ov(ksi0,eta0,n)),ksi0,satz204c):is(ksi0,ts(eta0,ov(ksi0,eta0,n)))
satz204e:=tris(rl,ts(ov(ksi0,eta0,n),eta0),ts(eta0,ov(ksi0,eta0,n)),ksi0,comts(ov(ksi0,eta0,n),eta0),satz204c):is(ts(ov(ksi0,eta0,n),eta0),ksi0)
satz204f:=symis(rl,ts(ov(ksi0,eta0,n),eta0),ksi0,satz204e):is(ksi0,ts(ov(ksi0,eta0,n),eta0))
eta0@[phi0:rl][n:nis(eta0,0)][i:is(ts(eta0,phi0),ksi0)]
satz204g:=satz204b(n,phi0,ov(ksi0,eta0,n),i,satz204c(n)):is(phi0,ov(ksi0,eta0,n))
eta0@[n:nis(eta0,0)][p:pos(ksi0)][q:pos(eta0)]
+*4204
q@t10:=isp(rl,[x:rl]pos(x),ksi0,ts(eta0,ov(ksi0,eta0,n)),p,satz204d(ksi0,eta0,n)):pos(ts(eta0,ov(ksi0,eta0,n)))
t11:=th1"l.and"(neg(eta0),neg(ov(ksi0,eta0,n)),pnotn(eta0,q)):not(and(neg(eta0),neg(ov(ksi0,eta0,n))))
t12:=ore1(and(pos(eta0),pos(ov(ksi0,eta0,n))),and(neg(eta0),neg(ov(ksi0,eta0,n))),satz196g(eta0,ov(ksi0,eta0,n),t10),t11):and(pos(eta0),pos(ov(ksi0,eta0,n)))
-4204
q@posovpp:=ande2(pos(eta0),pos(ov(ksi0,eta0,n)),t12".4204"):pos(ov(ksi0,eta0,n))
ksi0@s01:=setof(rl,[x:rl]lessis(x,ksi0)):set(rl)
s02:=setof(rl,[x:rl]more(x,ksi0)):set(rl)
+5205
eta0@[n:not(in(eta0,s01))]
t1:=th3"l.imp"(lessis(eta0,ksi0),in(eta0,s01),n,[t:lessis(eta0,ksi0)]estii(rl,[x:rl]lessis(x,ksi0),eta0,t)):not(lessis(eta0,ksi0))
t2:=estii(rl,[x:rl]more(x,ksi0),eta0,satz167k(eta0,ksi0,t1)):in(eta0,s02)
-5205
vb00:=[x:rl][t:not(in(x,s01))]t2".5205"(x,t):all([x:rl]or(in(x,s01),in(x,s02)))
+*5205
ksi0@t3:=estii(rl,[x:rl]lessis(x,ksi0),ksi0,lessisi2(ksi0,ksi0,refis(rl,ksi0))):in(ksi0,s01)
-5205
ksi0@vb0ua:=nonemptyi(rl,s01,ksi0,t3".5205"):nonempty(rl,s01)
+*5205
ksi0@t4:=ismore2(pl(ksi0,0),ksi0,pl(ksi0,1rl),pl02(ksi0,0,refis(rl,0)),satz188k(1rl,0,ksi0,satz169a(1rl,pos1))):more(pl(ksi0,1rl),ksi0)
t5:=estii(rl,[x:rl]more(x,ksi0),pl(ksi0,1rl),t4):in(pl(ksi0,1rl),s02)
-5205
ksi0@vb01b:=nonemptyi(rl,s02,pl(ksi0,1rl),t5".5205"):nonempty(rl,s02)
+*5205
eta0@[i:in(eta0,s01)][zeta0:rl][j:in(zeta0,s02)]
t6:=satz172a(eta0,ksi0,zeta0,estie(rl,[x:rl]lessis(x,ksi0),eta0,i),estie(rl,[x:rl]more(x,ksi0),zeta0,j)):less(eta0,zeta0)
-5205
ksi0@vb02:=[x:rl][t:in(x,s01)][y:rl][u:in(y,s02)]t6".5205"(x,t,y,u):all([x:rl][t:in(x,s01)]all([y:rl][u:in(y,s02)]less(x,y)))
eta0@[l:less(eta0,ksi0)]
vb03a:=estii(rl,[x:rl]lessis(x,ksi0),eta0,lessisi1(eta0,ksi0,l)):in(eta0,s01)
eta0@[m:more(eta0,ksi0)]
vb03b:=estii(rl,[x:rl]more(x,ksi0),eta0,m):in(eta0,s02)
ksi0@s11:=setof(rl,[x:rl]less(x,ksi0)):set(rl)
s12:=setof(rl,[x:rl]moreis(x,ksi0)):set(rl)
+*5205
eta0@[n:not(in(eta0,s11))]
t7:=th3"l.imp"(less(eta0,ksi0),in(eta0,s11),n,[t:less(eta0,ksi0)]estii(rl,[x:rl]less(x,ksi0),eta0,t)):not(less(eta0,ksi0))
t8:=estii(rl,[x:rl]moreis(x,ksi0),eta0,satz167f(eta0,ksi0,t7)):in(eta0,s12)
-5205
ksi0@vb10:=[x:rl][t:not(in(x,s11))]t8".5205"(x,t):all([x:rl]or(in(x,s11),in(x,s12)))
+*5205
ksi0@t9:=isless2(pl(ksi0,0),ksi0,mn(ksi0,1rl),pl02(ksi0,0,refis(rl,0)),satz188m(mn0(1rl),0,ksi0,satz169c(mn0(1rl),satz176a(1rl,pos1)))):less(mn(ksi0,1rl),ksi0)
t10:=estii(rl,[x:rl]less(x,ksi0),mn(ksi0,1rl),t9):in(mn(ksi0,1rl),s11)
-5205
ksi0@vb11a:=nonemptyi(rl,s11,mn(ksi0,1rl),t10".5205"):nonempty(rl,s11)
+*5205
ksi0@t11:=estii(rl,[x:rl]moreis(x,ksi0),ksi0,moreisi2(ksi0,ksi0,refis(rl,ksi0))):in(ksi0,s12)
-5205
ksi0@vb10b:=nonemptyi(rl,s12,ksi0,t11".5205"):nonempty(rl,s12)
+*5205
eta0@[i:in(eta0,s11)][zeta0:rl][j:in(zeta0,s12)]
t12:=satz172c(zeta0,ksi0,eta0,estie(rl,[x:rl]moreis(x,ksi0),zeta0,j),estie(rl,[x:rl]less(x,ksi0),eta0,i)):less(eta0,zeta0)
-5205
ksi0@vb12:=[x:rl][t:in(x,s11)][y:rl][u:in(y,s12)]t12".5205"(x,t,y,u):all([x:rl][t:in(x,s11)]all([y:rl][u:in(y,s12)]less(x,y)))
eta0@[l:less(eta0,ksi0)]
vb13a:=estii(rl,[x:rl]less(x,ksi0),eta0,l):in(eta0,s11)
eta0@[m:more(eta0,ksi0)]
vb13b:=estii(rl,[x:rl]moreis(x,ksi0),eta0,moreisi1(eta0,ksi0,m)):in(eta0,s12)
eta0@[n:nis(ksi0,0)]
lemma205a:=tr3is(rl,ts(ov(1rl,ksi0,n),ts(ksi0,eta0)),ts(ts(ov(1rl,ksi0,n),ksi0),eta0),ts(1rl,eta0),eta0,assts2(ov(1rl,ksi0,n),ksi0,eta0),ists1(ts(ov(1rl,ksi0,n),ksi0),1rl,eta0,satz204e(1rl,ksi0,n)),satz195b(eta0)):is(ts(ov(1rl,ksi0,n),ts(ksi0,eta0)),eta0)
lemma205b:=satz204g(eta0,ksi0,ts(ov(1rl,ksi0,n),eta0),n,tr3is(rl,ts(ksi0,ts(ov(1rl,ksi0,n),eta0)),ts(ts(ksi0,ov(1rl,ksi0,n)),eta0),ts(1rl,eta0),eta0,assts2(ksi0,ov(1rl,ksi0,n),eta0),ists1(ts(ksi0,ov(1rl,ksi0,n)),1rl,eta0,satz204c(1rl,ksi0,n)),satz195b(eta0))):is(ts(ov(1rl,ksi0,n),eta0),ov(eta0,ksi0,n))
+*5205
@t13:=pnot0(pl(1rl,1rl),pospl(1rl,1rl,pos1,pos1)):nis(pl(1rl,1rl),0)
-5205
@lemma205c:=posovpp(1rl,pl(1rl,1rl),t13".5205",pos1,pospl(1rl,1rl,pos1,pos1)):pos(ov(1rl,pl(1rl,1rl),t13".5205"))
lemma205d:=satz182a(pl(1rl,1rl),1rl,isp(rl,[x:rl]pos(x),1rl,mn(pl(1rl,1rl),1rl),pos1,satz187d(pl(1rl,1rl),1rl,1rl,refis(rl,pl(1rl,1rl))))):more(pl(1rl,1rl),1rl)
[s1:set(rl)][s2:set(rl)][p0:all([x:rl]or(in(x,s1),in(x,s2)))][p1a:nonempty(rl,s1)][p1b:nonempty(rl,s2)][p2:all([x:rl][t:in(x,s1)]all([y:rl][u:in(y,s2)]less(x,y)))]
+*5205
s2@[ksi0:rl]
prop1:=all([x:rl][t:less(x,ksi0)]in(x,s1)):'prop'
prop2:=all([x:rl][t:more(x,ksi0)]in(x,s2)):'prop'
prop3:=and(prop1,prop2):'prop'
p2@[ksi1:rl][ksi2:rl][px1:prop3(ksi1)][px2:prop3(ksi2)]
t14:=ande2(prop1(ksi1),prop2(ksi1),px1):prop2(ksi1)
t15:=ande1(prop1(ksi2),prop2(ksi2),px2):prop1(ksi2)
[l:less(ksi1,ksi2)]
ksi1@t16:=tris(rl,pl(ksi1,ksi1),pl(ts(1rl,ksi1),ts(1rl,ksi1)),ts(pl(1rl,1rl),ksi1),ispl12(ksi1,ts(1rl,ksi1),ksi1,ts(1rl,ksi1),satz195c(ksi1),satz195c(ksi1)),distpt1(1rl,1rl,ksi1)):is(pl(ksi1,ksi1),ts(pl(1rl,1rl),ksi1))
l@t17:=isless1(pl(ksi1,ksi1),ts(pl(1rl,1rl),ksi1),pl(ksi1,ksi2),t16,satz188m(ksi1,ksi2,ksi1,l)):less(ts(pl(1rl,1rl),ksi1),pl(ksi1,ksi2))
t18:=isless2(pl(ksi2,ksi2),ts(pl(1rl,1rl),ksi2),pl(ksi1,ksi2),t16(ksi2),satz188f(ksi1,ksi2,ksi2,l)):less(pl(ksi1,ksi2),ts(pl(1rl,1rl),ksi2))
t19:=satz203k(ts(pl(1rl,1rl),ksi1),pl(ksi1,ksi2),ov(1rl,pl(1rl,1rl),t13),t17,lemma205c):less(ts(ov(1rl,pl(1rl,1rl),t13),ts(pl(1rl,1rl),ksi1)),ts(ov(1rl,pl(1rl,1rl),t13),pl(ksi1,ksi2)))
t20:=satz203k(pl(ksi1,ksi2),ts(pl(1rl,1rl),ksi2),ov(1rl,pl(1rl,1rl),t13),t18,lemma205c):less(ts(ov(1rl,pl(1rl,1rl),t13),pl(ksi1,ksi2)),ts(ov(1rl,pl(1rl,1rl),t13),ts(pl(1rl,1rl),ksi2)))
ksim:=ov(pl(ksi1,ksi2),pl(1rl,1rl),t13):rl
t21:=isless12(ts(ov(1rl,pl(1rl,1rl),t13),ts(pl(1rl,1rl),ksi1)),ksi1,ts(ov(1rl,pl(1rl,1rl),t13),pl(ksi1,ksi2)),ksim,lemma205a(pl(1rl,1rl),ksi1,t13),lemma205b(pl(1rl,1rl),pl(ksi1,ksi2),t13),t19):less(ksi1,ksim)
t22:=isless12(ts(ov(1rl,pl(1rl,1rl),t13),pl(ksi1,ksi2)),ksim,ts(ov(1rl,pl(1rl,1rl),t13),ts(pl(1rl,1rl),ksi2)),ksi2,lemma205b(pl(1rl,1rl),pl(ksi1,ksi2),t13),lemma205a(pl(1rl,1rl),ksi2,t13),t20):less(ksim,ksi2)
t23:=<t22><ksim>t15:in(ksim,s1)
t24:=<t21><ksim>t14:in(ksim,s2)
t25:=<refis(rl,ksim)>ec3e31(is(ksim,ksim),more(ksim,ksim),less(ksim,ksim),satz167b(ksim,ksim),<t24><ksim><t23><ksim>p2):con
px2@t26:=[t:less(ksi1,ksi2)]t25(t):not(less(ksi1,ksi2))
t27:=t26(ksi2,ksi1,px2,px1):not(more(ksi1,ksi2))
t28:=or3e1(is(ksi1,ksi2),more(ksi1,ksi2),less(ksi1,ksi2),satz167a(ksi1,ksi2),t27,t26):is(ksi1,ksi2)
p2@t29:=[x:rl][y:rl][t:prop3(x)][u:prop3(y)]t28(x,y,t,u):amone(rl,[x:rl]prop3(x))
[ksi0:rl][eta0:rl][i:in(ksi0,s1)][l:less(eta0,ksi0)]
t30:=ec3e32(is(eta0,ksi0),more(eta0,ksi0),less(eta0,ksi0),satz167b(eta0,ksi0),l):not(less(ksi0,eta0))
t31:=th3"l.imp"(in(eta0,s2),less(ksi0,eta0),t30,<eta0><i><ksi0>p2):not(in(eta0,s2))
t32:=ore1(in(eta0,s1),in(eta0,s2),<eta0>p0,t31):in(eta0,s1)
eta0@[i:in(ksi0,s2)][m:more(eta0,ksi0)]
t33:=ec3e23(is(eta0,ksi0),more(eta0,ksi0),less(eta0,ksi0),satz167b(eta0,ksi0),m):not(less(eta0,ksi0))
t34:=th3"l.imp"(in(eta0,s1),less(eta0,ksi0),t33,[t:in(eta0,s1)]<i><ksi0><t><eta0>p2):not(in(eta0,s1))
t35:=ore2(in(eta0,s1),in(eta0,s2),<eta0>p0,t34):in(eta0,s2)
p2@[s:some([x:rl]and(pos(x),in(x,s1)))][x0:rat]
notmax:=some"rt"([y:rat]and(in(pofrt(y),s1),more"rt"(y,x0))):'prop'
ctprop:=and(in(pofrt(x0),s1),notmax(x0)):'prop'
s@ctset:=setof(rat,[x:rat]ctprop(x)):set(rat)
x0@[i:in"rt"(x0,ctset)]
t36:=estie(rat,[x:rat]ctprop(x),x0,i):ctprop(x0)
t37:=ande1(in(pofrt(x0),s1),notmax(x0),t36):in(pofrt(x0),s1)
t38:=ande2(in(pofrt(x0),s1),notmax(x0),t36):notmax(x0)
[y0:rat][n:not(notmax(y0))]
t39:=th4"l.some"(rat,[z:rat]and(in(pofrt(z),s1),more"rt"(z,y0)),n,x0):not(and(in(pofrt(x0),s1),more"rt"(x0,y0)))
t40:=th3"l.and"(in(pofrt(x0),s1),more"rt"(x0,y0),t39,t37):not(more"rt"(x0,y0))
t41:=th3"l.imp"(is"rt"(x0,y0),notmax(y0),n,[t:is"rt"(x0,y0)]isp(rat,[x:rat]notmax(x),x0,y0,t38,t)):nis"rt"(x0,y0)
t42:=or3e3(is"rt"(x0,y0),more"rt"(x0,y0),less"rt"(x0,y0),satz81a(x0,y0),t41,t40):less"rt"(x0,y0)
x0@[c:ctprop(x0)]
t43:=estii(rat,[x:rat]ctprop(x),x0,c):in"rt"(x0,ctset)
x0@[i:in(pofrt(x0),s1)][n:notmax(x0)]
t44:=t43(andi(in(pofrt(x0),s1),notmax(x0),i,n)):in"rt"(x0,ctset)
x0@[y0:rat][i:in"rt"(y0,ctset)][l:less"rt"(x0,y0)]
t45:=th4"l.imp"(in"rt"(y0,ctset),moreis"rt"(x0,y0),i,satz81h(x0,y0,l)):not(imp(in"rt"(y0,ctset),moreis"rt"(x0,y0)))
t46:=th1"l.all"(rat,[z:rat]imp(in"rt"(z,ctset),moreis"rt"(x0,z)),y0,t45):not(ub(ctset,x0))
s@[ksi0:rl][p:pos(ksi0)]
ksi:=rpofp(ksi0,p):cut
ksi0@[a:and(pos(ksi0),in(ksi0,s1))]
t47:=ande1(pos(ksi0),in(ksi0,s1),a):pos(ksi0)
t48:=ande2(pos(ksi0),in(ksi0,s1),a):in(ksi0,s1)
[x0:rat][lx:lrt(ksi(t47),x0)]
t49:=lessipp(pofrt(x0),ksi0,posrt(x0),t47,isless1"rp"(rpofrt(x0),rpofp(pofrt(x0),posrt(x0)),ksi(t47),isrpp1(rpofrt(x0)),satz158a(ksi(t47),x0,lx))):less(pofrt(x0),ksi0)
t50:=t32(ksi0,pofrt(x0),t48,t49):in(pofrt(x0),s1)
[y0:rat][ly:lrt(ksi(t47),y0)][l:less"rt"(x0,y0)]
t51:=andi(in(pofrt(y0),s1),more"rt"(y0,x0),t50(y0,ly),satz83(x0,y0,l)):and(in(pofrt(y0),s1),more"rt"(y0,x0))
t52:=somei(rat,[y:rat]and(in(pofrt(y),s1),more"rt"(y,x0)),y0,t51):notmax(x0)
lx@t53:=cutapp3(ksi(t47),x0,lx,notmax(x0),[y:rat][t:lrt(ksi(t47),y)][u:less"rt"(x0,y)]t52(y,t,u)):notmax(x0)
t54:=t44(x0,t50,t53):in"rt"(x0,ctset)
a@[eta0:rl][i:in(eta0,s2)]
t55:=lessep1a(ksi0,eta0,<i><eta0><t48><ksi0>p2,t47):pos(eta0)
eta:=rpofp(eta0,t55):cut
[x0:rat][ux:urt(eta,x0)]
t56:=satz123c(rpofrt(x0),eta,satz158b(eta,x0,ux)):not(less"rp"(rpofrt(x0),eta))
t57:=th3"l.imp"(less(pofrt(x0),eta0),less"rp"(rpofrt(x0),eta),t56,[t:less(pofrt(x0),eta0)]isless1"rp"(rpofp(pofrt(x0),posrt(x0)),rpofrt(x0),eta,isrpp2(rpofrt(x0)),lessep2(pofrt(x0),eta0,t,posrt(x0),t55))):not(less(pofrt(x0),eta0))
t58:=th3"l.imp"(in(pofrt(x0),s1),less(pofrt(x0),eta0),t57,[t:in(pofrt(x0),s1)]<i><eta0><t><pofrt(x0)>p2):not(in(pofrt(x0),s1))
t59:=th3"l.imp"(in"rt"(x0,ctset),in(pofrt(x0),s1),t58,[t:in"rt"(x0,ctset)]t37(x0,t)):not(in"rt"(x0,ctset))
s@[x0:rat][i:in"rt"(x0,ctset)][y0:rat][n:not(in"rt"(y0,ctset))]
t60:=th3"l.imp"(ctprop(y0),in"rt"(y0,ctset),n,[t:ctprop(y0)]t43(y0,t)):not(ctprop(y0))
t61:=th15"l.or"(in(pofrt(y0),s1),notmax(y0),t60):or(not(in(pofrt(y0),s1)),not(notmax(y0)))
[o:not(in(pofrt(y0),s1))]
t62:=ore2(in(pofrt(y0),s1),in(pofrt(y0),s2),<pofrt(y0)>p0,o):in(pofrt(y0),s2)
t63:=<t62><pofrt(y0)><t37(x0,i)><pofrt(x0)>p2:less(pofrt(x0),pofrt(y0))
t64:=lessrtip(x0,y0,t63):less"rt"(x0,y0)
n@[o:not(notmax(y0))]
t65:=t42(x0,i,y0,o):less"rt"(x0,y0)
n@t66:=orapp(not(in(pofrt(y0),s1)),not(notmax(y0)),less"rt"(x0,y0),t61,[t:not(in(pofrt(y0),s1))]t64(t),[t:not(notmax(y0))]t65(t)):less"rt"(x0,y0)
x0@[a:all"rt"([y:rat]imp(in(pofrt(y),s1),notmax(y)))][i:in"rt"(x0,ctset)]
t67:=t38(x0,i):notmax(x0)
[y0:rat][b:and(in(pofrt(y0),s1),more"rt"(y0,x0))]
t68:=ande1(in(pofrt(y0),s1),more"rt"(y0,x0),b):in(pofrt(y0),s1)
t69:=t44(y0,t68,<t68><y0>a):in"rt"(y0,ctset)
t70:=satz82(y0,x0,ande2(in(pofrt(y0),s1),more"rt"(y0,x0),b)):less"rt"(x0,y0)
t71:=t46(x0,y0,t69,t70):not(ub(ctset,x0))
i@t72:=someapp(rat,[y:rat]and(in(pofrt(y),s1),more"rt"(y,x0)),t67,not(ub(ctset,x0)),[y:rat][t:and(in(pofrt(y),s1),more"rt"(y,x0))]t71(y,t)):not(ub(ctset,x0))
a@t72a:=th2"l.ec"(ub(ctset,x0),in"rt"(x0,ctset),[t:in"rt"(x0,ctset)]t72(t)):ec(ub(ctset,x0),in"rt"(x0,ctset))
t73:=weli(ec(ub(ctset,x0),in"rt"(x0,ctset)),t72a):not(max(ctset,x0))
x0@[n:not(all"rt"([y:rat]imp(in(pofrt(y),s1),notmax(y))))]
t74:=th1"l.some"(rat,[y:rat]imp(in(pofrt(y),s1),notmax(y)),n):some"rt"([y:rat]not(imp(in(pofrt(y),s1),notmax(y))))
[y0:rat][o:not(imp(in(pofrt(y0),s1),notmax(y0)))]
t75:=th5"l.imp"(in(pofrt(y0),s1),notmax(y0),o):in(pofrt(y0),s1)
t76:=th6"l.imp"(in(pofrt(y0),s1),notmax(y0),o):not(notmax(y0))
[i:in"rt"(x0,ctset)]
t77:=t42(x0,i,y0,t76):less"rt"(x0,y0)
t78:=satz91(x0,y0,t77):some"rt"([z:rat]and(less"rt"(x0,z),less"rt"(z,y0)))
[z0:rat][a:and(less"rt"(x0,z0),less"rt"(z0,y0))]
t79:=ande1(less"rt"(x0,z0),less"rt"(z0,y0),a):less"rt"(x0,z0)
t80:=ande2(less"rt"(x0,z0),less"rt"(z0,y0),a):less"rt"(z0,y0)
t81:=t32(pofrt(y0),pofrt(z0),t75,lessrtep(z0,y0,t80)):in(pofrt(z0),s1)
t82:=andi(in(pofrt(y0),s1),more"rt"(y0,z0),t75,satz83(z0,y0,t80)):and(in(pofrt(y0),s1),more"rt"(y0,z0))
t83:=somei(rat,[y:rat]and(in(pofrt(y),s1),more"rt"(y,z0)),y0,t82):notmax(z0)
t84:=t46(x0,z0,t44(z0,t81,t83),t79):not(ub(ctset,x0))
i@t85:=someapp(rat,[z:rat]and(less"rt"(x0,z),less"rt"(z,y0)),t78,not(ub(ctset,x0)),[z:rat][t:and(less"rt"(x0,z),less"rt"(z,y0))]t84(z,t)):not(ub(ctset,x0))
o@t85a:=th2"l.ec"(ub(ctset,x0),in"rt"(x0,ctset),[t:in"rt"(x0,ctset)]t85(t)):ec(ub(ctset,x0),in"rt"(x0,ctset))
t86:=weli(ec(ub(ctset,x0),in"rt"(x0,ctset)),t85a):not(max(ctset,x0))
n@t87:=someapp(rat,[y:rat]not(imp(in(pofrt(y),s1),notmax(y))),t74,not(max(ctset,x0)),[y:rat][t:not(imp(in(pofrt(y),s1),notmax(y)))]t86(y,t)):not(max(ctset,x0))
x0@t88:=th1"l.imp"(all"rt"([x:rat]imp(in(pofrt(x),s1),notmax(x))),not(max(ctset,x0)),[t:all"rt"([x:rat]imp(in(pofrt(x),s1),notmax(x)))]t73(t),[t:not(all"rt"([x:rat]imp(in(pofrt(x),s1),notmax(x))))]t87(t)):not(max(ctset,x0))
ksi0@[a:and(pos(ksi0),in(ksi0,s1))][x0:rat][lx:lrt(ksi(t47(a)),x0)][eta0:rl][i:in(eta0,s2)][y0:rat][uy:urt(eta(a,eta0,i),y0)]
t89:=cut1(ctset,x0,t54(ksi0,a,x0,lx),y0,t59(a,eta0,i,y0,uy),[x:rat][t:in"rt"(x,ctset)][y:rat][u:not(in"rt"(y,ctset))]t66(x,t,y,u),[x:rat]t88(x)):cutprop(ctset)
i@t90:=cutapp1b(eta(a,eta0,i),cutprop(ctset),[y:rat][t:urt(eta(a,eta0,i),y)]t89(y,t)):cutprop(ctset)
lx@t91:=nonemptyapp(rl,s2,p1b,cutprop(ctset),[y:rl][t:in(y,s2)]t90(y,t)):cutprop(ctset)
a@t92:=cutapp1a(ksi(t47(a)),cutprop(ctset),[x:rat][t:lrt(ksi(t47(a)),x)]t91(x,t)):cutprop(ctset)
s@t93:=someapp(rl,[x:rl]and(pos(x),in(x,s1)),s,cutprop(ctset),[x:rl][t:and(pos(x),in(x,s1))]t92(x,t)):cutprop(ctset)
phi:=cutof(ctset,t93):cut
phi0:=pofrp(phi):rl
ksi0@[l:less(ksi0,phi0)][p:pos(ksi0)]
t94:=isless2"rp"(rpofp(phi0,posi(phi)),phi,ksi(p),isrpp2(phi),lessep2(ksi0,phi0,l,p,posi(phi))):less"rp"(ksi(p),phi)
[x0:rat][l1:less"rp"(ksi(p),rpofrt(x0))][l2:less"rp"(rpofrt(x0),phi)]
t95:=lessipp(ksi0,pofrt(x0),p,posrt(x0),isless2"rp"(rpofrt(x0),rpofp(pofrt(x0),posrt(x0)),ksi(p),isrpp1(rpofrt(x0)),l1)):less(ksi0,pofrt(x0))
t96:=t32(pofrt(x0),ksi0,t37(x0,ini(ctset,t93,x0,satz158c(phi,x0,l2))),t95):in(ksi0,s1)
p@t97:=satz159app(ksi(p),phi,t94,in(ksi0,s1),[x:rat][t:less"rp"(ksi(p),rpofrt(x))][u:less"rp"(rpofrt(x),phi)]t96(x,t,u)):in(ksi0,s1)
s@t98:=isless1(ts(1rl,phi0),phi0,ts(pl(1rl,1rl),phi0),satz195b(phi0),satz203a(pl(1rl,1rl),1rl,phi0,lemma205d,posi(phi))):less(phi0,ts(pl(1rl,1rl),phi0))
t99:=satz203k(phi0,ts(pl(1rl,1rl),phi0),ov(1rl,pl(1rl,1rl),t13),t98,lemma205c):less(ts(ov(1rl,pl(1rl,1rl),t13),phi0),ts(ov(1rl,pl(1rl,1rl),t13),ts(pl(1rl,1rl),phi0)))
t100:=isless12(ts(ov(1rl,pl(1rl,1rl),t13),phi0),ov(phi0,pl(1rl,1rl),t13),ts(ov(1rl,pl(1rl,1rl),t13),ts(pl(1rl,1rl),phi0)),phi0,lemma205b(pl(1rl,1rl),phi0,t13),lemma205a(pl(1rl,1rl),phi0,t13),t99):less(ov(phi0,pl(1rl,1rl),t13),phi0)
t101:=posovpp(phi0,pl(1rl,1rl),t13,posi(phi),pospl(1rl,1rl,pos1,pos1)):pos(ov(phi0,pl(1rl,1rl),t13))
hphi:=rpofp(ov(phi0,pl(1rl,1rl),t13),t101):cut
t102:=isless2"rp"(rpofp(phi0,posi(phi)),phi,hphi,isrpp2(phi),lessep2(ov(phi0,pl(1rl,1rl),t13),phi0,t100,t101,posi(phi))):less"rp"(hphi,phi)
l@[n:not(pos(ksi0))][x0:rat][l1:less"rp"(hphi,rpofrt(x0))][l2:less"rp"(rpofrt(x0),phi)]
t103:=rlapp(ksi0,less(ksi0,pofrt(x0)),th2"l.imp"(pos(ksi0),less(ksi0,pofrt(x0)),n),[t:is(ksi0,0)]lessi0p(ksi0,pofrt(x0),t,posrt(x0)),[t:neg(ksi0)]lessinp(ksi0,pofrt(x0),t,posrt(x0))):less(ksi0,pofrt(x0))
t104:=t32(pofrt(x0),ksi0,t37(x0,ini(ctset,t93,x0,satz158c(phi,x0,l2))),t103):in(ksi0,s1)
n@t105:=satz159app(hphi,phi,t102,in(ksi0,s1),[x:rat][t:less"rp"(hphi,rpofrt(x))][u:less"rp"(rpofrt(x),phi)]t104(x,t,u)):in(ksi0,s1)
l@t106:=th1"l.imp"(pos(ksi0),in(ksi0,s1),[t:pos(ksi0)]t97(t),[t:not(pos(ksi0))]t105(t)):in(ksi0,s1)
ksi0@[m:more(ksi0,phi0)]
t112:=moreep1a(ksi0,phi0,m,posi(phi)):pos(ksi0)
t113:=isless1"rp"(rpofp(phi0,posi(phi)),phi,ksi(t112),isrpp2(phi),lessep2(phi0,ksi0,m,posi(phi),t112)):less"rp"(phi,ksi(t112))
[x0:rat][l1:less"rp"(phi,rpofrt(x0))][l2:less"rp"(rpofrt(x0),ksi(t112))]
l1@t114:=satz158d(phi,x0,moreisi1"rp"(rpofrt(x0),phi,satz122(phi,rpofrt(x0),l1))):urt(phi,x0)
l2@t115:=lessipp(pofrt(x0),ksi0,posrt(x0),t112,isless1"rp"(rpofrt(x0),rpofp(pofrt(x0),posrt(x0)),ksi(t112),isrpp1(rpofrt(x0)),l2)):more(ksi0,pofrt(x0))
[y0:rat][k1:less"rp"(phi,rpofrt(y0))][k2:less"rp"(rpofrt(y0),rpofrt(x0))]
t116:=t114(y0,k1):urt(phi,y0)
t117:=th3"l.imp"(ctprop(y0),lrt(phi,y0),t116,[t:ctprop(y0)]ine(ctset,t93,y0,t43(y0,t))):not(ctprop(y0))
t118:=th15"l.or"(in(pofrt(y0),s1),notmax(y0),t117):or(not(in(pofrt(y0),s1)),not(notmax(y0)))
[n:not(in(pofrt(y0),s1))]
t119:=lessipp(pofrt(y0),pofrt(x0),posrt(y0),posrt(x0),isless12"rp"(rpofrt(y0),rpofp(pofrt(y0),posrt(y0)),rpofrt(x0),rpofp(pofrt(x0),posrt(x0)),isrpp1(rpofrt(y0)),isrpp1(rpofrt(x0)),k2)):more(pofrt(x0),pofrt(y0))
t120:=ore2(in(pofrt(y0),s1),in(pofrt(y0),s2),<pofrt(y0)>p0,n):in(pofrt(y0),s2)
t121:=t35(pofrt(y0),pofrt(x0),t120,t119):in(pofrt(x0),s2)
k2@[n:not(notmax(y0))]
t122:=th4"l.some"(rat,[z:rat]and(in(pofrt(z),s1),more"rt"(z,y0)),n,x0):not(and(in(pofrt(x0),s1),more"rt"(x0,y0)))
t123:=satz83(y0,x0,satz154f(y0,x0,k2)):more"rt"(x0,y0)
t124:=th4"l.and"(in(pofrt(x0),s1),more"rt"(x0,y0),t122,t123):not(in(pofrt(x0),s1))
t125:=ore2(in(pofrt(x0),s1),in(pofrt(x0),s2),<pofrt(x0)>p0,t124):in(pofrt(x0),s2)
k2@t126:=orapp(not(in(pofrt(y0),s1)),not(notmax(y0)),in(pofrt(x0),s2),t118,[t:not(in(pofrt(y0),s1))]t121(t),[t:not(notmax(y0))]t125(t)):in(pofrt(x0),s2)
l2@t127:=satz159app(phi,rpofrt(x0),l1,in(pofrt(x0),s2),[y:rat][t:less"rp"(phi,rpofrt(y))][u:less"rp"(rpofrt(y),rpofrt(x0))]t126(y,t,u)):in(pofrt(x0),s2)
t128:=t35(pofrt(x0),ksi0,t127,t115):in(ksi0,s2)
m@t129:=satz159app(phi,ksi(t112),t113,in(ksi0,s2),[x:rat][t:less"rp"(phi,rpofrt(x))][u:less"rp"(rpofrt(x),ksi(t112))]t128(x,t,u)):in(ksi0,s2)
s@t130:=andi(prop1(phi0),prop2(phi0),[x:rl][t:less(x,phi0)]t106(x,t),[x:rl][t:more(x,phi0)]t129(x,t)):prop3(phi0)
t131:=somei(rl,[x:rl]prop3(x),phi0,t130):some([x:rl]prop3(x))
p2@[n1:not(some([x:rl]and(pos(x),in(x,s1))))][ksi0:rl][p:pos(ksi0)]
t132:=th4"l.some"(rl,[x:rl]and(pos(x),in(x,s1)),n1,ksi0):not(and(pos(ksi0),in(ksi0,s1)))
t133:=th3"l.and"(pos(ksi0),in(ksi0,s1),t132,p):not(in(ksi0,s1))
t134:=ore2(in(ksi0,s1),in(ksi0,s2),<ksi0>p0,t133):in(ksi0,s2)
n1@[i:in(0,s1)][ksi0:rl][l:less(ksi0,0)]
t135:=t32(0,ksi0,i,l):in(ksi0,s1)
ksi0@[m:more(ksi0,0)]
t136:=t134(ksi0,satz169b(ksi0,m)):in(ksi0,s2)
i@t137:=andi(prop1(0),prop2(0),[x:rl][t:less(x,0)]t135(x,t),[x:rl][t:more(x,0)]t136(x,t)):prop3(0)
t138:=somei(rl,[x:rl]prop3(x),0,t137):some([x:rl]prop3(x))
n1@[n2:not(in(0,s1))]
t139:=ore2(in(0,s1),in(0,s2),<0>p0,n2):in(0,s2)
[a:all([x:rl]imp(neg(x),in(x,s1)))][ksi0:rl][l:less(ksi0,0)]
t140:=<satz169d(ksi0,l)><ksi0>a:in(ksi0,s1)
ksi0@[m:more(ksi0,0)]
t141:=t35(0,ksi0,t139,m):in(ksi0,s2)
a@t142:=andi(prop1(0),prop2(0),[x:rl][t:less(x,0)]t140(x,t),[x:rl][t:more(x,0)]t141(x,t)):prop3(0)
t143:=somei(rl,[x:rl]prop3(x),0,t142):some([x:rl]prop3(x))
n2@[n3:not(all([x:rl]imp(neg(x),in(x,s1))))]
t144:=th1"l.some"(rl,[x:rl]imp(neg(x),in(x,s1)),n3):some([x:rl]not(imp(neg(x),in(x,s1))))
[ksi0:rl][n:not(imp(neg(ksi0),in(ksi0,s1)))]
t145:=th5"l.imp"(neg(ksi0),in(ksi0,s1),n):neg(ksi0)
t146:=ore2(in(ksi0,s1),in(ksi0,s2),<ksi0>p0,th6"l.imp"(neg(ksi0),in(ksi0,s1),n)):in(ksi0,s2)
t147:=andi(neg(ksi0),in(ksi0,s2),t145,t146):and(neg(ksi0),in(ksi0,s2))
n3@t148:=th6"l.some"(rl,[x:rl]not(imp(neg(x),in(x,s1))),[x:rl]and(neg(x),in(x,s2)),t144,[x:rl][t:not(imp(neg(x),in(x,s1)))]t147(x,t)):some([x:rl]and(neg(x),in(x,s2)))
sn1:=setof(rl,[x:rl]in(mn0(x),s2)):set(rl)
sn2:=setof(rl,[x:rl]in(mn0(x),s1)):set(rl)
ksi0@[i:in(mn0(ksi0),s1)]
t149:=ori2(in(ksi0,sn1),in(ksi0,sn2),estii(rl,[x:rl]in(mn0(x),s1),ksi0,i)):or(in(ksi0,sn1),in(ksi0,sn2))
ksi0@[i:in(mn0(ksi0),s2)]
t150:=ori1(in(ksi0,sn1),in(ksi0,sn2),estii(rl,[x:rl]in(mn0(x),s2),ksi0,i)):or(in(ksi0,sn1),in(ksi0,sn2))
ksi0@t151:=orapp(in(mn0(ksi0),s1),in(mn0(ksi0),s2),or(in(ksi0,sn1),in(ksi0,sn2)),<mn0(ksi0)>p0,[t:in(mn0(ksi0),s1)]t149(t),[t:in(mn0(ksi0),s2)]t150(t)):or(in(ksi0,sn1),in(ksi0,sn2))
[i:in(ksi0,s2)]
t152:=estii(rl,[x:rl]in(mn0(x),s2),mn0(ksi0),isp(rl,[x:rl]in(x,s2),ksi0,mn0(mn0(ksi0)),i,satz177a(ksi0))):in(mn0(ksi0),sn1)
t153:=nonemptyi(rl,sn1,mn0(ksi0),t152):nonempty(rl,sn1)
n3@t154:=nonemptyapp(rl,s2,p1b,nonempty(rl,sn1),[x:rl][t:in(x,s2)]t153(x,t)):nonempty(rl,sn1)
ksi0@[i:in(ksi0,s1)]
t155:=estii(rl,[x:rl]in(mn0(x),s1),mn0(ksi0),isp(rl,[x:rl]in(x,s1),ksi0,mn0(mn0(ksi0)),i,satz177a(ksi0))):in(mn0(ksi0),sn2)
t156:=nonemptyi(rl,sn2,mn0(ksi0),t155):nonempty(rl,sn2)
n3@t157:=nonemptyapp(rl,s1,p1a,nonempty(rl,sn2),[x:rl][t:in(x,s1)]t156(x,t)):nonempty(rl,sn2)
ksi0@[i:in(ksi0,sn1)][eta0:rl][j:in(eta0,sn2)]
t158:=estie(rl,[x:rl]in(mn0(x),s2),ksi0,i):in(mn0(ksi0),s2)
t159:=estie(rl,[x:rl]in(mn0(x),s1),eta0,j):in(mn0(eta0),s1)
t160:=<t158><mn0(ksi0)><t159><mn0(eta0)>p2:less(mn0(eta0),mn0(ksi0))
t161:=satz183d(eta0,ksi0,t160):less(ksi0,eta0)
ksi0@[a:and(neg(ksi0),in(ksi0,s2))]
t162:=satz176c(ksi0,ande1(neg(ksi0),in(ksi0,s2),a)):pos(mn0(ksi0))
t163:=t152(ksi0,ande2(neg(ksi0),in(ksi0,s2),a)):in(mn0(ksi0),sn1)
t164:=andi(pos(mn0(ksi0)),in(mn0(ksi0),sn1),t162,t163):and(pos(mn0(ksi0)),in(mn0(ksi0),sn1))
t165:=somei(rl,[x:rl]and(pos(x),in(x,sn1)),mn0(ksi0),t164):some([x:rl]and(pos(x),in(x,sn1)))
n3@t166:=someapp(rl,[x:rl]and(neg(x),in(x,s2)),t148,some([x:rl]and(pos(x),in(x,sn1))),[x:rl][t:and(neg(x),in(x,s2))]t165(x,t)):some([x:rl]and(pos(x),in(x,sn1)))
t167:=t131(sn1,sn2,[x:rl]t151(x),t154,t157,[x:rl][t:in(x,sn1)][y:rl][u:in(y,sn2)]t161(x,t,y,u),t166):some([x:rl]prop3(sn1,sn2,x))
[ksi0:rl][px:prop3(sn1,sn2,ksi0)]
t168:=ande1(prop1(sn1,sn2,ksi0),prop2(sn1,sn2,ksi0),px):prop1(sn1,sn2,ksi0)
t169:=ande2(prop1(sn1,sn2,ksi0),prop2(sn1,sn2,ksi0),px):prop2(sn1,sn2,ksi0)
chi0:=mn0(ksi0):rl
[eta0:rl][l:less(eta0,chi0)]
t170:=ismore2(mn0(chi0),ksi0,mn0(eta0),satz177(ksi0),satz183c(eta0,chi0,l)):more(mn0(eta0),ksi0)
t171:=<t170><mn0(eta0)>t169:in(mn0(eta0),sn2)
t172:=isp(rl,[x:rl]in(x,s1),mn0(mn0(eta0)),eta0,estie(rl,[x:rl]in(mn0(x),s1),mn0(eta0),t171),satz177(eta0)):in(eta0,s1)
eta0@[m:more(eta0,chi0)]
t173:=isless2(mn0(chi0),ksi0,mn0(eta0),satz177(ksi0),satz183a(eta0,chi0,m)):less(mn0(eta0),ksi0)
t174:=<t173><mn0(eta0)>t168:in(mn0(eta0),sn1)
t175:=isp(rl,[x:rl]in(x,s2),mn0(mn0(eta0)),eta0,estie(rl,[x:rl]in(mn0(x),s2),mn0(eta0),t174),satz177(eta0)):in(eta0,s2)
px@t176:=andi(prop1(chi0),prop2(chi0),[y:rl][t:less(y,chi0)]t172(y,t),[y:rl][t:more(y,chi0)]t175(y,t)):prop3(chi0)
t177:=somei(rl,[x:rl]prop3(x),chi0,t176):some([x:rl]prop3(x))
n3@t178:=someapp(rl,[x:rl]prop3(sn1,sn2,x),t167,some([x:rl]prop3(x)),[x:rl][t:prop3(sn1,sn2,x)]t177(x,t)):some([x:rl]prop3(x))
n2@t179:=th1"l.imp"(all([x:rl]imp(neg(x),in(x,s1))),some([x:rl]prop3(x)),[t:all([x:rl]imp(neg(x),in(x,s1)))]t143(t),[t:not(all([x:rl]imp(neg(x),in(x,s1))))]t178(t)):some([x:rl]prop3(x))
n1@t180:=th1"l.imp"(in(0,s1),some([x:rl]prop3(x)),[t:in(0,s1)]t138(t),[t:not(in(0,s1))]t179(t)):some([x:rl]prop3(x))
p2@t181:=th1"l.imp"(some([x:rl]and(pos(x),in(x,s1))),some([x:rl]prop3(x)),[t:some([x:rl]and(pos(x),in(x,s1)))]t131(t),[t:not(some([x:rl]and(pos(x),in(x,s1))))]t180(t)):some([x:rl]prop3(x))
-5205
p2@satz205:=onei(rl,[x:rl]prop3".5205"(x),t29".5205",t181".5205"):one([x:rl]and(all([y:rl][t:less(y,x)]in(y,s1)),all([y:rl][t:more(y,x)]in(y,s2))))
dedekind:=satz205:one([x:rl]and(all([y:rl][t:less(y,x)]in(y,s1)),all([y:rl][t:more(y,x)]in(y,s2))))
satz205a:=t181".5205":some([x:rl]and(all([y:rl][t:less(y,x)]in(y,s1)),all([y:rl][t:more(y,x)]in(y,s2))))
@[ksi0:rl]
+sqrt
[p:pos(ksi0)]
ksi:=rpofp(ksi0,p):cut
sqrt1:=pofrp(sqrt(ksi)):rl
t1:=posi(sqrt(ksi)):pos(sqrt1)
[q:pos(ksi0)]
t2:=isrpep(sqrt(ksi(p)),sqrt(ksi(q)),issqrt(ksi(p),ksi(q),isperp(ksi0,p,ksi0,q,refis(rl,ksi0)))):is(sqrt1(p),sqrt1(q))
ksi0@sqrt2:=ite"l.r"(pos(ksi0),rl,[t:pos(ksi0)]sqrt1(t),[t:not(pos(ksi0))]0,[t:pos(ksi0)][u:pos(ksi0)]t2(t,u),[t:not(pos(ksi0))][u:not(pos(ksi0))]refis(rl,0)):rl
p@t3:=itet"l.r"(pos(ksi0),rl,[t:pos(ksi0)]sqrt1(t),[t:not(pos(ksi0))]0,[t:pos(ksi0)][u:pos(ksi0)]t2(t,u),[t:not(pos(ksi0))][u:not(pos(ksi0))]refis(rl,0),p):is(sqrt2,sqrt1(p))
ksi0@[n:not(pos(ksi0))]
t4:=itef"l.r"(pos(ksi0),rl,[t:pos(ksi0)]sqrt1(t),[t:not(pos(ksi0))]0,[t:pos(ksi0)][u:pos(ksi0)]t2(t,u),[t:not(pos(ksi0))][u:not(pos(ksi0))]refis(rl,0),n):is(sqrt2,0)
-sqrt
[n:not(neg(ksi0))]
sqrt:=sqrt2".sqrt":rl
[p:pos(ksi0)]
possqrt:=isp1(rl,[x:rl]pos(x),sqrt1".sqrt"(p),sqrt(ksi0,n),t1".sqrt"(p),t3".sqrt"(p)):pos(sqrt(ksi0,n))
n@[i:is(ksi0,0)]
sqrt0:=t4".sqrt"(0notp(ksi0,i)):is(sqrt(ksi0,n),0)
ksi0@[eta0:rl][n:not(neg(ksi0))][o:not(neg(eta0))][i:is(ksi0,eta0)]
issqrt:=isf(rl,rl,[x:rl]sqrt2".sqrt"(x),ksi0,eta0,i):is(sqrt(ksi0,n),sqrt(eta0,o))
ksi0@[n:not(neg(ksi0))]
thsqrt1a:=or3app(is(ksi0,0),pos(ksi0),neg(ksi0),not(neg(sqrt(ksi0,n))),axrlo(ksi0),[t:is(ksi0,0)]0notn(sqrt(ksi0,n),sqrt0(ksi0,n,t)),[t:pos(ksi0)]pnotn(sqrt(ksi0,n),possqrt(ksi0,n,t)),th2"l.imp"(neg(ksi0),not(neg(sqrt(ksi0,n))),n)):not(neg(sqrt(ksi0,n)))
+*sqrt
n"rl"@[p:pos(ksi0)]
t5:=tris(cut,ts"rp"(rpofp(sqrt1(p),t1(p)),rpofp(sqrt1(p),t1(p))),ts"rp"(sqrt"rp"(ksi(p)),sqrt"rp"(ksi(p))),ksi(p),ists12"rp"(rpofp(sqrt1(p),t1(p)),sqrt"rp"(ksi(p)),rpofp(sqrt1(p),t1(p)),sqrt"rp"(ksi(p)),isrpp2(sqrt"rp"(ksi(p))),isrpp2(sqrt"rp"(ksi(p)))),thsqrt1(ksi(p))):is"rp"(ts"rp"(rpofp(sqrt1(p),t1(p)),rpofp(sqrt1(p),t1(p))),ksi(p))
t6:=tr4is(rl,ts(sqrt(ksi0,n),sqrt(ksi0,n)),ts(sqrt1(p),sqrt1(p)),pofrp(ts"rp"(rpofp(sqrt1(p),t1(p)),rpofp(sqrt1(p),t1(p)))),pofrp(ksi(p)),ksi0,ists12(sqrt(ksi0,n),sqrt1(p),sqrt(ksi0,n),sqrt1(p),t3(p),t3(p)),tspp(sqrt1(p),sqrt1(p),t1(p),t1(p)),isrpep(ts"rp"(rpofp(sqrt1(p),t1(p)),rpofp(sqrt1(p),t1(p))),ksi(p),t5),isprp2(ksi0,p)):is(ts(sqrt(ksi0,n),sqrt(ksi0,n)),ksi0)
n"rl"@[o:not(pos(ksi0))]
t7:=or3e1(is(ksi0,0),pos(ksi0),neg(ksi0),axrlo(ksi0),o,n):is(ksi0,0)
t8:=tris2(rl,ts(sqrt(ksi0,n),sqrt(ksi0,n)),ksi0,0,ts01(sqrt(ksi0,n),sqrt(ksi0,n),t4(o)),t7):is(ts(sqrt(ksi0,n),sqrt(ksi0,n)),ksi0)
-sqrt
n@thsqrt1b:=th1"l.imp"(pos(ksi0),is(ts(sqrt(ksi0,n),sqrt(ksi0,n)),ksi0),[t:pos(ksi0)]t6".sqrt"(t),[t:not(pos(ksi0))]t8".sqrt"(t)):is(ts(sqrt(ksi0,n),sqrt(ksi0,n)),ksi0)
[eta0:rl][o:not(neg(eta0))][i:is(ts(eta0,eta0),ksi0)]
+*sqrt
i@[p:pos(eta0)]
t9:=isp(rl,[x:rl]pos(x),ts(eta0,eta0),ksi0,posts(eta0,eta0,p,p),i):pos(ksi0)
t10:=tr3is(rl,pofrp(ts"rp"(rpofp(eta0,p),rpofp(eta0,p))),ts(eta0,eta0),ksi0,pofrp(rpofp(ksi0,t9)),symis(rl,ts(eta0,eta0),pofrp(ts"rp"(rpofp(eta0,p),rpofp(eta0,p))),tspp(eta0,eta0,p,p)),i,isprp1(ksi0,t9)):is(pofrp(ts"rp"(rpofp(eta0,p),rpofp(eta0,p))),pofrp(rpofp(ksi0,t9)))
t11:=isrpip(ts"rp"(rpofp(eta0,p),rpofp(eta0,p)),rpofp(ksi0,t9),t10):is"rp"(ts"rp"(rpofp(eta0,p),rpofp(eta0,p)),rpofp(ksi0,t9))
t12:=thsqrt2(rpofp(ksi0,t9),rpofp(eta0,p),t11):is"rp"(rpofp(eta0,p),sqrt"rp"(rpofp(ksi0,t9)))
t13:=tr3is(rl,eta0,pofrp(rpofp(eta0,p)),sqrt1(ksi0,t9),sqrt(ksi0,n),isprp1(eta0,p),isrpep(rpofp(eta0,p),sqrt"rp"(rpofp(ksi0,t9)),t12),symis(rl,sqrt(ksi0,n),sqrt1(ksi0,t9),t3(t9))):is(eta0,sqrt(ksi0,n))
i@[np:not(pos(eta0))]
t14:=or3e1(is(eta0,0),pos(eta0),neg(eta0),axrlo(eta0),np,o):is(eta0,0)
t15:=tris1(rl,ksi0,0,ts(eta0,eta0),i,ts01(eta0,eta0,t14)):is(ksi0,0)
t16:=tris2(rl,eta0,sqrt(ksi0,n),0,t14,sqrt0(ksi0,n,t15)):is(eta0,sqrt(ksi0,n))
-sqrt
i@thsqrt2:=th1"l.imp"(pos(eta0),is(eta0,sqrt(ksi0,n)),[t:pos(eta0)]t13".sqrt"(t),[t:not(pos(eta0))]t16".sqrt"(t)):is(eta0,sqrt(ksi0,n))
o@[i:is(ksi0,ts(eta0,eta0))]
thsqrt3:=symis(rl,eta0,sqrt(ksi0,n),thsqrt2(symis(rl,ksi0,ts(eta0,eta0),i))):is(sqrt(ksi0,n),eta0)
-rl
-rp
-rt
-n
-landau
-eq
-st
-e
-l
